Get Notification while user select ListView items

[MrCreatoR]

Hi,

I need to call some function while user is selecting listview items, i know that there is $LVN_MARQUEEBEGIN event, but that's only when user starts to select, and i need to catch the period of time that user actualy selecting the items...

Somethink like this:

expandcollapse popup

#include <GuiConstants.au3>
#include <GuiListView.au3>

GUICreate("LV Get Selected Notification", 400, 300)
$hListView = GUICtrlCreateListView("Column1|Column2", 2, 2, 394, 268, $LVS_SHOWSELALWAYS)

GUICtrlCreateListViewItem("Item1|SubItem1", $hListView)
GUICtrlCreateListViewItem("Item2|SubItem2", $hListView)

$Status_Mark = 0
$Status_Label = GUICtrlCreateLabel("", 20, 280, 200)

GUISetState()

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")


While GUIGetMsg() <> $GUI_EVENT_CLOSE
    If $Status_Mark = 1 Then
        GUICtrlSetData($Status_Label, "")
        $Status_Mark = 0
    EndIf
WEnd

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView
    $hWndListView = $hListView
    If Not IsHWnd($hListView) Then $hWndListView = GUICtrlGetHandle($hListView)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $NM_CUSTOMDRAW
                    ;If $Status_Mark = 0 Then
                        GUICtrlSetData($Status_Label, "Selecting....")
                        ;$Status_Mark = 1
                    ;EndIf
                Case $LVN_MARQUEEBEGIN
                    ConsoleWrite("Selecting BEGIN" & @LF)
            EndSwitch
    EndSwitch
    
    Return $GUI_RUNDEFMSG
EndFunc

Now the status update once we hovering the items, if we uncomment the lines with $Status_Mark, it will updated only while we selecting the items, but i need that this will happen without any "marks" and only by notification, so my function will not bein called when it's not needed.

Is it possible?

Thanks.

Edited January 15, 2008 by MsCreatoR

[GaryFrost]

$LVN_ITEMCHANGED

[MrCreatoR]

Thanks.

But this event is called even if i press on item/check item, and i need only when the selecting box is there (user selecting items)...

[Siao]

but i need that this will happen without any "marks" and only by notification

So does this mean when converted to human language, that you don't want to use global variable?

Because if doesn't, set the global flag upon LVN_MARQUEEBEGIN, reset it upon NM_RELEASEDCAPTURE. Process the item change notifications only if flag is set.

Edited January 15, 2008 by Siao

[MrCreatoR]

set the global flag upon LVN_MARQUEEBEGIN, reset it upon NM_RELEASEDCAPTURE. Process the item change notifications only if flag is set

It work, but only if i call the function from the WM_NOTIFY, and i can not do that, because the called function trigger many operations, it's slowing down the main handler process, and the selection is bein a little ugly

expandcollapse popup

#include <GuiConstants.au3>
#include <GuiListView.au3>

Global $IsSelectingBegin = False

GUICreate("LV Get Selected Notification", 400, 300)
$hListView = GUICtrlCreateListView("Column1|Column2", 2, 2, 394, 268, $LVS_SHOWSELALWAYS)

GUICtrlCreateListViewItem("Item1|SubItem1", $hListView)
GUICtrlCreateListViewItem("Item2|SubItem2", $hListView)

$Status_Label = GUICtrlCreateLabel("", 20, 280, 200)

GUISetState()

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")


While GUIGetMsg() <> $GUI_EVENT_CLOSE
    If Not $IsSelectingBegin Then
        GUICtrlSetData($Status_Label, "")
    Else
        ;uncomment this, and... (see WM_NOTIFY -> $LVN_MARQUEEBEGIN)
        ;MyFunc()
    EndIf
WEnd

Func MyFunc()
    GUICtrlSetData($Status_Label, "Selecting....")
EndFunc

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView
    $hWndListView = $hListView
    If Not IsHWnd($hListView) Then $hWndListView = GUICtrlGetHandle($hListView)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $LVN_MARQUEEBEGIN
                    $IsSelectingBegin = True
                    MyFunc() ;...comment this
                Case $NM_RELEASEDCAPTURE
                    $IsSelectingBegin = False
            EndSwitch
    EndSwitch
    
    Return $GUI_RUNDEFMSG
EndFunc

It works as you can see, but then follow the comments, and you will see that this will not work

[Siao]

GUI is "frozen" as long as a mouse button is down (aka capture), so you won't ever get what you want to work from the main loop.

[MrCreatoR]

GUI is "frozen" as long as a mouse button is down (aka capture), so you won't ever get what you want to work from the main loop.

You right, thanks

I figured this out using cakllback timer

expandcollapse popup

#include <GuiConstants.au3>
#include <GuiListView.au3>

Global $IsSelectingBegin = False
Global $ah_Timer

GUICreate("LV Get Selected Notification", 400, 300)
$hListView = GUICtrlCreateListView("Column1|Column2", 2, 2, 394, 268, $LVS_SHOWSELALWAYS)

GUICtrlCreateListViewItem("Item1|SubItem1", $hListView)
GUICtrlCreateListViewItem("Item2|SubItem2", $hListView)

$Status_Label = GUICtrlCreateLabel("", 20, 280, 200)

