Removing characters from the end of a file?

[AzKay]

Ive wanted to make a function to add/remove 0x0 from files, until the size is X.

Ive got;

$File = ""
$Bytes = ""

Do
    $File = FileOpen($File, 1+16)
    FileWrite($File, 0)
    FileClose($File)
Until FileGetSize($File) == $Bytes

But, this only makes the file bigger.

I want to do the reverse, remove the last characters until its X size.

[ProgAndy]

$FilePAth = ""
$Bytes = ""
$File = FileOpen($FilePAth, 1+16)
$File2 = FileOPen($FilePAth&".tmp", 1+16)
FileWrite($File2,FileRead($File,$bytes)) ; Reads Given amount of bytes and writes them to an new File
FileClose($file)
FileClose($file2)
FileDelete($FilePATH)
FileMove($FilePATH&".tmp",$FILEPATH)

[AzKay]

Thanks :3

[AzKay]

Know of a more memory efficient way?

I just tried it on an 800mb file, and itll just hang.

Also, using making the computer go really slow.

Requiring me to restart, because nor taskmanager, or process explorer, would kill it.

[AzKay]

Hmm, I ended up using some VB6 code.

If anyones interested, I could rewrite it in autoit.

[Siao]

Know of a more memory efficient way?

Bunch of DllCalls to WinAPI functions: CreateFile+SetFilePointer+SetEndOfFile+CloseHandle

[zorphnog]

Maybe something like this:

Func _FileSplit($sFilename, $iOutfileBytes)
    Local $hInfile, $iInfileBytes, $sFile, $i=0
    $iInfileBytes = FileGetSize($sFilename)

    If $iInfileBytes > $iOutfileBytes Then
        $hInfile = FileOpen($sFilename, 16)
        $sFile = FileRead($hInfile, $iOutfileBytes)
        While @error <> -1
            $i += 1
            FileWrite(StringFormat($sFilename & ".%04d",$i), $sFile)
            $sFile = FileRead($hInfile, $iOutfileBytes)
        WEnd
    EndIf
EndFunc

[AzKay]

Bunch of DllCalls to WinAPI functions: CreateFile+SetFilePointer+SetEndOfFile+CloseHandle

Yeah, Thats the VB6 code I used.

Not quite working out in autoit though, It keeps giving me "unknown revision", Or something along those lines.

[AzKay]

K, Scrapped half the DLLCalls, Founds them in the _WinAPI_ functions.

Used those instead, Finnished product:

#Include <WinAPI.au3>

SetFileSize("test.txt", 6)

Func SetFileSize($FileName, $newSize)
    $fileHandle = _WinAPI_CreateFile($FileName, 2)
    DllCall("kernel32.dll", "long", "SetFilePointer", "long", $fileHandle, "long", $newSize, "long", 0, "long", 0)
    DllCall("kernel32.dll", "long", "SetEndOfFile", "long", $fileHandle)
    _WinAPI_CloseHandle($fileHandle)
EndFunc

:3