_ClipPutFile doesn't work - need help !

[dost0011]

The small skript doesn't work...

-------------- Skript start -----------------

#include "misc.au3"

$fTest = _ClipPutFile ("C:\background01.jpg")

If Not $fTest Then

MsgBox(0,"_ClipPutFile() call Failed","@error = " & @error)

Else

MsgBox(0,"_ClipPutFile()",ClipGet())

EndIf

--------------- Skript end ------------------

Result:

A Window with "background01.jpg".

I would have expected "C:\background01.jpg".

If the Path is "background01.jpg" I get the Window with "ckgroun01.jpg".

If I want to paste the clipboard now to anyplace with <Strg v>

I get the message: "Datei kann nicht kopiert werden: Die Quelldatei oder

vom Quelldatenträger kann nicht gelesen werden"

On Englisch :-) Can't read the file...

What is wrong ?

Many thanks.

I have installed Version 3.2.10 (overwrite from Version 3.1.?)

[MrCreatoR]

I can confirm - there is a bug in AutoIt 3.2.10.0, to fix it there is need to replace this line (inside _ClipPutFile() funcntion ) :

DllStructSetData($DROPFILES, 1, DllStructGetSize($DROPFILES) - StringLen($sFile))

by this:

DllStructSetData($DROPFILES, 1, DllStructGetSize($DROPFILES) - StringLen($sFile) - 2)

As you can see, i added only the - 2 ... not stable, better wait to answer here .

Edited December 30, 2007 by MsCreatoR

[DW1]

Minus 3 right?

minus two gives me ":\filename.ext"

minus three gives me "C:\filename.ext"

[MrCreatoR]

Minus 3 right?

It's unstable, there must be another way, in some cases -3 will put wrong string to clipboard, but the same can happend with -2 ...

P.S

I made a bug report on this one.

[dost0011]

It's unstable, there must be another way, in some cases -3 will put wrong string to clipboard, but the same can happend with -2 ...

P.S

I made a bug report on this one.

Many thanks !

Do you know any other possibility to copy a File to the clipboard, to make ist available for other Windows Application ?

[GaryFrost]

Replace the function in Misc.au3 with

expandcollapse popup

Func _ClipPutFile($sFile, $sSeperator = "|")
    Local $vDllCallTmp, $nGlobMemSize, $hGlobal, $DROPFILES, $i, $hLock
    Local $GMEM_MOVEABLE = 0x0002, $CF_HDROP = 15

    $sFile &= $sSeperator & $sSeperator
    $nGlobMemSize = (StringLen($sFile) + 20)
    $vDllCallTmp = DllCall("user32.dll", "int", "OpenClipboard", "hwnd", 0)

    If @error Or $vDllCallTmp[0] = 0 Then Return SetError(1, 1, False)

    $vDllCallTmp = DllCall("user32.dll", "int", "EmptyClipboard")
    If @error Or $vDllCallTmp[0] = 0 Then Return SetError(2, 2, False)

    $vDllCallTmp = DllCall("kernel32.dll", "hwnd", "GlobalAlloc", "int", $GMEM_MOVEABLE, "int", $nGlobMemSize)
    If @error Or $vDllCallTmp[0] < 1 Then Return SetError(3, 3, False)

    $hGlobal = $vDllCallTmp[0]
    $vDllCallTmp = DllCall("kernel32.dll", "hwnd", "GlobalLock", "long", $hGlobal)
    If @error Or $vDllCallTmp[0] < 1 Then Return SetError(4, 4, False)

    $hLock = $vDllCallTmp[0]
    $DROPFILES = DllStructCreate("dword;ptr;int;int;int;char[" & StringLen($sFile) + 1 & "]", $hLock)
    If @error Then Return SetError(5, 6, False)

    Local $tempStruct = DllStructCreate("dword;ptr;int;int;int")

    DllStructSetData($DROPFILES, 1, DllStructGetSize($tempStruct))
    DllStructSetData($DROPFILES, 2, 0)
    DllStructSetData($DROPFILES, 3, 0)
    DllStructSetData($DROPFILES, 4, 0)
    DllStructSetData($DROPFILES, 5, 0)
    DllStructSetData($DROPFILES, 6, $sFile)
    For $i = 1 To StringLen($sFile)
        If DllStructGetData($DROPFILES, 6, $i) = $sSeperator Then DllStructSetData($DROPFILES, 6, Chr(0), $i)
    Next

    $vDllCallTmp = DllCall("user32.dll", "long", "SetClipboardData", "int", $CF_HDROP, "long", $hGlobal)
    If @error Or $vDllCallTmp[0] < 1 Then Return SetError(6, 6, False)
    $vDllCallTmp = DllCall("user32.dll", "int", "CloseClipboard")
    If @error Or $vDllCallTmp[0] = 0 Then Return SetError(7, 7, False)
    $vDllCallTmp = DllCall("kernel32.dll", "int", "GlobalUnlock", "long", $hGlobal)
    If @error Then Return SetError(8, 8, False)
    $vDllCallTmp = DllCall("kernel32.dll", "int", "GetLastError")
    If $vDllCallTmp = 0 Then Return SetError(8, 9, False)
    Return True
EndFunc   ;==>_ClipPutFile