Jump to content
Rex

Imgur UDF using Curl

Recommended Posts

Some time ago I needed a way to uploade images to imgur, from one of my programs, and took a look at there API.

Don't know if anyone can/would use it, but here is my code :)

 

#AutoIt3Wrapper_Au3Check_Parameters=-q -d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w- 7
; #INDEX# =======================================================================================================================
; Title .........: IMGUR Curl udf
; AutoIt Version : 1.0
; Description ...: Uploads files to imgur using curl, and returns imgur url, deletion key, imgsize ect. in an array
; Author(s) .....: Rex
; ===============================================================================================================================
#include-once
#include <curl.au3> ; By Ward
#include <JSON.au3> ; by Ward

; #FUNCTION# ====================================================================================================================
; Name...........:  _Imgur
; Description ...:  Allows the user to uploade images to Imgur, or delete an already uploaded image using the images DeleteHash
; Syntax.........:  _Imgur($AuthKey, True/False, $vData)
; Parameters ....: $AuthKey     - API key from Imgur
;                  $bImg_Up     - If true an image uploade is expected, if False a DeleteHas is expected
;                  $vData       - The image to uploade, or the DeleteHash that was returned from Imgur at Image uploade
; Return values .: Success      - An Array containing: ID, Datetime, type, animated, width, height, size, deletehash and url
;                  Failur       - Sets @Error to 1 if no AuthKey is provided
;                  Failur       - Sets @Error to 2 if $bImg_Up = True but no Image data is provided
;                  Failur       - Sets @Error to 3 if $bImg_Up = True but $vData isn't Binary
;                  Failur       - Sets @Error to 4 if $bImg_Up = False but no DeleteHash is provided
;                  Failur       - Sets @Error to 5 if the API returns 400 -> Bad Request
;                  Failur       - Sets @Error to 6 if the API returns 403 -> Permission Denied
;                  Failur       - Sets @Error to 7 if the API returns 413 -> Data to large
;                  Failur       - Sets @Error to 8 if the API returns 415 -> Unsupported data
;                  Failur       - Sets @Error to 9 if Curl returns no Curl
;                  Failur       - Sets @Error to 10 and returns Curl error msg if Curl fails
;                  Failur       - Sets @Error to 11 If StringRegExp failed on the header (no array)
; Author ........: Rex
; Modified.......:
; Remarks .......: Needs Curl, Json And BinaryCall by Ward - Base64Encode By Ward and _EPOCH_Decrypt by Trancexx
;                  Is includede in the UDF is self 
; Related .......:
; Link ..........:
; Example .......: $dFile = FileOpenDialog('Open', @ScriptDir, 'Image Files (*.jpg;*.jpeg;*.png;*.bmp;*.gif)', 1) ; Browse image
;                  $hData = FileOpen($dFile, 16) ; Open as binary
;                  $dData = FileRead($hData) ; Read the data
;                  FileClose($hData) ; Close the FileHandle
;                  $aData = _Imgur('APIKEY', True, $dData) ; Uploade the Image
;
;                  $aDelete = _Imgur('APIKEY', False, 'DELETEHASH')
;
; ===============================================================================================================================


