send command line to VLC with it open

[Belini]

when I go to display and choose console I can control VLC by command line by typing in its console window, does anyone know if there is any way to send the commands directly without opening the console window and without having to close and reopen vlc to send the command?

Edited February 27, 2022 by Belini

[Belini]

I managed to do what I wanted by making the command window invisible but I still wanted to find a way to send commands directly to vlc without having to use its console window.

if ProcessExists("vlc.exe") then 

WinSetTrans("[CLASS:ConsoleWindowClass]", "", 0)

ControlSend("[CLASS:ConsoleWindowClass]", '', '', "f on  " & "{enter}"); Fullscreen on
Sleep(1000)
ControlSend("[CLASS:ConsoleWindowClass]", '', '', "f off  " & "{enter}"); Fullscreen off

endif

 

[caramen]

This is a solution I get from this post :

And I had this script from the topic : (Whitch helped me a lot in lot of similar situation.)

It could react the same with your shell console. You have to redefine the code as you need.

expandcollapse popup

#include <constants.au3>
#include <string.au3>
#RequireAdmin

; Use RunAs if you want use a fixed username/password within the script:
; Global $hPowerShellPID = RunAs("UserName", "Domain", "Password", "", "powershell.exe", '', @SW_HIDE, BitOR($STDIN_CHILD, $STDERR_MERGED))

; or use #RequireAdmin and a simple Run Statement to enter Admin credentials (if needed) at runtime
; Here we start a "permanent" powershell prompt with redirected streams
Global $hPowerShellPID = Run("powershell.exe", '', @SW_HIDE, BitOR($STDIN_CHILD, $STDERR_MERGED))

; this little loop is to wait for the "welcome" message from powershell
; just a way to be sure that the powershell is running and "streaming"
Do
    StdoutRead($hPowerShellPID)
Until @extended ; out stream started

; example:
; Here we "execute a command via the Powershell that is running in background...
; ...and we get back to resulting output
Local $Out = _Run_Cmdlet("Get-ItemPropertyValue 'Registry::HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System' -Name 'EnableLUA'", $hPowerShellPID)
ConsoleWrite($Out)

; here another command
ConsoleWrite(_Run_Cmdlet("dir c:\", $hPowerShellPID))

; .... and so on ...

; this function execute the passed powershell command and returns the resulting output
Func _Run_Cmdlet($sCmd, ByRef $hPS)
    Local $sStdOut = ''
    ; we insert a start and an end message in order to identify the "body" of the result of the command executed
    $sCmd = 'write-host "->StartOfStream<-"; ' & $sCmd & '; write-host "->EndOfStream<-"' & @CRLF
    StdinWrite($hPS, $sCmd)
    Do
        Sleep(250)
        $sStdOut &= StdoutRead($hPS)
        ; the presence of the known end message signals the end of the execution
    Until StringInStr($sStdOut, "->EndOfStream<-" & @LF)
    ; return only the body of the outpu of the passed command
    Return _StringBetween($sStdOut, "->StartOfStream<-" & @LF, "->EndOfStream<-" & @LF)[0]
EndFunc   ;==>_Run_Cmdlet

I'm sure you could done your goal with this

 

Enjoy.

Thanks @Gianni btw.

Edited March 5, 2022 by caramen

[Belini]

Thanks for the tip @caramen but I've already managed to send all the commands I need using the vlc console itself, for sure what you posted will be useful for other things and I'll do tests with it.

ShellExecute("vlc.exe", "vlc -I rc", @ScriptDir); open vlc console without opening its graphical interface
Sleep(200)
WinSetTrans("[CLASS:ConsoleWindowClass]", '', 0); make the console window invisible
Sleep(3000)
ControlSend("[CLASS:ConsoleWindowClass]", '', '', "f on " & "{enter}"); put the video in full screen
Sleep(3000)
ControlSend("[CLASS:ConsoleWindowClass]", '', '', "f off " & "{enter}"); put the video in windowed mode

 

Edited March 5, 2022 by Belini

[ad777]

@Belini

better way is to replace:

 WinSetTrans 

to:

 

WinSetState

script:

ShellExecute("vlc.exe", "vlc -I rc", @ScriptDir); open vlc console without opening its graphical interface
Sleep(200)
WinSetState("[CLASS:ConsoleWindowClass]","",@SW_HIDE)
Sleep(3000)
ControlSend("[CLASS:ConsoleWindowClass]", '', '', "f on " & "{enter}"); put the video in full screen
Sleep(3000)
ControlSend("[CLASS:ConsoleWindowClass]", '', '', "f off " & "{enter}"); put the video in windowed mode

[Belini]

thanks for the tip @ad777 I will do as you suggested.