Newbie Question

[S0uL]

Sorry im new. iwannto ask how can i make stop, puase , exit button for script im so sory again i wantto trybut i cant do it.

[SpookMeister]

Please post whatever code you have at this point so we have something to work with.

If you just want some pointers.... look at Exit and HotKeySet() in the help file

Edited December 12, 2007 by SpookMeister

[John117]

do you really want buttons like on a gui? or just keyboard shortcuts? like hit esc to exit, 1 to play, 2 to pause . . .

both should be very easy with while statement.

[S0uL]

Sorry im new. iwannto ask how can i make stop, puase , exit button for script im so sory again i wantto trybut i cant do it.

i dont wat to hot key just make button stop pause and exit script

[John117]

If you wanted hotkeys

expandcollapse popup

Opt("GUIOnEventMode", 1)
HotKeySet("{ESC}", "_Custom_Exit")
HotKeySet("{LEFT}", "_Pause")
HotKeySet("{RIGHT}", "_Play")
Global $Play = True
;GUICreate ( "title" [, width [, height [, left [, top [, style [, exStyle [, parent]]]]]]] )
$GUI = GUICreate("Example", 110, 100)

;GUICtrlCreateButton ( "text", left, top [, width [, height [, style [, exStyle]]]] )
Global $Play_Button = GUICtrlCreateButton("Play", 10, 10, 90, 24)
GUICtrlSetOnEvent(-1, "_Play")

Global $Pause_Button = GUICtrlCreateButton("Pause", 10, 35, 90, 24)
GUICtrlSetOnEvent(-1, "_Pause")

Global $Exit_Button = GUICtrlCreateButton("Exit", 10, 60, 90, 24)
GUICtrlSetOnEvent(-1, "_Custom_Exit")

GUISetState(@SW_SHOW, $GUI)

; ============================================================================
; Main Loop
; ============================================================================
While 1
    Sleep(10)
    If $Play = True Then
        ToolTip("Playing")
    Else
        ToolTip("Paused")
    EndIf
WEnd
; ============================================================================
; Functions
; ============================================================================

Func _Play()
    $Play = True
EndFunc   ;==>_Play

Func _Pause()
    $Play = False
EndFunc   ;==>_Pause

Func _Custom_Exit()
    Exit
EndFunc   ;==>_Custom_Exit

Edited December 12, 2007 by Hatcheda

[S0uL]

Sorry im new. iwannto ask how can i make stop, puase , exit button for script im so sory again i wantto trybut i cant do it.

MsgBox(0,"Macro"," By S0uL")

Sleep(500)

#include <GuiConstants.au3>

GuiCreate("Macro", 601, 124,-1, -1 , BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS))

GuiSetState()

WinMove("Macro", "", 430, 320, 207,210)

; PIC

GuiCtrlCreatePic("menu.jpg",0,0, 207,157)

; START BUTTON

$Button_1 = GuiCtrlCreateButton("Start",0, 160,30)

GUICtrlSetState( $Button_1, $GUI_FOCUS)

; STOP BUTTON

$Button_2 = GuiCtrlCreateButton("Stop", 40,160,30)

; EXIT BUTTON

$Exit = GUICtrlCreateButton("Exit", 80, 160, 30)

GUISetState()

While 1

$msg = GUIGetMsg()

Send("a1s1a2s3w3")

WinActivate("MAcro")

Select

Case $msg = $GUI_EVENT_CLOSE

Exit

Case $msg = $Exit

Exit

Case $msg = $Button_1

EndSelect

wend

[John117]

ok you should easily be able to work that in at this point with what you see above.

[SpookMeister]

expandcollapse popup

#include <GuiConstants.au3> ; always put your include statements at the very begining of a script


MsgBox(0, "Macro", " By S0uL")
Sleep(500)


GUICreate("Macro", 601, 124, -1, -1, BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS))
GUISetState()
WinMove("Macro", "", 430, 320, 207, 210)

; PIC
GUICtrlCreatePic("menu.jpg", 0, 0, 207, 157)
; START BUTTON
$Button_1 = GUICtrlCreateButton("Start", 0, 160, 30)
GUICtrlSetState($Button_1, $GUI_FOCUS)

; STOP BUTTON
$Button_2 = GUICtrlCreateButton("Stop", 40, 160, 30)

; EXIT BUTTON
$Exit = GUICtrlCreateButton("Exit", 80, 160, 30)
GUISetState()

$Paused = 0

While 1
    $msg = GUIGetMsg()

    ; WinActivate("MAcro")  ; I dont think this is needed
    Select
        Case $msg = $GUI_EVENT_CLOSE
            Exit
        Case $msg = $Exit
            Exit
        Case $msg = $Button_1
            $Paused = 0
        Case $msg = $Button_2
            $Paused = 1
    EndSelect
    
    If $Paused = 0 Then
        ToolTip("Running") ; You can put your Send("a1s1a2s3w3") here
    Else
        ToolTip("Paused")
    EndIf
    Sleep(10) ; to keep from using 100% CPU
WEnd

Edited December 13, 2007 by SpookMeister