Jump to content

[REGEX] Complex string to be validated


Recommended Posts

Hello, i need to validate a string can be different things. I just need a True - False return value, no groups or things like that. It will be always one line at time to be processed by StringRegEx

Valid:

13:52|String
02:52 XX|String
13:52~SUN, MON, TUE, WED, THU, FRI, SAT|String
02:52 XX~SUN, MON, FRI|String
22/04/2017 13:52|String
22/04/2017 02:52 YY|String

Not Valid
22/04/2017 13:52~Dom|String

I need to validate until and inclusively the | after that i don't care

The XX and YY value are two $sVariable from my script

SUN, MON, TUE, WED, THU, FRI, SAT are fixed value, the can be mixed but always in the same order like

SUN

SUN, TUE, WED

SUN, SAT 

The time can be 12 or 24 hours, the date is always in the same format DD/MM/YYYY. If there is a date can't be a day after that ( see not valid )

Well i think is all :D

Sorry if i don't provide a working code, regex is too way complex.

Thanks

Edited by MyEarth
Link to comment
Share on other sites

Try this:

Local $aIn = [ _
    "13:52|String", _
    "02:52 XX|String", _
    "13:52~SUN, MON, TUE, WED, THU, FRI, SAT|String", _
    "22/04/2017 13:52|String", _
    "22/04/2017 02:52 YY|String", _
    "22/04/2017 13:52~Dom|String", _
    "13:72|String", _
    "33:12|String", _
    "13:52~ WED, THU|String", _
    "22/14/2017 13:52|String", _
    "62/04/2017 13:52|String", _
    "22/04/2117 13:52|String" _
]

Local $sVarXX = "XX", $sVarYY = "YY"

; Let's avoid painful repetition of sub patterns
;
; (?(DEFINE) (?<Time>   (?:[01]\d | 2[0-3]) : [0-5]\d ) )                   ; subroutine for hh:ss
; (?(DEFINE) (?<Day>    SUN | MON | TUE | WED | THU | FRI | SAT) )          ; subroutine for one day name
; (?(DEFINE) (?<Daylist> (?&Day) (?:,\ (?&Day))* ) )                        ; subroutine for a list of days
; (?(DEFINE) (?<Date>   (?:[0-2]\d|3[0-1]) / (?:0\d|1[0-2]) / 20\d\d\ ) )   ; subroutine for dd/mm/20xx (I choose to restrict YYYY to 2000..2099 but your app may need otherwise)
;
; Now we can sew all the pieces together, in the order of cases in $aIn
;
; (?x) allows ignoing non-escaped whitespaces in the pattern for improved readability
;
;"(?x) ^                                            ; anchor at start of string
;        (                                          ; group the pieces ORed (outer alternation)
;        (?&Time)                                   ; time alone
;        |                                          ; or
;        (?&Time) \ \Q" & $sVarXX & "\E             ; time space XX
;        |                                          ; or
;        (?&Time) ~ (?&Daylist)                     ; time tilde daylist
;        |                                          ; or
;        (?&Date) (?&Time) \                        ; date space time
;        |                                          ; or
;        (?&Date) (?&Time) \ \Q" & $sVarYY & "\E    ; date time space XX
;        )                                          ; end of alternation
;\|"                                                ; final bar
;
; Smoke test:

Local $sPattern = _
    "(?x)" & _
    " (?(DEFINE) (?<Time>   (?:[01]\d | 2[0-3]) : [0-5]\d ) )" & _
    " (?(DEFINE) (?<Day>    SUN | MON | TUE | WED | THU | FRI | SAT) )" & _
    " (?(DEFINE) (?<Daylist> (?&Day) (?:,\ (?&Day))* ) )" & _
    " (?(DEFINE) (?<Date>   (?:[0-2]\d|3[0-1]) / (?:0\d|1[0-2]) / 20\d\d\ ) )" & _
    "" & _
        "^" & _
        " (?:" & _
            " (?&Time)" & _                                     ; time alone
            " | " & _                                           ; or
            " (?&Time) \ \Q" & $sVarXX & "\E" & _               ; time space XX
            " | " & _                                           ; or
            " (?&Time) ~ (?&Daylist)" & _                       ; time tilde daylist
            " | " & _                                           ; or
            " (?&Date) (?&Time)" & _                            ; date time
            " | " & _                                           ; or
            " (?&Date) (?&Time) \ \Q" & $sVarYY & "\E" & _      ; date time space XX
        ")" & _
    "\| .*"


For $s In $aIn
    ConsoleWrite('"' & $s & '" is ' & (StringRegExp($s, $sPattern) ? '' : 'in') & 'valid' & @LF)
Next

 

This wonderful site allows debugging and testing regular expressions (many flavors available). An absolute must have in your bookmarks.
Another excellent RegExp tutorial. Don't forget downloading your copy of up-to-date pcretest.exe and pcregrep.exe here
RegExp tutorial: enough to get started
PCRE v8.33 regexp documentation latest available release and currently implemented in AutoIt beta.

SQLitespeed is another feature-rich premier SQLite manager (includes import/export). Well worth a try.
SQLite Expert (freeware Personal Edition or payware Pro version) is a very useful SQLite database manager.
An excellent eBook covering almost every aspect of SQLite3: a must-read for anyone doing serious work.
SQL tutorial (covers "generic" SQL, but most of it applies to SQLite as well)
A work-in-progress SQLite3 tutorial. Don't miss other LxyzTHW pages!
SQLite official website with full documentation (may be newer than the SQLite library that comes standard with AutoIt)

Link to comment
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
 Share

×
×
  • Create New...