Change Label if key Is Pressed

[WoodGrain 2]

Hi guys,

I'm learning about GUI's, I'm trying the below code, the idea being if I press the letter "e" while I have the GUI open I want the label color to change to green (I'm using a UDF for label colors). But every time I press "e" on my keyboard I just get a "ding" sound from my speakers and nothing changes with the label.

I've looked at using something like "While GUIGetMsg() <> $GUI_EVENT_CLOSE" as I've seen it in other code instead of "While 1", but I don't think it's relevant.

#include <GUIConstantsEx.au3>; for GUI...
#include <GUIRichLabel.au3>; UDF for rich text label fonts
#include <Misc.au3>; for _IsPressed

$myLetter = "e"

$hGUI = GUICreate("test", 700, 60)

$lbl2 = _GUICtrlRichLabel_Create($hGUI, '<font color="purple">' & $myLetter & '</font>', 10, 10); , 260, 25

GUISetState(@SW_SHOW)


Local $hDLL = DllOpen("user32.dll")
While 1
   if _IsPressed(Hex($myLetter), $hDLL) Then
      While _IsPressed(Hex($myLetter), $hDLL)
         Sleep(250)
      WEnd
      _GUICtrlRichLabel_SetData($lbl2, '<font color="green">' & $myLetter & '</font>')
      Sleep(2000)
      DllClose($hDLL)
      Exit
   EndIf
   Sleep(50)
WEnd
DllClose($hDLL)

I am using an array of letters that I'm wanting to do this for, but as I can't get it to work I've stripped it down to the simplest code I can think of to try and get this working first. Appreciate any help.

Thanks!

[FrancescoDiMuro 376]

@WoodGrain

16 hours ago, WoodGrain said:

But every time I press "e" on my keyboard I just get a "ding" sound from my speakers and nothing changes with the label.

I think that this is caused by the GUI that hasn't the focus, and so, that sound indicates an invalid action of the current focussed GUI.

I think that you have to see when you are in your GUI, using WinGetState() to see if you are able to interact with your GUI, and, if it is not, you could use the other Win* functions to make it possible.

Try that and let us know

[WoodGrain 2]

I saw this code which looks interesting

#include <GuiConstants.au3>
#include <windowsconstants.au3>

GUICreate("MyGUI")

GUISetState()
GUIRegisterMsg(0x101,"WM_KEYDOWN")


While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
    EndSelect
WEnd
Func WM_KEYDOWN($hWnd, $msg, $wParam, $lParam)
    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $wParam = ' & $wParam & @crlf & '>Error code: ' & @error & @crlf) ;### Debug Console
EndFunc

 

[Melba23 3,277]

WoodGrain,

The "letter" parameter required for _IsPressed is not Hex("E") but Hex(Asc("E")) - as explained in the Help file. Once you set that parameter correctly, the label colour changes (at least with native labels):

#include <GUIConstantsEx.au3>; for GUI...
#include <Misc.au3>; for _IsPressed

$myLetter = "E" ; This is the letter
$iCode = Hex(Asc($myLetter), 2) ; and this is the code required for _IsPressed

$hGUI = GUICreate("test", 700, 60)
$cLabel = GUICtrlCreateLabel($myLetter, 10, 10, 200, 20)
GUISetState(@SW_SHOW)

Local $hDLL = DllOpen("user32.dll")
While 1
   if _IsPressed($iCode, $hDLL) Then
      While _IsPressed($iCode, $hDLL)
         Sleep(250)
      WEnd
      GUICtrlSetBkColor($cLabel, 0x00FF00)
      Sleep(2000)
      DllClose($hDLL)
      Exit
   EndIf
   Sleep(50)
WEnd
DllClose($hDLL)

M23

[WoodGrain 2]

Thanks M23, your script works for me too. Would you be so kind to explain to me how you derived the ASC() requirement from the help file? Please be sure I'm not trying to question your comment so much as understand it for myself so I can better understand the doco before posting here next time. I can see the reference to HEX() in that it mentions the 1st parameter as "$sHexKey". Is it just that you already happen to know that those number codes in the list correlate to their ASCII numbers (assuming that's what they are)?

Wow, I also noted in the help file, now that I've tried both lower and upper case letters after noting in your script you used an upper case E, that, as listed in the help file, only upper case letters will work in this scenario! So, after changing my "e" to "E" and adding in the Asc() inside the 2 _IsPressed functions my script worked!

Only remaining question is how do I stop it from making the "ding" noise when I press a key in the GUI lol? That's going to otherwise drive me spare!

Thanks!

[WoodGrain 2]

BTW, looking in control panel > sounds, it's "Windows Background.wav" that's playing..

[mikell 957]