Func _Imgur($sAuthKey, $bImg_Up = True, $vData = '')
    ; Performe some error checking
    Select
        Case $sAuthKey = '' ; If no authkey is provided
            Return SetError(1, 0, -1) ; We set error to 1
        Case $vData = '' And $bImg_Up = True ; If no image data is sendt
            Return SetError(2, 0, -1) ; We sent error to 2
        Case $vData <> '' And $bImg_Up = True And IsBinary($vData) = 0 ; If $vData isn't binary
            Return SetError(3, 0, -1) ; We sent error to 3
        Case $vData = '' And $bImg_Up = False ; If no deleta hash was send
            Return SetError(4, 0, -1) ; We sent error to 4
    EndSelect

    Local $aResult[9] ; Return array
    Local $ProgressCallback = DllCallbackGetPtr(DllCallbackRegister("ShowProgress", "int:cdecl", "ptr;uint64;uint64;uint64;uint64"))
    Local $Curl = Curl_Easy_Init()
    If Not $Curl Then Return SetError(9, 0, -1)
    Local $sHtml = $Curl
    Local $sHeader = $Curl + 1 ; any number as identify
    Local $sList = Curl_Slist_Append(0, "User-Agent: Mozilla/5.0 (Windows NT 6.1; rv:34.0) Gecko/20100101 Firefox/34.0")
    $sList = Curl_Slist_Append($sList, 'Referer: http://imgur.com/')
    $sList = Curl_Slist_Append($sList, 'Type: Base64')
    $sList = Curl_Slist_Append($sList, "Authorization: client-ID " & $sAuthKey)
    Curl_Easy_Setopt($Curl, $CURLOPT_HTTPHEADER, $sList)

    ; If $bImg_Up is true we uploads the image
    If $bImg_Up = True Then
        $dImage = _Base64Encode($vData) ; Convert the image to Base64
        Curl_Easy_Setopt($Curl, $CURLOPT_URL, "https://api.imgur.com/3/upload/") ; If we wants to uploade an image
        Curl_Easy_Setopt($Curl, $CURLOPT_POST, 1)
        Curl_Easy_Setopt($Curl, $CURLOPT_COPYPOSTFIELDS, $dImage)
    Else ; If no img we expect a delete
        Curl_Easy_Setopt($Curl, $CURLOPT_URL, "https://api.imgur.com/3/image/" & $vData) ; If we wants to delete an image
        Curl_Easy_Setopt($Curl, $CURLOPT_CUSTOMREQUEST, 'DELETE') ; When we deletes an image
    EndIf
    ; Get header
    Curl_Easy_Setopt($Curl, $CURLOPT_HEADERFUNCTION, Curl_DataWriteCallback())
    Curl_Easy_Setopt($Curl, $CURLOPT_HEADERDATA, $sHeader)
    Curl_Easy_Setopt($Curl, $CURLOPT_FOLLOWLOCATION, 1)

    ; Checks use this to see the respons from server, and get img url/delete hash ect.
    Curl_Easy_Setopt($Curl, $CURLOPT_WRITEFUNCTION, Curl_DataWriteCallback())
    Curl_Easy_Setopt($Curl, $CURLOPT_WRITEDATA, $sHtml)
    Curl_Easy_Setopt($Curl, $CURLOPT_TIMEOUT, 30)
    Curl_Easy_Setopt($Curl, $CURLOPT_SSL_VERIFYPEER, 0)
    Curl_Easy_Setopt($Curl, $CURLOPT_NOPROGRESS, 0)
    Curl_Easy_Setopt($Curl, $CURLOPT_XFERINFOFUNCTION, $ProgressCallback)

    Local $Code = Curl_Easy_Perform($Curl)
    If $Code <> $CURLE_OK Then
        Return SetError(10, 0, Curl_Easy_StrError($Code))
    EndIf
    ;ConsoleWrite(@CRLF & 'HEADER: ' & BinaryToString(Curl_Data_Get($sHeader)) & @CRLF)
    ;ConsoleWrite(@CRLF & 'HTML RAW: ' & BinaryToString(Curl_Data_Get($sHtml)) & @CRLF)
    ; Check what the header returns
    $aHeader = StringRegExp(BinaryToString(Curl_Data_Get($sHeader)), 'HTTP/1.1 (400|403|413|415|200)', 1)
    If IsArray($aHeader) Then
        Select
            Case $aHeader[0] = 400 ; If 403 then Permission Denied
                Return SetError(5, 0, -1)
            Case $aHeader[0] = 403 ; If 403 then Permission Denied
                Return SetError(6, 0, -1)
            Case $aHeader[0] = 413 ; If 413 then the data is to large
                Return SetError(7, 0, -1)
            Case $aHeader[0] = 415 ; If 415 then the data is unsupported
                Return SetError(8, 0, -1)
            Case $aHeader[0] = 200 ; If 200 uploade/delete was a sucess
                ; Decode the json returned from imgur
                Local $sJson = Json_Decode(BinaryToString(Curl_Data_Get($sHtml)))
                ; If deleting an image we only needs to return Sucess - IMGUR returns Sucess
                If $bImg_Up = False Then
                    ReDim $aResult[1] ; Slim down the array
                    $aResult[0] = 'Success'
                    Return $aResult
                EndIf
                ; If an image was uploaded then we need to return some data to the user
                $aResult[0] = Json_Get($sJson, '["data"]["id"]') ; Imgur image id
                ; Date time the image was uploaded, it's returned in unix timestamp, so we converts it to regular time stamp
                $aResult[1] = _EPOCH_Decrypt(Json_Get($sJson, '["data"]["datetime"]'))
                ; Type of uploaded image
                $aResult[2] = Json_Get($sJson, '["data"]["type"]')
                ; Was the image animated
                $aResult[3] = Json_Get($sJson, '["data"]["animated"]')
                ; Width of the image
                $aResult[4] = Json_Get($sJson, '["data"]["width"]')
                ; Height of the image
                $aResult[5] = Json_Get($sJson, '["data"]["height"]')
                ; Size of the image
                $aResult[6] = Json_Get($sJson, '["data"]["size"]')
                ; Delete hash of the image
                $aResult[7] = Json_Get($sJson, '["data"]["deletehash"]')
                ; Image link
                $aResult[8] = Json_Get($sJson, '["data"]["link"]')
                Curl_Easy_Cleanup($Curl)
                Curl_Data_Cleanup($Curl)
                Curl_Slist_Free_All($sList)
                Return $aResult
        EndSelect
    Else ; If the Regexp failed
        Return SetError(11, 1, -1)
    EndIf

