Jump to content
ExiLeD4EveR

Show/Hide Password when pressing checkbox

Recommended Posts

ExiLeD4EveR

Hello guys, i need help with something. Don't show me other similar threads pls i searched everything and nothing helped my situation. I just need when i press the checkbox in the password form to hide the text and show up as ** and when i press it again it should show letters instead of **.  Thanks in advance!

 

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <StaticConstants.au3>
#include <IE.au3>
#Region ### START Koda GUI section ### Form=c:\users\EXILED\desktop\coding\autoit\gui samples\simplegui.kxf
$SimpleGUI = GUICreate("MultiProgram", 392, 122, -1, -1)
GUISetIcon("C:\Users\EXILED\Desktop\Work\Smile\Icon Pack\EcranLcd.ico", -1)
$Notepad = GUICtrlCreateButton("Notepad", 16, 24, 73, 25)
GUICtrlSetCursor (-1, 0)
$Calculator = GUICtrlCreateButton("Calculator", 112, 24, 73, 25)
GUICtrlSetCursor (-1, 0)
$ExitButoon = GUICtrlCreateButton("Exit", 160, 72, 73, 25)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
GUICtrlSetCursor (-1, 0)
$Lol = GUICtrlCreateButton("Lol Login", 208, 24, 73, 25)
GUICtrlSetCursor (-1, 0)
$Facebook = GUICtrlCreateButton("Facebook ", 304, 24, 73, 25)
GUICtrlSetCursor (-1, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###



While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Calculator
            StartCalc()
        Case $Notepad
            StartNotepad()
        Case $Facebook ;= if Facebook is pressed it creates the email form
            $Face_Login = GUICreate("Facebook Login", 295, 88, -1, -1)
            GUISetIcon("C:\Users\EXILED\Downloads\Iconshock-Social-Media-Beakers-Facebook.ico", -1)
            $Label1 = GUICtrlCreateLabel("Email", 40, 24, 29, 17)
            $InputBox1 = GUICtrlCreateInput("", 72, 21, 148, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_CENTER))
            $Email_button = GUICtrlCreateButton("Done", 96, 56, 97, 25)
            GUISetState(@SW_SHOW)

            ;Case $nMsg = $button
         ;$read = GUICtrlRead ($Password)
            ;GUICtrlDelete ($Password)
                ;If $shown Then
                 ;   $shown = False
                  ;  $Password = GUICtrlCreateInput($read, 20, 75, 160, 20, $ES_PASSWORD)
                   ; GUICtrlSetData($button, "Show Password")
                ;Else
                 ;   $shown = True
                  ;  $Password = GUICtrlCreateInput($read, 20, 75, 160, 20, $GUI_SS_DEFAULT_INPUT)
                   ; GUICtrlSetData($button, "Hide Password")
                ;EndIf






            While 1
                $nMsg = GUIGetMsg()
                Switch $nMsg
                    Case $GUI_EVENT_CLOSE
                        Exit
                    Case $Email_button ;= if Done from email form is pressed then delete the email form and open the password form
                        $data1 = GUICtrlRead($InputBox1)
                        GUIDelete($Face_Login)
                        Sleep(200)
                        $Face_Login2 = GUICreate("Facebook Login", 295, 120, -1, -1)
                        GUISetIcon("C:\Users\ExILD\Downloads\Iconshock-Social-Media-Beakers-Facebook.ico", -1)
                        $Label2 = GUICtrlCreateLabel("Password", 16, 24, 50, 17)
                        $InputBox2 = GUICtrlCreateInput("", 72, 21, 148, 21, $ES_PASSWORD)
                        $Pass_button = GUICtrlCreateButton("Done", 96, 88, 97, 25)
                        $Checkbox1 = GUICtrlCreateCheckbox("Show Password", 16, 56, 105, 17, $BS_CENTER)
                        GUISetState(@SW_SHOW)



                        While 1
                            $nMsg = GUIGetMsg()
                            Switch $nMsg
                                Case $GUI_EVENT_CLOSE
                                    Exit
                                Case $Checkbox1
                                    $read = GUICtrlRead($InputBox2)
                                    GUICtrlDelete($InputBox2)
                                    If GUICtrlRead($Checkbox1) = $GUI_CHECKED  Then



                                        MsgBox(64, "Checked successfully!", "Your password is now visible", 10)

                                    Else


                                        MsgBox(64, "Unchecked successfully!", "Your password is now hidden",10)


                                    EndIf
                                    Case $Pass_button;= if Done from password form is pressed then it deletes the password form and , to add(open internet explorer on the facebook login page
                                    $data2 = GUICtrlRead($InputBox2)
                                    GUIDelete($Face_Login2)
                                    FB_SignIn()
                            EndSwitch
                        WEnd






                EndSwitch
            WEnd



    EndSwitch
WEnd

Func FB_SignIn()

    Global $oIE = _IECreate("https://www.facebook.com/")

    Local $username = _IEGetObjByName($oIE, "email")
    Local $password = _IEGetObjByName($oIE, "pass")
    Local $button = _IEGetObjById($oIE, "loginbutton")

    _IEFormElementSetValue($username, $data1)
    _IEFormElementSetValue($password, $data2)

    _IEAction($button, "click")

EndFunc

Func StartNotepad()
    Run("notepad.exe")

EndFunc

Func StartCalc()
    Run("calc.exe")

EndFunc

 

Share this post


Link to post
Share on other sites
Melba23

ExiLeD4EveR,

Quote

Don't show me other similar threads pls i searched everything and nothing helped my situation

You did not search very hard - this post gives you the answer.

Here is the code incorporated into your script:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <ButtonConstants.au3>

$SimpleGUI = GUICreate("MultiProgram", 392, 122, -1, -1)

$Notepad = GUICtrlCreateButton("Notepad", 16, 24, 73, 25)
GUICtrlSetCursor(-1, 0)
$Calculator = GUICtrlCreateButton("Calculator", 112, 24, 73, 25)
GUICtrlSetCursor(-1, 0)
$ExitButoon = GUICtrlCreateButton("Exit", 160, 72, 73, 25)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
GUICtrlSetCursor(-1, 0)
$Lol = GUICtrlCreateButton("Lol Login", 208, 24, 73, 25)
GUICtrlSetCursor(-1, 0)
$Facebook = GUICtrlCreateButton("Facebook ", 304, 24, 73, 25)
GUICtrlSetCursor(-1, 0)

GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Calculator
            ; StartCalc()
        Case $Notepad
            ; StartNotepad()
        Case $Facebook ;= if Facebook is pressed it creates the email form

            $Face_Login = GUICreate("Facebook Login", 295, 88, -1, -1)

            $Label1 = GUICtrlCreateLabel("Email", 40, 24, 29, 17)
            $InputBox1 = GUICtrlCreateInput("", 72, 21, 148, 21) ;, BitOR($GUI_SS_DEFAULT_INPUT,$ES_CENTER))
            $Email_button = GUICtrlCreateButton("Done", 96, 56, 97, 25)

            GUISetState(@SW_SHOW)

            While 1
                $nMsg = GUIGetMsg()
                Switch $nMsg
                    Case $GUI_EVENT_CLOSE
                        Exit
                    Case $Email_button ;= if Done from email form is pressed then delete the email form and open the password form
                        $data1 = GUICtrlRead($InputBox1)
                        GUIDelete($Face_Login)

                        Sleep(200)

                        $Face_Login2 = GUICreate("Facebook Login", 295, 120, -1, -1)

                        $Label2 = GUICtrlCreateLabel("Password", 16, 24, 50, 17)
                        $InputBox2 = GUICtrlCreateInput("", 72, 21, 148, 21, $ES_PASSWORD)
                        $Pass_button = GUICtrlCreateButton("Done", 96, 88, 97, 25)
                        $Checkbox1 = GUICtrlCreateCheckbox("Show Password", 16, 56, 105, 17, $BS_CENTER)

                        GUISetState(@SW_SHOW)

                        ;Retrieve the ASCII value of the default password char
                        $sDefaultPassChar = GUICtrlSendMsg($InputBox2, $EM_GETPASSWORDCHAR, 0, 0)

                        While 1
                            $nMsg = GUIGetMsg()
                            Switch $nMsg
                                Case $GUI_EVENT_CLOSE
                                    Exit
                                Case $Checkbox1
                                    If GUICtrlRead($Checkbox1) = $GUI_CHECKED Then
                                        GUICtrlSendMsg($InputBox2, $EM_SETPASSWORDCHAR, 0, 0)
                                        MsgBox(64, "Checked successfully!", "Your password is now visible", 10)
                                    Else
                                        GUICtrlSendMsg($InputBox2, $EM_SETPASSWORDCHAR, $sDefaultPassChar, 0)
                                        MsgBox(64, "Unchecked successfully!", "Your password is now hidden", 10)
                                    EndIf
                                     GUICtrlSetState($InputBox2, $GUI_FOCUS) ; Needed to rewrite characters
                                Case $Pass_button ;= if Done from password form is pressed then it deletes the password form and , to add(open internet explorer on the facebook login page
                                    $data2 = GUICtrlRead($InputBox2)
                                    GUIDelete($Face_Login2)
                                    ; FB_SignIn()
                            EndSwitch
                        WEnd
                EndSwitch
            WEnd
    EndSwitch
WEnd

And you might want to look at the Managing Multiple GUIs tutorial in the Wiki - at the moment you exit the entire script if you close the child dialogs using the [X].

M23

 


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites
ExiLeD4EveR

Thanks a lot. Yeah i'll have to find a way to make it not exit when pressing  [X] , is there a documentation about the msg parameter from the GUICtrlSendMsg function?

Share this post


Link to post
Share on other sites
Melba23

ExiLeD4EveR,

Did you read the tutorial to which I linked? That explains exactly how to differentiate between multiple GUIs - which is why I wrote it.

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites
ExiLeD4EveR

Yeah but im kinda confused how to implement it in my code...

Share this post


Link to post
Share on other sites
Melba23

ExiLeD4EveR,

This seems to work:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <ButtonConstants.au3>

opt("TrayIcondebug", 1)

$SimpleGUI = GUICreate("MultiProgram", 392, 122, -1, -1)

$Notepad = GUICtrlCreateButton("Notepad", 16, 24, 73, 25)
GUICtrlSetCursor(-1, 0)
$Calculator = GUICtrlCreateButton("Calculator", 112, 24, 73, 25)
GUICtrlSetCursor(-1, 0)
$ExitButoon = GUICtrlCreateButton("Exit", 160, 72, 73, 25)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
GUICtrlSetCursor(-1, 0)
$Lol = GUICtrlCreateButton("Lol Login", 208, 24, 73, 25)
GUICtrlSetCursor(-1, 0)
$Facebook = GUICtrlCreateButton("Facebook ", 304, 24, 73, 25)
GUICtrlSetCursor(-1, 0)

GUISetState(@SW_SHOW)

While 1
    $aMsg = GUIGetMsg(1)
    Switch $aMsg[1]
        Case $SimpleGUI ; Only react to main GUI events
            Switch $aMsg[0]
                Case $GUI_EVENT_CLOSE
                    Exit
                Case $Calculator
                    ; StartCalc()
                Case $Notepad
                    ; StartNotepad()
                Case $Facebook ;= if Facebook is pressed it creates the email form

                    $Face_Login = GUICreate("Facebook Login", 295, 88, -1, -1)

                    $Label1 = GUICtrlCreateLabel("Email", 40, 24, 29, 17)
                    $InputBox1 = GUICtrlCreateInput("", 72, 21, 148, 21) ;, BitOR($GUI_SS_DEFAULT_INPUT,$ES_CENTER))
                    $Email_button = GUICtrlCreateButton("Done", 96, 56, 97, 25)

                    GUISetState(@SW_SHOW)

                    While 1
                        $aMsg = GUIGetMsg(1)
                        Switch $aMsg[1]
                            Case $Face_Login ; Only react to $Face_Login events
                                Switch $aMsg[0]
                                    Case $GUI_EVENT_CLOSE
                                        GUIDelete($Face_Login)
                                        ExitLoop ; And return to the outer loop to look for main GUI events
                                    Case $Email_button ;= if Done from email form is pressed then delete the email form and open the password form
                                        $data1 = GUICtrlRead($InputBox1)
                                        GUIDelete($Face_Login)

                                        Sleep(200)

                                        $Face_Login2 = GUICreate("Facebook Login", 295, 120, -1, -1)

                                        $Label2 = GUICtrlCreateLabel("Password", 16, 24, 50, 17)
                                        $InputBox2 = GUICtrlCreateInput("", 72, 21, 148, 21, $ES_PASSWORD)
                                        $Pass_button = GUICtrlCreateButton("Done", 96, 88, 97, 25)
                                        $Checkbox1 = GUICtrlCreateCheckbox("Show Password", 16, 56, 105, 17, $BS_CENTER)

                                        GUISetState(@SW_SHOW)

                                        ;Retrieve the ASCII value of the default password char
                                        $sDefaultPassChar = GUICtrlSendMsg($InputBox2, $EM_GETPASSWORDCHAR, 0, 0)

                                        While 1
                                            $aMsg = GUIGetMsg(1)
                                            Switch $aMsg[1]
                                                Case $Face_Login2 ; Only react to $Face_Login2 events
                                                    Switch $aMsg[0]
                                                        Case $GUI_EVENT_CLOSE
                                                            GUIDelete($Face_Login2)
                                                            ExitLoop 2 ; And return to the outer loop to look for main GUI events - note we need to exit 2 loops
                                                        Case $Checkbox1
                                                            If GUICtrlRead($Checkbox1) = $GUI_CHECKED Then
                                                                GUICtrlSendMsg($InputBox2, $EM_SETPASSWORDCHAR, 0, 0)
                                                                MsgBox(64, "Checked successfully!", "Your password is now visible", 10)
                                                            Else
                                                                GUICtrlSendMsg($InputBox2, $EM_SETPASSWORDCHAR, $sDefaultPassChar, 0)
                                                                MsgBox(64, "Unchecked successfully!", "Your password is now hidden", 10)
                                                            EndIf
                                                            GUICtrlSetState($InputBox2, $GUI_FOCUS) ; Needed to rewrite characters
                                                        Case $Pass_button ;= if Done from password form is pressed then it deletes the password form and , to add(open internet explorer on the facebook login page
                                                            $data2 = GUICtrlRead($InputBox2)
                                                            GUIDelete($Face_Login2)
                                                            ; FB_SignIn()
                                                            ExitLoop 2  ; And return to the outer loop to look for main GUI events - note we need to exit 2 loops
                                                    EndSwitch
                                            EndSwitch
                                        WEnd
                                EndSwitch
                        EndSwitch
                    WEnd
            EndSwitch
    EndSwitch
WEnd

Please ask if you have any questions.

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now

  • Similar Content

    • Haselnuzz
      By Haselnuzz
      Hi and Hello from a Noob..:-)
      i have a very weird problem. I fill up a 2d array with a)numbers and b)letters from A-Z, so 2 columns. This works absolutely perfect. But as soon as i try to sort them (numbers ascending) the array ends up in some kind of "String-sortation". What exactly am i doin wrong? To make it easy, i post below the piece of code, which i am talking about. Hope that someone can help me out.
      Func Analyse()
          Local $BasisArray[0]
          Local $aFill = "A" & "|B" & "|C" & "|D" & "|E" & "|F" & "|G" & "|H" & "|I" & "|J" & "|K" & "|L" & "|M" & "|N" & "|O" & "|P" & "|Q" & "|R" & "|S" & "|T" & "|U" & "|V" & "|W" & "|X" & "|Y" & "|Z"
          _ArrayAdd ($BasisArray, $afill)
          Local $FreqArray[0][2]=[[]]
       
          $row = 0

          For $i = 0 to 25
       
              $fummel = _ArrayToString ($BasisArray, ":" , $row, $row)
              $readout = _GUICtrlRichEdit_GetText ($hRichEdit)
              $anzAs = stringreplace ($readout, $fummel, $fummel)
              $extended = @extended
              $FreqFill = $extended & "|" & $fummel
              _ArrayAdd($FreqArray, $FreqFill)
       
              $row = $row + 1
          Next
          _ArrayDisplay($FreqArray, "2D - Item delimited")
          _ArraySort($FreqArray)
          _ArrayDisplay($FreqArray, "bla")
       
       
      Thanks for helping me,
       
      Cheers,
       
      Patrick
    • greichert
      By greichert
      I am running an exe, that copies a seperate exe (test123.exe)from my computer and puts it onto a remote server "testserver". Everything  works fine up to this point. I need to run this copied exe (test123.exe) on "testserver" but it keeps running on my computer instead. The code I am using to run the exe is below. What am I doing wrong? How can I get this executable to run on the remote server and not my home computer?
      RunWait( "\\testserver.domain.com\c$\user1\greichert\Desktop\InstallEXE\InstallEXE\test123.exe","\\testserver.domain.com\c$\Users\user1\Desktop\InstallEXE\InstallEXE");run exe  
    • greichert
      By greichert
      I am trying to stop a windows service on a separate server than where my script is running. When I run the following script on the same server as the service I need to stop, it works fine. 
      RunWait(@ComSpec & " /c net stop FascetAgentfv2", @ScriptDir, @SW_HIDE);stop agent But when I change "@ScriptDir" to ""\\newserver\c$\Program Files\test\" and run it on my server nothing happens. I tried to error handle and all it was returning was "2". Any suggestions?
    • ufukreis1212
      By ufukreis1212
      Hello, I am new members. Help me please. I want vbs convert to au3 .
      This vbs code : 
      'deneme Set SystemSet = GetObject("winmgmts:").InstancesOf ("Win32_OperatingSystem") strOSArch = GetObject("winmgmts:root\cimv2:Win32_OperatingSystem=@").OSArchitecture Set objNetwork = CreateObject("Wscript.Network") Set wshShell = CreateObject( "WScript.Shell" ) strComputerName = wshShell.ExpandEnvironmentStrings( "%COMPUTERNAME%" ) Set oShell = WScript.CreateObject("WScript.Shell") proc_arch = oShell.ExpandEnvironmentStrings("%PROCESSOR_ARCHITECTURE%") Set oEnv = oShell.Environment("SYSTEM") strComputer = "." Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2") Set colMB = objWMIService.ExecQuery("Select * from Win32_BaseBoard") Set colCSes = objWMIService.ExecQuery("SELECT * FROM Win32_ComputerSystem") Set colProcessors = objWMIService.ExecQuery("Select * from Win32_Processor") Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2") Set colItemsx = objWMIService.ExecQuery( _ "SELECT * FROM Win32_VideoController",,48) '------------------------------------------------------------------- Set obj = GetObject("winmgmts:").InstancesOf("Win32_PhysicalMemory") i = 1 For Each obj2 In obj memTmp1 = obj2.capacity / 1024 / 1024 TotalRam = TotalRam + memTmp1 i = i +1 Next '-------------------------------------------------------------------- Dim objWMIService : Set objWMIService = GetObject("winmgmts:\\.\root\cimv2") Set colItems = objWMIService.ExecQuery("Select Architecture from Win32_Processor") For Each objItem in colItems if objItem.Architecture = 0 then strArchitecture = "x86" end if if objItem.Architecture = 9 then strArchitecture = "x64" end if next '-------------------------------------------------------------------- strComputer = "." ' Local computer strMemory = "" i = 1 set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2") set colItems = objWMIService.ExecQuery("Select * from Win32_PhysicalMemory") For Each objItem In colItems if strMemory <> "" then strMemory = strMemory & vbcrlf strMemory = strMemory & "Bank" & i & " : " & (objItem.Capacity /1024 /1024) & " Mb" i = i + 1 Next installedModules = i - 1 Set colItems = objWMIService.ExecQuery("Select * from Win32_PhysicalMemoryArray") For Each objItem in colItems totalSlots = objItem.MemoryDevices Next '---------------------------------------------------------------------- Set objWMISvc = GetObject( "winmgmts:\\.\root\cimv2" ) Set colItems = objWMISvc.ExecQuery( "Select * from Win32_ComputerSystem" ) For Each objItem in colItems strComputerDomain = objItem.Domain Next for each System in SystemSet For Each objItem in colItemsx For Each objProcessor in colProcessors For Each bbType In colMB MbVendor = bbType.Manufacturer MbModel = bbType.Product MsgBox "İşletim Sistemi : " & System.Caption & vbNewLine & _ "İşletim Sistemi Versionu : " & + System.Version & vbNewLine & _ "Windows Mimari Yapısı: " & strOSArch & vbNewLine & _ "Kullanıcı isminiz: " & objNetwork.UserName & vbNewLine & _ "Bilgisayar ismi: " & strComputerName & vbNewLine & _ "Çalışma Grubu: " & strComputerDomain & vbNewLine & _ "--------------------------------------" & vbNewLine & _ "Anakart: " & MbVendor & " " & "[" & MbModel & "]" & vbNewLine & _ "--------------------------------------" & vbNewLine & _ "Grafik Kartı: " & objItem.Caption & vbNewLine & _ "Driver Version: " & objItem.DriverVersion & vbNewLine & _ "--------------------------------------" & vbNewLine & _ "İşlemci Üreticisi: " & objProcessor.Manufacturer & vbNewLine & _ "İşlemci İsmi: " & objProcessor.Name & vbNewLine & _ "CPU Mimarisi: " & strArchitecture & vbNewLine & _ "İşlemci Çekirdek sayısı: " & oEnv("NUMBER_OF_PROCESSORS") & vbNewLine & _ "--------------------------------------" & vbNewLine & _ "Toplam RAM: " & TotalRam & " MB" & vbNewLine & _ "Toplam Slot: " & totalSlots & vbNewLine & _ "Boş Slot: " & (totalSlots - installedModules) & vbNewLine & _ "Ramlerin bulunduğu slotlar:" & vbcrlf & strMemory,0,"deneme" Next Next Next Next please help me , thanks.
    • JuanFelipe
      By JuanFelipe
       
      Hello friends, I have a query, it happens that I have a matrix nxn, the first column of this contains each cell a number with 21 digits, when I pass this matrix to Excel I obviously write that number as 1,10016E + 20, I solved it by adding a * at the end of each cell, but I want it to be written as a text so that I do not have to remove that *, I searched in Google but could not find an effective solution, thanks in advance. 
×