[RESOLVED] Gravatar display on GUI

Skysnake · March 28, 2017

Hello

So I thought it would be cool to use my Gravatar account to display my gravatar in a local GUI.

I use this code:

#cs ----------------------------------------------------------------------------

    AutoIt Version: 3.3.14.2
    Author:         Skysnake

    Script Function:
    Example to download avatar from Gravatar and display locally

#ce ----------------------------------------------------------------------------

; Script Start
; includes
#include <Crypt.au3>

#include <InetConstants.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

; declare Global vars
Global $md5GraMail = '' ; will store email for Grvatar request request



GravatarLogin()

GetAvatar()

Func GravatarLogin()
    ; get the email required for downloading the Gravatar

    Local $sGraMail = InputBox("Get Gravatar", "What is your email registered with Gravatar?", "someone@somewhere.com", "", -1, -1, 0, 0)

    ; from http://en.gravatar.com/site/implement/hash/
    ; make the hash
    ;  Local $dHash = _Crypt_HashData(GUICtrlRead($g_idInputEdit), $g_iAlgorithm) ; Create a hash of the text entered
    $md5GraMail = _Crypt_HashData(StringLower(StringStripWS($sGraMail, 8)), $CALG_MD5)
    ; lose the left two '0x' chars and convert to lower case
    $md5GraMail = StringLower(StringTrimLeft($md5GraMail, 2))

    ; Display the result.
    MsgBox($MB_SYSTEMMODAL, "", $sGraMail & @CRLF & "md5 " & $md5GraMail, 15)
EndFunc   ;==>GravatarLogin



; example from Help file: /html/functions/InetGet.htm

; Download a file in the background.
; Wait for the download to complete.

Func GetAvatar()
    ; Save the downloaded file to the temporary folder.
    Local $sFilePath = _WinAPI_GetTempFileName(@TempDir)

    ; from http://en.gravatar.com/site/implement/images/
    ; <img src="https://www.gravatar.com/avatar/205e460b479e2e5b48aec07710c08d50" />

    ; Download the file in the background with the selected option of 'force a reload from the remote site.'
    ; the next THREE options are alternatives
    ; Gravatar sample from here http://en.gravatar.com/site/implement/images/
    ; 1
    ;Local $hDownload = InetGet("https://www.gravatar.com/avatar/205e460b479e2e5b48aec07710c08d50", $sFilePath, $INET_FORCERELOAD, $INET_DOWNLOADBACKGROUND)

    ;   the normal code, should show user avatar
    ; 2
    Local $hDownload = InetGet("https://www.gravatar.com/avatar/" & $md5GraMail & "?d=retro", $sFilePath, $INET_FORCERELOAD, $INET_DOWNLOADBACKGROUND)

    ; my email hardcoded, downloads, but does not show avatar
    ; 3
    ;Local $hDownload = InetGet("https://www.gravatar.com/avatar/cac637b47c9fecc8aa1dcdf71e7a4cc8", $sFilePath, $INET_FORCERELOAD, $INET_DOWNLOADBACKGROUND)

    ; Wait for the download to complete by monitoring when the 2nd index value of InetGetInfo returns True.
    Do
        Sleep(250)
    Until InetGetInfo($hDownload, $INET_DOWNLOADCOMPLETE)

    ; Retrieve the number of total bytes received and the filesize.
    Local $iBytesSize = InetGetInfo($hDownload, $INET_DOWNLOADREAD)
    Local $iFileSize = FileGetSize($sFilePath)

    ; Close the handle returned by InetGet.
    InetClose($hDownload)

    ; Display details about the total number of bytes read and the filesize.
    MsgBox($MB_SYSTEMMODAL, "", "The total download size: " & $iBytesSize & @CRLF & _
            "The total filesize: " & $iFileSize, 1)

    Local $MyGravatar = @ScriptDir & "\Gravatar.jpg"
    FileCopy($sFilePath, $MyGravatar)


    MsgBox(0, "Now showing!", $MyGravatar, 5)


    ; make gui and show file
    GUICreate("My Gravatar in a GUI " & $MyGravatar, 350, 300, -1, -1, $WS_SIZEBOX + $WS_SYSMENU) ; will create a dialog box that when displayed is centered

    Local $idPic = GUICtrlCreatePic($MyGravatar, 50, 50, 80, 80)

    GUISetState(@SW_SHOW)



    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd

    ;FileDelete($MyGravatar)
    ;   Delete the file.
    FileDelete($sFilePath)