A cute workaround (and more selective/secure IMHO) could be to use GUISetAccelerators and a hidden button 
Of course it works only if the gui is active...

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("test", 700, 60)
$cLabel = GUICtrlCreateLabel("test", 10, 10, 200, 20)
$fake = GUICtrlCreateButton("", -10, 0, 1, 1)
Local $aAccelKeys[1][2] = [["e", $fake]]
GUISetAccelerators($aAccelKeys)
GUISetState(@SW_SHOW)
Local $n

While 1
      Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
            Case $fake
                $n = not $n
                GUICtrlSetBkColor($cLabel, ($n? 0x00FF00 : 0xFF0000))
     EndSwitch
WEnd

 

Edited August 18, 2018 by mikell

[WoodGrain 2]

Thanks Mikell! I can confirm that if I press the correct key ("e" in this example) it doesn't make any sound and does change the color (in fact toggles the color?), however if I press any other key on my keyboard it still makes that awful ding sound. I'll have to spend some time looking at how to get this to work with my array of letters too. Thanks.

[Melba23 3,277]

WoodGrain,

Quote

how you derived the ASC() requirement from the help file? [...] Is it just that you already happen to know that those number codes in the list correlate to their ASCII numbers (assuming that's what they are)?

Exactly that - knowing how the function works internally helps too.

Quote

I'll have to spend some time looking at how to get this to work with my array of letters too

Please read this announcement before you post again - not being accusatory but just offering some friendly advice.

M23

Edited August 18, 2018 by Melba23
Fixed link

[WoodGrain 2]

All good M23, I'm aware of that, I'm writing myself a touch-typing app so I can do dvorak training.

I'm using Klavaro atm to learn dvorak, but it has to be up in the middle of my screen, and I have to type 400+ characters per lesson, I'm writing an app that will just pop-up and hide on hotkey, pull in the current lesson from my lesson plans, and as I type if I press the right key for the letter it will change the color to green, then at the end of the text will load the next random letters from the lesson. "Dinging" every time I make a typo will certainly annoy the staff around me in no time lol.

[WoodGrain 2]

<offtopic>tbh I've been doing some c++ training on the side and would love to learn to start doing this sort of stuff in c++ instead of AutoIT, but haven't got past console basics with if/loops/etc, wouldn't know where to start with a GUI in c++, from what I can see you need to use 3rd party tools to do this.. so here I am writing it in AutoIT lol.</offtopic>

[FrancescoDiMuro 376]

@WoodGrain

For C++ GUI Editor, I'd suggest Borland C++ Builder, which is a very complete and powerful tool to build your GUIs, and much more.

But, if you wanna make it easy, why don't you use Koda Form Designer, which comes with AutoIt, and it's a complete and powerful tool too ( which generates .au3 code too )?

[WoodGrain 2]

ooh, thanks @FrancescoDiMuro
I'll check out both of those resources!!

[WoodGrain 2]

Anyone have any thoughts as to how I can stop the noise in my GUI?

Do I need to use an Input Box and have the program read the last letter on input and use that?
Wouldn't look as clean though.

[WoodGrain 2]

So, after thinking this through it looks like the best method will be to add in an Input Control that I can type into and then use GUIGetMsg to poll it for any changes and then from that run my function to check if the last char they typed in the control is correct compared to the current letter from my array, I've read about $SS_NOTIFY with the control to assist with this.

[FrancescoDiMuro 376]

1 hour ago, WoodGrain said:

and then use GUIGetMsg to poll it for any changes and then from that run my function to check if the last char they typed in the control is correct compared to the current letter from my array

You can use a WM_COMMAND too

expandcollapse popup

#include <Date.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1)

#Region ### START Koda GUI section ### Form=
Global $frmMainForm = GUICreate("A Form", 235, 62, -1, -1)
GUISetOnEvent($GUI_EVENT_CLOSE, "ExitApplication")
Global $txtInput = GUICtrlCreateInput("", 19, 22, 201, 21)
GUICtrlSetFont(-1, 10, 400)
GUISetState(@SW_SHOW, $frmMainForm)
#EndRegion ### END Koda GUI section ###

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

While 1
    Sleep(100)
WEnd


Func ExitApplication()
    Exit
EndFunc

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)

    Local $hdlWindowFrom, _
          $intMessageCode, _
          $intControlID_From

    $intControlID_From =  BitAND($wParam, 0xFFFF)
    $intMessageCode = BitShift($wParam, 16)

    Switch $intControlID_From
        Case $txtInput
            Switch $intMessageCode
                Case $EN_CHANGE
                    ConsoleWrite("[" & _Now() & "] - The text in the $txtInput control has changed! Text = " & GUICtrlRead($txtInput) & @CRLF)
            EndSwitch
    EndSwitch

    Return $GUI_RUNDEFMSG

EndFunc

 

[WoodGrain 2]

Cheers FD, I'll check that out, and thanks for the example code