Jump to content
TrashBoat

Add spaces between string elements

Recommended Posts

TrashBoat

hey i would like to know if its possible to take a string like this

$string = "onethousandninehundredeightyfive"

and convert it into:

$string = "one thousand nine hundred eighty five"

i have something going on here but its no use

$string = "onethousandninehundredeightyfive"
Global $array[9] = ['one', 'two', 'three', 'four', 'five', 'six', 'seven', 'eight', 'nine']
Global $array1[19] = ['onethousand', 'twothousand', 'threethousand', 'fourthousand', 'fivethousand', 'sixthousand', 'seventhousand', 'eightthousand', 'ninethousand','tenthousand','hundred', 'twohundred', 'threehundred', 'fourhundred', 'fivehundred', 'sixhundred', 'sevenhundred', 'eighthundred', 'ninehundred']
MsgBox(0, 0, AddSpaces($string))


Func AddSpaces($string)
    Local $finalStr
    $length = StringLen($string)
    For $x = 0 To $length
        Local $trim = StringTrimRight($string, $x)
        For $h = 0 To 18
            If $trim = $array1[$h] Then
                $finalStr = $finalStr & " " & $trim
                $string = StringTrimLeft($string, $h)
                $length = StringLen($string)
            EndIf
        Next

        For $z = 0 To 8
            If $trim = $array[$z] Then
                $finalStr = $finalStr & " " & $trim
                $string = StringTrimLeft($string, $z)
                $length = StringLen($string)
            EndIf
        Next
    Next
    Return $finalStr
EndFunc   ;==>AddSpaces

 

Share this post


Link to post
Share on other sites
TheXman
Posted (edited)

Here's one way that it could be done:

example()

Func example()
    Const $kData = "onethousandninehundredeightyfivefiftysixninetyfour"

    Local $s = $kData
    $s       = StringRegExpReplace($s, "(?i)(zero|one|two|three|four(?!ty)|five|six(?!ty)|seven(?!y)|eight(?!y)|nine(?!ty))", "\1 ")
    $s       = StringRegExpReplace($s, "(?i)(twenty|thirty|fourty|fifty|sixty|seventy|eighty|ninety)", "\1 ")
    $s       = StringRegExpReplace($s, "(?i)(hundred|thousand)", "\1 ")

    ConsoleWrite($s & @CRLF)
EndFunc

 

Edited by TheXman
  • Like 1

Whoever said that there's no such thing as a dumb question, probably asked a lot of DUMB questions.  Dumb questions are ones that you can easily find the answer to on your own.

Share this post


Link to post
Share on other sites
TrashBoat

ughh.. what are those (?i) i want to know i understand the (?!y) and (?!ty) , and thanks it works perfectly!

Share this post


Link to post
Share on other sites
TheXman
17 minutes ago, TrashBoat said:

ughh.. what are those (?i) i want to know i understand the (?!y) and (?!ty) , and thanks it works perfectly!

https://www.autoitscript.com/autoit3/docs/functions/StringRegExp.htm

(?i)  = Caseless: matching becomes case-insensitive from that point on.


Whoever said that there's no such thing as a dumb question, probably asked a lot of DUMB questions.  Dumb questions are ones that you can easily find the answer to on your own.

Share this post


Link to post
Share on other sites
Melba23

TheXman,

I would add the space before the detected string, not after - think of "nine" and "nineteen".

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites
TheXman
5 minutes ago, Melba23 said:

I would add the space before the detected string, not after - think of "nine" and "nineteen".

@Melba23

Point taken.  My suggestion doesn't cover a myriad of additional possibilities or requirements.  But to your point, yes, there are several ways that it could have been accomplished. :)

Since "teens" weren't a part of the request, I didn't take them into account.  My solution was meant only to be as accurate as the request itself.  I try not to make any assumptions. :D

However, I did add "thousand" to the example just to point out that it was easy to expand upon the solution, if necessary.


Whoever said that there's no such thing as a dumb question, probably asked a lot of DUMB questions.  Dumb questions are ones that you can easily find the answer to on your own.

Share this post


Link to post
Share on other sites
TrashBoat

yeah ive added them myself no need

$s       = StringRegExpReplace($s, "(?i)(ten|eleven|twelve|thirteen|fourteen|fifteen|sixteen|seventeen|eighteen|nineteen)", "\1 ")

 

Share this post


Link to post
Share on other sites
mikell
24 minutes ago, Melba23 said:

I would add the space before the detected string, not after - think of "nine" and "nineteen".