EndFunc   ;==>GetAvatar

Now, here is the issue.

If I use the example from the Gravatar site, located here:

http://en.gravatar.com/site/implement/images/

Then this code 205e460b479e2e5b48aec07710c08d50 downloads this pic (not me)

AND it displays correctly.

PROBLEM

However, If I download my own Gravatar, I see the image in the @Script folder, BUT IT DOES NOT DISPLAY. The same with the retro image. To be clear, this image downloads, but is not displayed.

I guess it has something to do with the format of my gravatar. Or that the display funtion GUICtrlCreatePic() does not like my gravatar.

I would be grateful if someone would be willing to test this and may offer a suggestion or two...

Skysnake

Edited March 28, 2017 by Skysnake

Subz · March 28, 2017

The image above is a png file, GuiCtrlCreatePic doesn't support png.

Skysnake · March 28, 2017

Thank you for the comment. That may very well be true. I will check. However, why does the retro image not display? Its also a .PNG

And BTW, except for right clicking in this Forum, how would you detect the format?

I was being naive in thinking Gravatar would convert the uploaded image to bmp/jpg/gif on download...

Thanks for the reply.

Skysnake

Edited March 28, 2017 by Skysnake

Subz · March 28, 2017

You would need to read the file extension using something like

If StringRight($Filepath, 4) = ".jpg" Then do something..

Alternatively you could use GDIPlus functions which supports png format, see post by UEZ

Skysnake · March 28, 2017

Thank you kindly.

Will clean up and post a working script.

Skysnake

Skysnake · March 28, 2017

Thank you kindly.

Will clean up and post a working script.

Skysnake

Skysnake · March 28, 2017

Here is the script that works. PNGs converted to BMP. BMPs also get converted to BMP with some loss of quality, but that is a matter for a different day.

Thank you.

Working script:

#cs ----------------------------------------------------------------------------

    AutoIt Version: 3.3.14.2
    Author:         Skysnake

    Script Function:
    Example to download avatar from Gravatar and display locally

#ce ----------------------------------------------------------------------------

; Script Start
; includes
#include <Crypt.au3>

#include <InetConstants.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <gdiplus.au3>
#include <memory.au3>
#include <staticconstants.au3>


; declare Global vars
Global $md5GraMail = '' ; will store email for Grvatar request request



GravatarLogin()

GetAvatar()

Func GravatarLogin()
    ; get the email required for downloading the Gravatar

    Local $sGraMail = InputBox("Get Gravatar", "What is your email registered with Gravatar?", "someone@somewhere.com", "", -1, -1, 0, 0)

    ; from http://en.gravatar.com/site/implement/hash/
    ; make the hash
    ;  Local $dHash = _Crypt_HashData(GUICtrlRead($g_idInputEdit), $g_iAlgorithm) ; Create a hash of the text entered
    $md5GraMail = _Crypt_HashData(StringLower(StringStripWS($sGraMail, 8)), $CALG_MD5)
    ; lose the left two '0x' chars and convert to lower case
    $md5GraMail = StringLower(StringTrimLeft($md5GraMail, 2))

    ; Display the result.
    MsgBox($MB_SYSTEMMODAL, "", $sGraMail & @CRLF & "md5 " & $md5GraMail, 15)
EndFunc   ;==>GravatarLogin



; example from Help file: /html/functions/InetGet.htm

; Download a file in the background.
; Wait for the download to complete.

