Simple ? JSON analyse with AutoIt - (Moved)

[ZoomTuX]

Hello, I would like to use the following JSON which I read out from an API:

[
  {
    "id": 2336916545,
    "item_id": 85016,
    "price": 103,
    "quantity": 250,
    "created": "2020-06-07T18:13:46+00:00"
  },
  {
    "id": 2336916458,
    "item_id": 85016,
    "price": 103,
    "quantity": 250,
    "created": "2020-06-07T18:13:34+00:00"
  },
  {
    "id": 2336916352,
    "item_id": 85016,
    "price": 103,
    "quantity": 250,
    "created": "2020-06-07T18:13:22+00:00"
  }
]

 

What is the easiest way to multiply "price" and "quantity" and get a total sum for the array?

Thanks for your help!

[jchd]

This should work:

Local $s = _
    '[{"id": 2336916545,"item_id": 85015,"price": 103,"quantity": 250,"created": "2020-06-07T18:13:46+00:00"},' & _
    ' {"id": 2336916458,"item_id": 85016,"price": 58,"quantity": 47,"created": "2020-06-07T18:13:34+00:00"},' & _
    ' {"id": 2336916352,"item_id": 85018,"price": 200,"quantity": 29,"created": "2020-06-07T18:13:22+00:00"}]'

Local $iTotal = Execute('0' & StringRegExpReplace($s, '.*?"price": (\d+),"quantity": (\d+).*?}]?', ' + $1 * $2'))
ConsoleWrite("Total invoice: " & $iTotal & @LF)

Will need adjust if ever you have non-integral prices or quantities. Just ask then.

[ZoomTuX]

Thank you jchd for your help. Can you also give me some information about reading out the json from the URL?

 

These are my first steps but i can't use object1 instead of your $s parameter :

 

$URL1 = "https://....."
$data1 = _INetGetSource($URL1)
$object1 = json_decode($data1)

Regards

[jchd]

I've zero idea about the content you read off this unknown website. You said you get the json text from an API.

[Melba23]

Moved to the appropriate forum, as the Developer General Discussion forum very clearly states:

Quote

General development and scripting discussions.

---

Do not create AutoIt-related topics here, use the AutoIt General Help and Support or AutoIt Technical Discussion forums.

Moderation Team

[Danp2]

It looks like you are using the JSON UDF from here. If so, it contains a helpful function named Json_Dump. There's an example of how to use it here.

[TheXman]

5 hours ago, ZoomTuX said:

What is the easiest way to multiply "price" and "quantity" and get a total sum for the array?

Below is another way to calculate the sum of price * quantity of each object in the array of objects.  It uses jq UDF.  A link to jq UDF can be found in my signature below.

#include <Constants.au3>
#include "jq.au3"         ;<== Change to your location (if necessary)


example()

Func example()
    Const $JSON_DATA = '[' & _
                         '{"id":2336916545,"item_id":85016,"price":103,"quantity":250,"created":"2020-06-07T18:13:46+00:00"},' & _
                         '{"id":2336916458,"item_id":85016,"price":103,"quantity":250,"created":"2020-06-07T18:13:34+00:00"},' & _
                         '{"id":2336916352,"item_id":85016,"price":103,"quantity":250,"created":"2020-06-07T18:13:22+00:00"}'  & _
                       ']'

    Local $sCmdOutput = ""

    _jqInit()
    If @error Then Exit MsgBox($MB_ICONERROR, "ERROR", "Unable to initialize jq. @error = " & @error)

    $sCmdOutput = _jqExec($JSON_DATA, "map(.price * .quantity) | add")
    If @error Then Exit MsgBox($MB_ICONERROR, "ERROR", "Error executing jq filter. @error = " & @error)

    ConsoleWrite("Sum of all price * quantity = " & StringFormat("%.2f", $sCmdOutput) & @CRLF)
EndFunc

Output:

Sum of all price * quantity = 77250.00

 

Edited June 8, 2020 by TheXman