As the regex engine reads the pattern left to right it could be done like this  :)

$string = "nineteenthousandninehundredninetynine"

Local $pattern
$pattern &= "(?i)("
$pattern &= "hundred|thousand|twenty|ten|eleven|twelve|"
$pattern &= "thirty|fourty|fifty|sixty|seventy|eighty|ninety|"
$pattern &= "thirteen|fourteen|fifteen|sixteen|seventeen|eighteen|nineteen|"
$pattern &= "zero|one|two|three|four|five|six|seven|eight|nine"
$pattern &= ")"

$s = StringRegExpReplace($string, $pattern, "$1 ")
Msgbox(0,"", $s)

 

  • Like 3

Share this post


Link to post
Share on other sites
TheXman
Posted (edited)
1 hour ago, Melba23 said:

I would add the space before the detected string, not after - think of "nine" and "nineteen".

 

Slightly modified version that uses @Melba23's suggestion:

#include <Constants.au3>

example()

Func example()
    Const $kData = "onethousandninehundredeightyfivefiftysixninetyfour"
    Const $kData2 = "nineteenthousandninehundredeightyfivefiftysixninetyfourfourteententhousand"

    Local $s = $kData2
    $s = StringRegExpReplace($s, "(?i)(?<! )(zero|one|two|three|four|five|six|seven|eight|nine|ten)", " \1")
    $s = StringRegExpReplace($s, "(?i)(?<! )(eleven|twelve|thirteen|fourteen|fifteen|sixteen|seventeen|eighteen|nineteen)", " \1")
    $s = StringRegExpReplace($s, "(?i)(?<! )(twenty|thirty|fourty|fifty|sixty|seventy|eighty|ninety)", " \1")
    $s = StringRegExpReplace($s, "(?i)(?<! )(hundred|thousand|million|billion)", " \1")
    $s = StringStripWS($s, $STR_STRIPLEADING)

    ConsoleWrite($s & @CRLF)
EndFunc

 

(?<! ) = Only do the replacement if there isn't already a leading space.

;)

Edited by TheXman

Whoever said that there's no such thing as a dumb question, probably asked a lot of DUMB questions.  Dumb questions are ones that you can easily find the answer to on your own.

Share this post


Link to post
Share on other sites
iamtheky
Posted (edited)

yours still struggles where there is a match inside of your match

e.g. the following string returns  "twomilli oneight thousand four hundred fifty three" in your script, but splits correctly with @mikell's (after adding million to the lead the pattern)

$string = "twomillioneightthousandfourhundredfiftythree"

Local $pattern
$pattern &= "(?i)("
$pattern &= "million|hundred|thousand|twenty|ten|eleven|twelve|"
$pattern &= "thirty|fourty|fifty|sixty|seventy|eighty|ninety|"
$pattern &= "thirteen|fourteen|fifteen|sixteen|seventeen|eighteen|nineteen|"
$pattern &= "zero|one|two|three|four|five|six|seven|eight|nine"
$pattern &= ")"

$s = StringRegExpReplace($string, $pattern, "$1 ")
Msgbox(0,"", $s)

 

Edited by iamtheky