EndFunc   ;==>_Imgur

Func ShowProgress($Ptr, $dltotal, $dlnow, $ultotal, $ulnow)
    ProgressSet(Int($ulnow / $ultotal * 100), '% Sendt = ' & Int($ulnow / $ultotal * 100))
    Return 0
EndFunc   ;==>ShowProgress


; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: _EPOCH_Decrypt
; Description ...: Converts Epoch Time to human time
; Syntax ........: _EPOCH_Decrypt(TIMESTAMP)
; Return values .: Convertede timestamp
; Author ........: Trancexx
; Modified ......:
; Remarks .......:
; ===============================================================================================================================

Func _EPOCH_Decrypt($iEpochTime) ; By trancexx forum thread: https://www.autoitscript.com/forum/topic/83667-epoch-time/
    Local $iDayToAdd = Int($iEpochTime / 86400)
    Local $iTimeVal = Mod($iEpochTime, 86400)
    If $iTimeVal < 0 Then
        $iDayToAdd -= 1
        $iTimeVal += 86400
    EndIf
    Local $i_wFactor = Int((573371.75 + $iDayToAdd) / 36524.25)
    Local $i_xFactor = Int($i_wFactor / 4)
    Local $i_bFactor = 2442113 + $iDayToAdd + $i_wFactor - $i_xFactor
    Local $i_cFactor = Int(($i_bFactor - 122.1) / 365.25)
    Local $i_dFactor = Int(365.25 * $i_cFactor)
    Local $i_eFactor = Int(($i_bFactor - $i_dFactor) / 30.6001)
    Local $aDatePart[3]
    $aDatePart[2] = $i_bFactor - $i_dFactor - Int(30.6001 * $i_eFactor)
    $aDatePart[1] = $i_eFactor - 1 - 12 * ($i_eFactor - 2 > 11)
    $aDatePart[0] = $i_cFactor - 4716 + ($aDatePart[1] < 3)
    Local $aTimePart[3]
    $aTimePart[0] = Int($iTimeVal / 3600)
    $iTimeVal = Mod($iTimeVal, 3600)
    $aTimePart[1] = Int($iTimeVal / 60)
    $aTimePart[2] = Mod($iTimeVal, 60)
    Return StringFormat("%.2d/%.2d/%.2d %.2d:%.2d:%.2d", $aDatePart[0], $aDatePart[1], $aDatePart[2], $aTimePart[0], $aTimePart[1], $aTimePart[2])
EndFunc   ;==>_EPOCH_Decrypt


; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: _Base64Encode
; Description ...: Encodes data into Base64
; Syntax ........: _Base64Encode(Data, Linebreak)
; Return values .: Base64 Encodede string
; Author ........: Ward
; Modified ......:
; Remarks .......:
; ===============================================================================================================================

Func _Base64Encode($Data, $LineBreak = 76) ; By Ward
    Local $Opcode = '0x5589E5FF7514535657E8410000004142434445464748494A4B4C4D4E4F505152535455565758595A6162636465666768696A6B6C6D6E6F707172737'
    $Opcode &= '475767778797A303132333435363738392B2F005A8B5D088B7D108B4D0CE98F0000000FB633C1EE0201D68A06880731C083F901760C0FB6430125F0000000C1'
    $Opcode &= 'E8040FB63383E603C1E60409C601D68A0688470183F90176210FB6430225C0000000C1E8060FB6730183E60FC1E60209C601D68A06884702EB04C647023D83F'
    $Opcode &= '90276100FB6730283E63F01D68A06884703EB04C647033D8D5B038D7F0483E903836DFC04750C8B45148945FC66B80D0A66AB85C90F8F69FFFFFFC607005F5E'
    $Opcode &= '5BC9C21000'

    Local $CodeBuffer = DllStructCreate("byte[" & BinaryLen($Opcode) & "]")
    DllStructSetData($CodeBuffer, 1, $Opcode)

    $Data = Binary($Data)
    Local $Input = DllStructCreate("byte[" & BinaryLen($Data) & "]")
    DllStructSetData($Input, 1, $Data)

    $LineBreak = Floor($LineBreak / 4) * 4
    Local $OputputSize = Ceiling(BinaryLen($Data) * 4 / 3)
    $OputputSize = $OputputSize + Ceiling($OputputSize / $LineBreak) * 2 + 4

    Local $Ouput = DllStructCreate("char[" & $OputputSize & "]")
    DllCall("user32.dll", "none", "CallWindowProc", "ptr", DllStructGetPtr($CodeBuffer), _
            "ptr", DllStructGetPtr($Input), _
            "int", BinaryLen($Data), _
            "ptr", DllStructGetPtr($Ouput), _
            "uint", $LineBreak)
    Return DllStructGetData($Ouput, 1)
