check if user is idle ?

[Kiesp]

Hey!

I was thinking, is it possible to detect if the user if afk or idle.. i made this program and it takes alot of the cpu, and that ok.. im fine with that. but i only want to run it when im not using the computer or watching a movie on it.. but is that possible ? and if it is.. how ?

I could ofc use _ispressed on every key.. but that might take a while.. is there another way ?

-Kiesp

[alex OF DEATH]

$counter = 0
$SecondsUntilConsideredAFK = 5
while 1
    $mouse1 = mousegetpos(0)
    sleep(10)
    $mouse2 = mousegetpos(0)
    if $mouse1 = $mouse2 then $counter = $counter+1
    if $counter = $SecondsUntilConsideredAFK then msgbox(1,"","I'm AFK lol")
    sleep(990)
wend

Edited November 13, 2007 by alex OF DEATH

[MrCreatoR]

i made this program and it takes alot of the cpu

Perhaps you should use Sleep(10) inside your main loop.

Here is one method to check idle:

expandcollapse popup

#include <Date.au3>

$IdleMinimum = 50

While 1
    $iIdle = _IdleWaitStart ($IdleMinimum)
    ConsoleWrite (_Now() & ' ' & @UserName & ' not active ' & _TickToTimeString ($iIdle) & @CRLF)
    $iIdle = _IdleWaitCommit($IdleMinimum)
    ConsoleWrite (_Now() & ' ' & @UserName & ' was not active ' & _TickToTimeString ($iIdle) & @CRLF)
Wend


Func _IdleWaitStart($idlesec)
    Local $aRet, $iSave, $iTick, $LastInputInfo = DllStructCreate ("uint;dword")
    DllStructSetData ($LastInputInfo, 1, DllStructGetSize ($LastInputInfo))
    DllCall ("user32.dll", "int", "GetLastInputInfo", "ptr", DllStructGetPtr ($LastInputInfo))
    Do
        Sleep(200)
        $iSave= DllStructGetData ($LastInputInfo, 2)
        DllCall ("user32.dll", "int", "GetLastInputInfo", "ptr", DllStructGetPtr ($LastInputInfo))
        $aRet = DllCall ("kernel32.dll", "long", "GetTickCount")
    Until ($aRet[0] - DllStructGetData ($LastInputInfo, 2))> $idlesec
    Return $aRet[0] - DllStructGetData ($LastInputInfo, 2)
EndFunc

Func _IdleWaitCommit($idlesec)
    Local $iSave, $LastInputInfo = DllStructCreate ("uint;dword")
    DllStructSetData ($LastInputInfo, 1, DllStructGetSize ($LastInputInfo))
    DllCall ("user32.dll", "int", "GetLastInputInfo", "ptr", DllStructGetPtr ($LastInputInfo))
    Do
        $iSave = DllStructGetData ($LastInputInfo, 2)
        Sleep(200)
        DllCall ("user32.dll", "int", "GetLastInputInfo", "ptr", DllStructGetPtr ($LastInputInfo))
    Until (DllStructGetData ($LastInputInfo, 2)-$iSave) > $idlesec
    Return DllStructGetData ($LastInputInfo, 2)-$iSave
EndFunc

Func _TickToTimeString($iTicks)
    Local $iHours, $iMins, $iSecs, $sText = ''
    _TicksToTime ($iTicks, $iHours, $iMins, $iSecs)
    If $iHours Then $sText = $iHours & ' hours '
    If $iMins Then $sText &= $iMins & ' minute(s) '
    If $iSecs Then $sText &= $iSecs & ' second(s)'
    If $sText = '' Then $sText = 'less then second'
    Return $sText
EndFunc