FuncExecute - Execute function without pause

[MrCreatoR]

Allows to execute function (UDF or built-in) without pausing the main script, using callback handler function to receive the return.

Notes:

Quote

* This UDF registers $WM_COPYDATA, if you or other UDF uses this message, __FE_WM_COPYDATA($hWnd, $iMsg, $wParam, $lParam) should be called from that other message function.
* This UDF uses #NoTrayIcon, to show the tray icon in your script use Opt('TrayIconHide', 0).

Example (Simple):

#include 'FuncExecute.au3'

_FuncExecute_Start('_MyCalcFunc', '3', '_Callback', 1)
_FuncExecute_Start('InputBox', 'Title|Prompt:|Text', '_Callback', 2)
_FuncExecute_Start('MsgBox', '52|FuncExecute Example #1|Simple message box, OK?', '_Callback', 3)

While _FuncExecute_Count() > 0
    Sleep(100)
WEnd

;This function get triggered only after the called function has finished
Func _Callback($sRet, $iErr, $iPID, $sFunc, $sParams, $vParam)
    Local $sMsg = StringFormat('External call...\n\tPID = %i\n\tCallback Param = %s\n\tFunc = %s\n\tParams: %s\nReturn:\n\t%s%s\nError:\n\t%i', _
        $iPID, $vParam, $sFunc, $sParams, $sRet, ($sRet = 6 ? ' (OK)' : ''), $iErr)
    
    ConsoleWrite($sMsg & @CRLF & '================================' & @CRLF & @CRLF)
EndFunc

Func _MyCalcFunc($iNumber)
    Return $iNumber & ' Is Even = ' & (Mod($iNumber, 2) = 0)
EndFunc

Example (Advanced):

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WinAPIShPath.au3>
#include 'FuncExecute.au3'

Global $aDirs[][3] = [[_WinAPI_PathCanonicalize(@AutoItExe & '\..')], [@ProgramFilesDir], [@WindowsDir], [@TempDir], [@ScriptDir]]

$hGUI = GUICreate('FuncExecute Example #2', 500, 400)

$iStart_Bttn = GUICtrlCreateButton('Get Size', 20, 20, 70, 20)
$iStop_Bttn = GUICtrlCreateButton('Stop', 100, 20, 70, 20)
GUICtrlSetState($iStop_Bttn, $GUI_DISABLE)

$iLV = GUICtrlCreateListView('Path|Size', 20, 50, 460, 310)

For $i = 0 To UBound($aDirs) - 1
    $aDirs[$i][1] = GUICtrlCreateListViewItem($aDirs[$i][0] & '|N/A', $iLV)
Next

GUICtrlSendMsg($iLV, $LVM_SETCOLUMNWIDTH, 0, 350)
GUICtrlSendMsg($iLV, $LVM_SETCOLUMNWIDTH, 1, 100)

$iStatus_Lbl = GUICtrlCreateLabel('Press "Get Size" Button', 20, 370, 460, 20)
GUICtrlSetColor($iStatus_Lbl, 0xFF0000)

GUISetState(@SW_SHOW, $hGUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            For $i = 0 To UBound($aDirs) - 1
                _FuncExecute_Stop($aDirs[$i][2])
            Next
            
            Exit
        Case $iStart_Bttn
            GUICtrlSetState($iStop_Bttn, $GUI_ENABLE)
            GUICtrlSetState($iStart_Bttn, $GUI_DISABLE)
            GUICtrlSetData($iStatus_Lbl, 'Please wait, collecting data...')
            
            For $i = 0 To UBound($aDirs) - 1
                GUICtrlSetData($aDirs[$i][1], $aDirs[$i][0] & '|Wait...')
                $aDirs[$i][2] = _FuncExecute_Start('DirGetSize', $aDirs[$i][0], '_DirSetSize_Callback', $aDirs[$i][1])
            Next
        Case $iStop_Bttn
            If MsgBox(52, 'Attention', 'Are you sure, Stop collecting data?', 0, $hGUI) <> 6 Then
                ContinueLoop
            EndIf
            
            For $i = 0 To UBound($aDirs) - 1
                If _FuncExecute_Stop($aDirs[$i][2]) Then
                    GUICtrlSetData($aDirs[$i][1], $aDirs[$i][0] & '|N/A')
                EndIf
            Next
            
            GUICtrlSetData($iStatus_Lbl, 'Press "Get Size" Button')
            GUICtrlSetState($iStop_Bttn, $GUI_DISABLE)
            GUICtrlSetState($iStart_Bttn, $GUI_ENABLE)
    EndSwitch
WEnd

Func _DirSetSize_Callback($iSize, $iErr, $iPID, $sFunc, $sParams, $iLVItemID)
    GUICtrlSetData($iLVItemID, $sParams & '|' & _ByteSuffix($iSize))
    
    If _FuncExecute_Count() <= 1 Then
        GUICtrlSetData($iStatus_Lbl, 'Done!')
        GUICtrlSetState($iStop_Bttn, $GUI_DISABLE)
        GUICtrlSetState($iStart_Bttn, $GUI_ENABLE)
    EndIf
EndFunc

Func _ByteSuffix($iBytes)
    Local $iIndex = 0, $aArray = ['bytes', 'KB', 'MB', 'GB', 'TB', 'PB', 'EB', 'ZB', 'YB']
   
    While $iBytes > 1023
        $iIndex += 1
        $iBytes /= 1024
    WEnd
    
    Return Round($iBytes, 2) & ' ' & $aArray[$iIndex]
EndFunc

 

History version:

Quote

v0.3
* Now by default the tray icon is hidden, to show it use Opt('TrayIconHide', 0). $FE_SHOWTRAYICON removed.
* Examples changed.
* Better interaction handling. Now Structures used (instead of StdOut) to pass the return value from called function.
* Added _FuncExecute_Count function to get the total count of the started functions.
* Added _FuncExecute_GetInfo function to get the info about the started function(s).
* Added support to accept 1D array from called function.

v0.2
* UDF renamed to FuncExecute.
* Examples changed.
* Better receiver handling (WM_COPYDATA usage).
* $sParams parameter in _FuncExecute_Start renamed to $sFuncParams.
+ Added optional parameter $vCallbackParam to _FuncExecute_Start function.

v0.1
* First public version.

 

FuncExecute_v0.3.zip

Edited April 23, 2020 by MrCreatoR

[ripdad]

MrCreatoR,

Thanks for this UDF -- I will put it to good use!