GUISetState()

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

While GUIGetMsg() <> $GUI_EVENT_CLOSE
WEnd

Func MyFunc($hWnd, $iMsg, $iwParam, $ilParam)
    If GUICtrlRead($Status_Label) <> "Selecting...." Then GUICtrlSetData($Status_Label, "Selecting....")
EndFunc

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView = $hListView
    If Not IsHWnd($hListView) Then $hWndListView = GUICtrlGetHandle($hListView)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $LVN_MARQUEEBEGIN
                    If Not $IsSelectingBegin Then
                        $ah_Timer = _TimerStart("MyFunc", 10)
                        $IsSelectingBegin = True
                    EndIf
                Case $NM_RELEASEDCAPTURE
                    If $IsSelectingBegin Then
                        _TimerStop($ah_Timer[0], $ah_Timer[1])
                        $IsSelectingBegin = False
                        GUICtrlSetData($Status_Label, "")
                    EndIf
            EndSwitch
    EndSwitch
    
    Return $GUI_RUNDEFMSG
EndFunc

Func _TimerStart($sFunction, $iTime=250)
    Local $hCallBack = DllCallbackRegister($sFunction, "none", "hwnd;int;int;dword")
    
    Local $aDll = DllCall("user32.dll", "int", "SetTimer", _
        "hwnd", 0, _
        "int", TimerInit(), _
        "int", $iTime, _
        "ptr", DllCallbackGetPtr($hCallBack))
    
    Local $aRet[2] = [$hCallBack, $aDll[0]]
    Return $aRet
EndFunc

Func _TimerStop($hCallBack, $hTimer)
    DllCallBackFree($hCallBack)
    Local $aRet = DllCall("user32.dll", "int", "KillTimer", "hwnd", 0, "int", $hTimer)
    Return $aRet[0]
EndFunc

Thanks Gary and Siao for your help!

I think the issue is [sOLVED]

[MrCreatoR]

Here is an example of what i really needed at the end:

expandcollapse popup

#include <GuiConstants.au3>
#include <GuiListView.au3>

Global $IsSelectingBegin = False
Global $ah_Timer

GUICreate("LV Get Selected Notification", 400, 300)
$hListView = GUICtrlCreateListView("Column1|Column2", 5, 5, 390, 150, $LVS_SHOWSELALWAYS)

GUICtrlCreateListViewItem("Item1|SubItem1", $hListView)
GUICtrlCreateListViewItem("Item2|SubItem2", $hListView)

GUICtrlCreateLabel("Selection:", 5, 165)
GUICtrlSetFont(-1, 9, 800)
$Selection_Edit = GUICtrlCreateEdit("", 5, 180, 390, 110)

GUISetState()

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

While GUIGetMsg() <> $GUI_EVENT_CLOSE
WEnd

Func MyFunc($hWnd, $iMsg, $iwParam, $ilParam)
    Local $aSelected_Indices = _GUICtrlListView_GetSelectedIndices($hListView, 1)
    Local $sSelected_Items = ""
    Local $sEdit_Content = GUICtrlRead($Selection_Edit)
    
    For $i = 1 To UBound($aSelected_Indices)-1
        $sSelected_Items &= _GUICtrlListView_GetItemText($hListView, $aSelected_Indices[$i]) & @CRLF
    Next
    
    $sSelected_Items = StringStripWS($sSelected_Items, 3)
    If $sEdit_Content <> $sSelected_Items Then GUICtrlSetData($Selection_Edit, $sSelected_Items)
EndFunc

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView = $hListView
    If Not IsHWnd($hListView) Then $hWndListView = GUICtrlGetHandle($hListView)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $LVN_MARQUEEBEGIN
                    If Not $IsSelectingBegin Then
                        $ah_Timer = _TimerStart("MyFunc", 10)
                        $IsSelectingBegin = True
                    EndIf
                Case $NM_RELEASEDCAPTURE
                    If $IsSelectingBegin Then
                        _TimerStop($ah_Timer[0], $ah_Timer[1])
                        $IsSelectingBegin = False
                        GUICtrlSetData($Selection_Edit, "")
                    EndIf
            EndSwitch
    EndSwitch
    
    Return $GUI_RUNDEFMSG
EndFunc

Func _TimerStart($sFunction, $iTime=250)
    Local $hCallBack = DllCallbackRegister($sFunction, "none", "hwnd;int;int;dword")
    
    Local $aDll = DllCall("user32.dll", "int", "SetTimer", _
        "hwnd", 0, _
        "int", TimerInit(), _
        "int", $iTime, _
        "ptr", DllCallbackGetPtr($hCallBack))
    
    Local $aRet[2] = [$hCallBack, $aDll[0]]
    Return $aRet
EndFunc

Func _TimerStop($hCallBack, $hTimer)
    DllCallBackFree($hCallBack)
    Local $aRet = DllCall("user32.dll", "int", "KillTimer", "hwnd", 0, "int", $hTimer)
    Return $aRet[0]
EndFunc

[Xandl]

Hello,

this is a nice solution, but I really would like to have an event driven way,

where the listview id can be local, and does not have to be in the global scope.

I read something about user parameters for callbacks, but I am neither sure

if it would help, nor if it is going to be implemented.

ciao

Xandl