,-. .--. ________ .-. .-. ,---. ,-. .-. .-. .-.
|(| / /\ \ |\ /| |__ __||| | | || .-' | |/ / \ \_/ )/
(_) / /__\ \ |(\ / | )| | | `-' | | `-. | | / __ \ (_)
| | | __ | (_)\/ | (_) | | .-. | | .-' | | \ |__| ) (
| | | | |)| | \ / | | | | | |)| | `--. | |) \ | |
`-' |_| (_) | |\/| | `-' /( (_)/( __.' |((_)-' /(_|
'-' '-' (__) (__) (_) (__)

Share this post


Link to post
Share on other sites
TheXman
4 minutes ago, iamtheky said:

yours still struggles where there is a match inside of your match

Nice catch! :)


Whoever said that there's no such thing as a dumb question, probably asked a lot of DUMB questions.  Dumb questions are ones that you can easily find the answer to on your own.

Share this post


Link to post
Share on other sites
mikell

Complication is not necessary
As I said before, the regex engine reads the pattern left to right, and after a match/replacement it doesn't go backwards
Simple example :

$string = "abcdefghi"

$pattern = "(\w{2}|\w)"

$s = StringRegExpReplace($string, $pattern, "$1.")
Msgbox(0,"", $s)

;)

Share this post


Link to post
Share on other sites
jchd

I believe to have answered the OP question in the other thread devoted to conversion "text to number".


This wonderful site allows debugging and testing regular expressions (many flavors available). An absolute must have in your bookmarks.
Another excellent RegExp tutorial. Don't forget downloading your copy of up-to-date pcretest.exe and pcregrep.exe here
RegExp tutorial: enough to get started
PCRE v8.33 regexp documentation latest available release and currently implemented in AutoIt beta.

SQLitespeed is another feature-rich premier SQLite manager (includes import/export). Well worth a try.
SQLite Expert (freeware Personal Edition or payware Pro version) is a very useful SQLite database manager.
An excellent eBook covering almost every aspect of SQLite3: a must-read for anyone doing serious work.
SQL tutorial (covers "generic" SQL, but most of it applies to SQLite as well)
A work-in-progress SQLite3 tutorial. Don't miss other LxyzTHW pages!
SQLite official website with full documentation (may be newer than the SQLite library that comes standard with AutoIt)

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now

  • Similar Content

    • TrashBoat
      By TrashBoat
      So Im trying to make a simple 2d game and make some sort of collision detection so why not to make a 2 dimensional array but i have no clue how  to write it in multiple lines
      Global $map[5,5] = [0,0,0,0,0 _ [0,0,0,0,0 _ [0,0,0,0,0 _ [0,0,0,0,0 _ [0,0,0,0,0] something like this but it doesn't work
    • Zein
      By Zein
      #include "..\Include\Array.au3" #include "..\Include\File.au3" #include "..\Include\AutoItConstants.au3" Local $aRetArray Local $sFilePath = "n.csv" _FileReadToArray($sFilePath, $aRetArray, ",") ; _FileReadToArray($sFilePath, $aRetArray, $FRTA_COUNT, ",") _ArrayDisplay($aRetArray, "Original", Default, 8) The above code shows two versions of _FileReadToArray and both don't work as expected.
      The first one doesn't use the comma as a delimiter. (so I get a single column array)  I tried adding "Default" between $aRetArray and "," then it told me it had an incorrect number of parameters. 

      I looked again at the documentation:
       
      #include <File.au3> _FileReadToArray ( $sFilePath, ByRef $vReturn [, $iFlags = $FRTA_COUNT [, $sDelimiter = ""]] )
      And I with or without the flags params I should be getting a 2D array due to my file being a csv. 
      I then tried a regular flag, $FRTA_COUNT, and it tells me that I'm using a variable $FRTA_COUNT while it's not declared. Tried putting in 1 instead and it told me again, incorrect number of params. 

       
    • nooneclose
      By nooneclose
      I need to perform a subtotal in excel and I would like to automate this process using Autoit if possible like always any and all help will be greatly appreciated. 
      I can not find a good example but the two from Microsoft. Here is one of the two from msdn.microsoft.com/en-us/vba/excel-vba/articles/range-subtotal-method-excel
      I do not really understand how to translate this into AutoIt, but I gave it a try and here is what I have.
      $OpenRange      = "A1:E200" $xlSum          = -4157 $Added_Array[2] = [2, 3] $OpenRange.Subtotal("B1", $xlSum, $Added_Array, True, False, True) I just need to perform a subtotal on a range based on a header called department, and then perform a sum on the results.
    • nooneclose
      By nooneclose
      How to use _Excel_RangeSort to sort my excel file by three different headers Column A1, B1, and C1 have headers on which I want to sort by. The headers on which I want to sort are department, employee type, and name.
      I still really new to AutoIt so I do not actually know how to properly start this line or lines of code, to be honest. The example code is the best I can do.
      _Excel_RangeSort($OpenWorkbook, Default, "A1:C1", "1:1", $xlDescending, Default, $xlYes, Default, $xlSortRows) I just need to sort by those three headers in that order of department, employee type, and name, plus in descending order.
       
      any and all help would be greatly appreciated.  Thank you!
    • Eminence
      By Eminence
      Hello,
      Using SQLite, I was trying to select a specific column with having duplicate entries removed by using the DISTINCT function. 
      Local $sQuery = "SELECT DISTINCT supervisor, COUNT(DISTINCT employee_name) FROM data_db What the above snippet does is just list only one supervisor but with the total count of unique employee names in the whole database when it should be listing out all supervisor entries from the database and list the total count of employees per each supervisors. If I remove the COUNT function, it does list out all unique entries of supervisor names from the list. Attached is a screenshot of an example database as well. 
      Any help will be much appreciated. Thank you!

×