EndFunc   ;==>_Base64Encode

I have added Wards curl, json and BinaryCall to the att. zip file.

 

Cheers

/Rex

Includes.zip

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now

  • Similar Content

    • By Surya
      Hi everyone its been loooong since I posted here 
      I have been trying to convert this curl executable parameters into autoit using the winhttp com object;
      curl -F data_file=@my_audio_file.mp3 -F model=en-US "https://api.speechmatics.com/v1.0/user/41049/jobs/?auth_token=MmQ5MTk4jdsgjhgghstOGU5YS00OWFhLWghdgjshgdhbshj017###" any ideas guys
       
      PS: I am excited to post here after a looong time
    • By islandspapand
      Hi All
      i am currently trying to add a function to my project that can send SMS, i have gone with Twilio for the sms service that use a REST API.
      I have never worked with an API before, and could use some help.
      I can get my function working with using cURL.exe and copy past command from the website with the following code. And thats great unfortunately i am have issue with character like æøå when sending a SMS appears like a box or ?. this does not happen if i do it from the website so it looks like a Unicode issue in curl.exe.
      I have done some searching on the forum and understand that i should be able to implement this curl command with the WinHTTP UDF from @trancexx so i don't need a third part exe and it might fix my charater issue.
      Unfortunately i really don't understand how i am to change curl commands to the WinHTTP and i was hoping some good maybe give me an example i could learn from.
      Thanks in advanced
      i have removed the AuthToken number from the script.
      _SendSMS("00000000","SomeOne","SMS body info") Func _SendSMS($SendTo,$SendFrom,$Msgtxt) $AccountSID = "ACbb765b3180d5938229eff8b8f63ed1bc" $AuthToken = "Auth Token number" $Data = '"https://api.twilio.com/2010-04-01/Accounts/'&$AccountSID&'/Messages.json"'& _ '-X POST \ --data-urlencode "To=+45'&$SendTo&'" \ --data-urlencode "From='&$SendFrom&'" \ --data-urlencode "Body='&$Msgtxt&'" \ -u '&$AccountSID&':'&$AuthToken&'' ShellExecute(@ScriptDir&"\curl.exe","-k "&$Data) ;~ curl 'https://api.twilio.com/2010-04-01/Accounts/ACbb765b3180d5938229eff8b8f63ed1bc/Messages.json' -X POST \ ;~ --data-urlencode 'To=+4500000000' \ ;~ --data-urlencode 'From=Reception' \ ;~ --data-urlencode 'Body=Test Body' \ ;~ -u ACbb765b3180d5938229eff8b8f63ed1bc:[AuthToken] EndFunc  
       
    • By jesus40
      Hello friends, i have a working curl command that show informations about my account on binance.com, but_it dont work with autoit code without curl.exe.
      I want to do it without curl, because the whole process much Slower_ with StdoutRead (I want get the response in variable.)
      My Curl command in Autoit:
      This 2 are works, but_ i would like to do it without curl.exe
      $apikey="XYZ" sCommand = @ScriptDir & '\curl.exe -k -H "X-MBX-APIKEY: ' & $apikey & '" -X GET "https://api.binance.com/api/v3/account?' & $request the same in .bat  file
      curl.exe -k -H "X-MBX-APIKEY: XYZ" -X GET "https://api.binance.com/api/v3/account?timestamp=1514917812000&signature=85bdee77e53cd521e1d5229fbfb459d53799c42b3fa4596d73f1520fad5f965a" (I use curl with -k option which allows curl to make insecure connections, because there is problem with the sites certificate, (cURL error 60))
       
      I tried many variations, this is the latest... I cant get the same response.
      curl $error message (I changed ): {"code":-2015,"msg":"Invalid API-key, IP, or permissions for action."}
      autoit version $error message (Response code:400): Mandatory parameter 'timestamp' was not sent, was empty/null, or malformed.
       
      $request = $query & '&signature=' & $signature $oHTTP = ObjCreate("winhttp.winhttprequest.5.1") $oHTTP.Open("GET", "https://api.binance.com/api/v3/account", False) $oHTTP.SetRequestHeader("X-MBX-APIKEY", $apikey) $oHTTP.Send($request) $oReceived = $oHTTP.ResponseText $oStatusCode = $oHTTP.Status If $oStatusCode <> 200 then MsgBox(4096, "Response code", $oStatusCode) EndIf  
      thanks
    • By wakillon
      Mp3SearchEngine v2.0.0.6

      May be some of you know Songr .
      This script do the same job, it can find more mp3 files but is not as fast as Songr.
       
       



      Sites used are music search engine Websites designed for LEGAL entertainment purposes only.
      Thanks to Brett Francis, Prog@ndy and Eukalyptus for >Bass Udf, trancex for >WinHttp Udf and the AutoIt Community for his help.

       
      Changes of v1.0.8.5
       
      Three websites replaced cause they are dead or use now js.
      All search engines updated ( not without difficulties for audiodump)
      I use RAGrid.dll for the first listview (more fast and stable, but with some inconvenients to manage the no-edit of cells)
      Input queries are saved ( the twenty latest)
      I use now an mp3 pre-Load management before playing and a double progressbar for visualize pre-load and play, where you can click for directly go play in the loaded part.
      Most includes needed are embedded and all external files are embedded in script with >BinaryToAu3Kompressor .
      Multi downloads available with embedded downloader.exe
       
      Changes of v1.0.8.8
      Search on audiodump and myfreemp3 fixed.
      New buttons.
      Added Gui Menu.
      Titles are no more editable.
      New "About" with >TaskDialog (Thanks Prog@andy)
      Query button permit now to check / uncheck all checkboxes
      And some few fixes and cleaning.
      Really more stable now.
      Changes of v1.0.9.2
      Dilandau is replaced by mp3chief and mp3ili by mp3clan 
      Search on mp3juices, baseofmp3 and soundcloud fixed.
      Soso now provide m4a (aac) instead of mp3 ( m4a can be played by MSE)
      Added possibility to encode automaticaly to mp3, aac or ogg ( at the end of download) using bassenc.dll and command line tools : lame, faac and oggenc.
       
      Changes of v1.0.9.3   mp3skull fixed mp3chief fixed myfreemp3 fixed mp3clan changed to tusmp3  mp3juices changed to emp3world baseofmp3 changed to imp3 and some minor improvements.  
      Version 2.0.0.6
      Most previous websites used are dead or have changed the way to get links, 
      so instead of try to repair the previous version, i have created a complete new version.
      The main tendency is the simplification :
      Only one website : audiodump (Up to 500 results by request)
      Script use now the little pearl created by Ward : curl.au3
      It permit to create tasks (get source and get multi mp3) in asynchronous mode.
      So now, no need to use several executables and no more gui who do not respond in case of connection problems. 
      Script use Bass.dll X86 loaded in memory for play songs.
      Result is light and fast, but don't abuse of audiodump servers who are not beasts of race.
      Warning : For avoid errors with curl.au3, you'll need to comment the line 63 : ;~ #Include <BinaryCall.au3>
      @AutoItX64 not supported and only tested on Win7X64 and Win8.1X64.
      As your browser, use Ctrl+w for remove the current Tab.(if there is no search or download running from it)
      And also Ctrl+q for set/remove Gridlines.
      Events are displayed to the bottom of the Gui.
       
      Version 2.0.1.1
      Added a Paste Button.
      Querry list is now correctly saved.
      Querry Combo is now sorted in alphabetical order
      After a 'No match', the next search will use the previous empty listview.
      Bug when removing tabs is corrected.
      Added string correction for the request that, in the previous version, was not always able to return a correct result.
       
      A big thanks to Ward for his great UDF, and Nina my favorite tester, (who between us is also my third daughter), for his precious advices .
      previous downloads : 1703
       
      As there is no more script downloads count, source and executable are available in the downloads section

      Enjoy ! 
      July 2017 Project Discontinued due to website changes
    • By 5ervant
      What's the best way to receive file from a desktop app?
      app.exe will execute a cmd with "au3file.exe /path/of/the/file.xml" and the au3file.exe will get and delete that. Or else? THE MOST IMPORTANT PART OF THE QUESTION
      And best way to transfer file to a desktop app?
      au3file.exe do a $_POST request and the app.exe MUST HAVE a local HTTP server that can receive $_POST, but it looks heavy 'cause the app must have a server such XAMPP. au3file.exe execute a cmd with "app.exe /path/of/the/file.xml" and the app.exe will now get that file and delete. Or else?  
×
×
  • Create New...