Func GetAvatar()
    ; Save the downloaded file to the temporary folder.
    Local $sFilePath = _WinAPI_GetTempFileName(@TempDir)

    ; from http://en.gravatar.com/site/implement/images/
    ; <img src="https://www.gravatar.com/avatar/205e460b479e2e5b48aec07710c08d50" />

    ; Download the file in the background with the selected option of 'force a reload from the remote site.'
    ; the next THREE options are alternatives
    ; Gravatar sample from here http://en.gravatar.com/site/implement/images/
    ; 1
    ;Local $hDownload = InetGet("https://www.gravatar.com/avatar/205e460b479e2e5b48aec07710c08d50", $sFilePath, $INET_FORCERELOAD, $INET_DOWNLOADBACKGROUND)

    ;   the normal code, should show user avatar
    ; 2
    Local $hDownload = InetGet("https://www.gravatar.com/avatar/" & $md5GraMail & "?d=retro", $sFilePath, $INET_FORCERELOAD, $INET_DOWNLOADBACKGROUND)

    ; my email hardcoded, downloads, but does not show avatar
    ; 3
    ;Local $hDownload = InetGet("https://www.gravatar.com/avatar/cac637b47c9fecc8aa1dcdf71e7a4cc8", $sFilePath, $INET_FORCERELOAD, $INET_DOWNLOADBACKGROUND)

    ; Wait for the download to complete by monitoring when the 2nd index value of InetGetInfo returns True.
    Do
        Sleep(250)
    Until InetGetInfo($hDownload, $INET_DOWNLOADCOMPLETE)

    ; Retrieve the number of total bytes received and the filesize.
    Local $iBytesSize = InetGetInfo($hDownload, $INET_DOWNLOADREAD)
    Local $iFileSize = FileGetSize($sFilePath)

    ; Close the handle returned by InetGet.
    InetClose($hDownload)

    ; Display details about the total number of bytes read and the filesize.
    MsgBox($MB_SYSTEMMODAL, "", "The total download size: " & $iBytesSize & @CRLF & _
            "The total filesize: " & $iFileSize, 1)

    Local $sMyGravatar = @ScriptDir & "\Gravatar.png"
    FileCopy($sFilePath, $sMyGravatar)

    ConvertGavatarBMP($sMyGravatar)


    MsgBox(0, "Now showing!", "MyGravatar", 5)


    ; make gui and show file
    GUICreate("My Gravatar in a GUI MyGravatar", 350, 300, -1, -1, $WS_SIZEBOX + $WS_SYSMENU) ; will create a dialog box that when displayed is centered

    Local $idPic = GUICtrlCreatePic(@ScriptDir & "\mygravatar.bmp", 50, 50, 80, 80)

    GUISetState(@SW_SHOW)



    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd

    FileDelete($sMyGravatar)
    FileDelete(@ScriptDir & "\mygravatar.bmp")
    ;   Delete the file.
    FileDelete($sFilePath)
EndFunc   ;==>GetAvatar



Func ConvertGavatarBMP($MyGravatar)
    If Not _GDIPlus_Startup() Or @extended < 6 Then
        MsgBox($MB_SYSTEMMODAL, "ERROR", "GDIPlus.dll v1.1 not available")
        Return
    EndIf

    $sFile = $MyGravatar

    Local $hImage = _GDIPlus_ImageLoadFromFile($sFile)

    Local $iWidth = 600
    Local $iHeight = _GDIPlus_ImageGetHeight($hImage) * 600 / _GDIPlus_ImageGetWidth($hImage)

    ;Local $hGui = GUICreate("GDI+ v1.1 (" & @ScriptName & ")", $iWidth, $iHeight)
    Local $hGui = GUICreate(@ScriptDir & "\mygravatar.bmp", $iWidth, $iHeight)
    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
    GUISetState(@SW_SHOW)

    ;Convert to a 16-color bitmap (4 bits per pixel) using FixedHalftone27 dithering
    Local $tPalette = _GDIPlus_PaletteInitialize(16, $GDIP_PaletteTypeFixedHalftone27, 16, False, $hImage)
    _GDIPlus_BitmapConvertFormat($hImage, $GDIP_PXF04INDEXED, $GDIP_DitherTypeDualSpiral8x8, $GDIP_PaletteTypeFixedHalftone27, $tPalette)

    _GDIPlus_GraphicsDrawImageRect($hGraphics, $hImage, 0, 0, $iWidth, $iHeight)



    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    _GDIPlus_ImageSaveToFile($hImage, @ScriptDir & "\mygravatar.bmp")
    _GDIPlus_ImageDispose($hImage)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
EndFunc   ;==>ConvertGavatarBMP

Skysnake

Sign In

[RESOLVED] Gravatar display on GUI

Recommended Posts

Skysnake

Link to comment

Share on other sites

Subz

Link to comment

Share on other sites

Skysnake

Link to comment

Share on other sites

Subz

Link to comment

Share on other sites

Skysnake

Link to comment

Share on other sites

Skysnake

Link to comment

Share on other sites

Skysnake

Link to comment

Share on other sites

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members

Similar Content

full screen gui

adding a variable inside a PowerShell command

Which possibilities do we have to embed a HTML page into a AutoIt GUI?

Memory leak with GUICtrlSendMsg and Picture control

DarkMode UDF for AutoIt's Win32GUIs 1 2

Browse

AutoIt Resources

Release

Beta