How to embed a FileSelectFolder into a form?

[tonyh]

Hi

Im new to autoit so take it easy on me.

How can i create a form with a FileSelectFolder box embeded into the form. I hope that makes sense. That is i would like a form and as part of that form I would like a FileSelectFolder as part of the form. Thats if its possible.

many thanks

Tony

[BrettF]

Like a treeveiw?

[tonyh]

Yeah sort of. But i want to display the drives and folders. As in the FileSelectFolder option.

I dont know if its possible to do!

[BrettF]

You'll have to create a GUI with a treeview, and then get all the drive files put into the treeview.

[tonyh]

You'll have to create a GUI with a treeview, and then get all the drive files put into the treeview.

Thanks Bert - thanks what i want to do - i dont seem to to able to get the code right .

[BrettF]

Any Code??

[MrCreatoR]

I have try to do this, but i have a problem - if someone can help me here, i think that i can solve this problem.

Here is a have-done script:

expandcollapse popup

#include <GUIConstants.au3>
#include <GUITreeView.au3>
#include <File.au3>
Opt("GuiOnEventMode", 1)

$Path = _FileSelectFolder("Select Folder", "Choose needed Path:", 300, 300)

If Not @error Then MsgBox(64, "Path", "The selected path is: <" & $Path & ">")

Func _FileSelectFolder($Title, $Dialog_Text, $Width=300, $Heght=300)
    Global $IsExit = 0, $IsCancel = 0, $PathInput, $MainTreeViewID
    GUICreate($Title, $Width, $Heght, -1, -1, $WS_SYSMENU+$WS_CAPTION+$WS_SIZEBOX, $WS_EX_CONTEXTHELP)
    GUISetOnEvent(-3, "Cancel")
    
    GUICtrlCreateLabel($Dialog_Text, 10, 5)

    $ButtonOK = GUICtrlCreateButton("OK", $Width-180, $Heght-25, 70, 20)
    GUICtrlSetOnEvent(-1, "OK")
    
    $ButtonCancel = GUICtrlCreateButton("Cancel", $Width-80, $Heght-25, 70, 20)
    GUICtrlSetOnEvent(-1, "Cancel")
    
    $PathInput = GUICtrlCreateInput("", 10, $Heght-50, $Width-20)

    $MainTreeViewID = GUICtrlCreateTreeView(10, 30, $Width-20, $Heght-90, BitOr($TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS), $WS_EX_CLIENTEDGE)

    GUISetState()

    $DrivesArr = _DrivesListToArray("all")
    If IsArray($DrivesArr) Then
        Dim $MainDriveID[$DrivesArr[0]+1], $CurrentIcon, $CurrentIcID
        For $i = 1 To $DrivesArr[0]
            $CurrentDrive = $DrivesArr[$i]
            If $CurrentDrive <> "a:" And $CurrentDrive <> "b:" Then
                $CurrentIcon = $CurrentDrive & "\" & IniRead($CurrentDrive & "\Autorun.inf", "Autorun", "Icon", "")
                $CurrentIcID = 0
            EndIf
            If Not FileExists($CurrentIcon) Then
                $CurrentIcon = "shell32.dll"
                $CurrentIcID = 8
            EndIf
            $MainDriveID[$i] = GUICtrlCreateTreeViewItem(StringUpper($CurrentDrive) & "\", $MainTreeViewID)
            GUICtrlSetOnEvent(-1, "GetText")
            
            If $CurrentDrive = "a:" Or $CurrentDrive = "b:" Then
                GUICtrlSetImage(-1, "shell32.dll", 6, 0)
            ElseIf DriveGetType($CurrentDrive) = "CDROM" Then
                GUICtrlSetImage(-1, "shell32.dll", 11, -1)
            Else
                GUICtrlSetImage(-1, StringStripWS($CurrentIcon, 3), $CurrentIcID, -1)
            EndIf
            
            If $CurrentDrive <> "a:" And $CurrentDrive <> "b:" Then
                $DirsArr = _FileListToArray($CurrentDrive, "*", 2)
                If IsArray($DirsArr) Then
                    For $j = 1 To $DirsArr[0]
                        $CurrentDir = $DirsArr[$j]
                        GUICtrlCreateTreeViewItem($CurrentDir, $MainDriveID[$i])
                        GUICtrlSetOnEvent(-1, "GetText")
                        _GUICtrlTreeViewSetIcon($MainTreeViewID, -1, "shell32.dll", 4)
                    Next
                EndIf
            EndIf
        Next
    EndIf

    While $IsExit = 0
        Sleep(10)
    WEnd
    $Path = StringReplace(_GUICtrlTreeViewGetTree($MainTreeViewID, "\"), "\\", "\")
    GUIDelete()
    If $IsCancel = 1 Then
        SetError(1)
        Return ""
    Else
        Return $Path
    EndIf
EndFunc

Func GetText()
    GUICtrlSetData($PathInput, GUICtrlRead(@GUI_CtrlId, 1))
EndFunc

Func OK()
    Global $IsExit = 1
EndFunc

Func Cancel()
    Global $IsExit = 1, $IsCancel = 1
EndFunc

Func Quit()
    Exit
EndFunc

Func _DrivesListToArray($Type)
    $DrivesArr = DriveGetDrive($Type)
    If IsArray($DrivesArr) Then
        Dim $DrivesListArr[$DrivesArr[0]+1]
        $DrivesListArr[0] = $DrivesArr[0]
        For $iDrive = 1 To $DrivesArr[0]
            $CurrentDrive = $DrivesArr[$iDrive]
            $DrivesListArr[$iDrive] = $CurrentDrive
        Next
    EndIf
    Return $DrivesListArr
EndFunc

Edited February 12, 2007 by MsCreatoR