controls on tabs don't hide

[dinodod]

I'm having an odd issue where I have several tabs in my GUI and when i click to change tabs, the controls don't hide. I end up having a merging of the 2 tabs and I was wondering if anyone knew how to correct this?

I know it sounds odd. Is there any way to 'trace' the issue to find the cause or is this a known issue?

Thanks!

[GaryFrost]

I'm having an odd issue where I have several tabs in my GUI and when i click to change tabs, the controls don't hide. I end up having a merging of the 2 tabs and I was wondering if anyone knew how to correct this?

I know it sounds odd. Is there any way to 'trace' the issue to find the cause or is this a known issue?

Thanks!

You using the built-in GuiCtrlCreateTab/GuiCtrlCreateTabItem or the UDF create?

If using the UDF create suggest using the built-in.

[martin]

I'm having an odd issue where I have several tabs in my GUI and when i click to change tabs, the controls don't hide. I end up having a merging of the 2 tabs and I was wondering if anyone knew how to correct this?

I know it sounds odd. Is there any way to 'trace' the issue to find the cause or is this a known issue?

Thanks!

Have you remembered to end the tab definition with GuiCtrlCreateTabItem("")?

[MrCreatoR]

To solve the problem we need to see some code, if you don't want to post your script (or it's to big), make an example that can reproduce your problem .

[dinodod]

ok, I believe I found the issue. I have my GUI partially buit when using the GUICreate function. The rest of the gui for the tabs is created on the fly in my While / Wend section (See below). As I move from one tab to another, the items stay on the screen and don't hide. This puts a wench in my logic atm as my tabs are dependant on the actions of the other tabs.

Guess I'm gonna need to re-think the logic here and find a way to do some background checks.

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
    
    Case $msg=$tab
        If GUICtrlRead($tab) = 1 then
            $GUI_Button_Back3 = GUICtrlCreateButton("Back", $ButtonX + 20, $Y1 + 20, 100, 30)
        EndIf
    EndSelect
WEnd

[MrCreatoR]

It's a bad idea to create the controls like that, better create them before the loop. And if you need them dynamically, then you can use GUISwitch($hGUI, GUICtrlRead($hTab, 1)) and end the tab definition every time...

#include <GuiConstants.au3>

$hGUI = GUICreate("Test Script", 300, 200)

$hTab = GUICtrlCreateTab(10, 20, 280, 130)

GUICtrlCreateTabItem("Tab1")
GUICtrlCreateTabItem("Tab2")

GUICtrlCreateTabItem("")

GUISetState(@SW_SHOW, $hGUI)

$iButton1 = -1
$iButton2 = -1

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hTab
            GUISwitch($hGUI, GUICtrlRead($hTab, 1))
            
            Switch GUICtrlRead($hTab)
                Case 0
                    If $iButton1 = -1 Then $iButton1 = GUICtrlCreateButton("Button (in tab 1)", 20, 60, 80, 20)
                Case 1
                    If $iButton2 = -1 Then $iButton2 = GUICtrlCreateButton("Button (in tab 2)", 20, 60, 80, 20)
            EndSwitch
            
            GUICtrlCreateTabItem("")
    EndSwitch
WEnd

But as i said, the best way is to create them previously:

#include <GuiConstants.au3>

$hGUI = GUICreate("Test Script", 300, 200)

$hTab = GUICtrlCreateTab(10, 20, 280, 130)

GUICtrlCreateTabItem("Tab1")
$iButton1 = GUICtrlCreateButton("Button (in tab 1)", 20, 60, 80, 20)

GUICtrlCreateTabItem("Tab2")
$iButton2 = GUICtrlCreateButton("Button (in tab 2)", 20, 60, 80, 20)

GUICtrlCreateTabItem("")

GUISetState(@SW_SHOW, $hGUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd