get window's handle from control's handle

[oMBRa]

I have an handle of a control, and with it I should get the handle of the window owner, but how to do it?

[evilertoaster]

_WinAPI_GetParent() ?

[oMBRa]

this is my code:

#include <WinAPI.au3>
#include <WindowsConstants.au3>
HotKeySet('{F2}', 'Esc')

Global $tPOINT = DllStructCreate("int X;int Y")



While 1
    Sleep(10)
    DllStructSetData($tPOINT, 'X', _WinAPI_GetMousePosX())
    DllStructSetData($tPOINT, 'Y', _WinAPI_GetMousePosY())

    $hWnd = _WinAPI_WindowFromPoint($tPOINT)
    ToolTip('' & _WinAPI_GetWindowText($hWnd), 0, 0)
    
WEnd

Func Esc()
    Exit
EndFunc  ;==>Esc

with that code I get the text of the control, but I need the name of the window that own the control

[ProgAndy]

Well, you have to use _WinAPI_GetParetn, as evilertoaster said

#include <WinAPI.au3>
#include <WindowsConstants.au3>
HotKeySet('{F2}', 'Esc')

Global $tPOINT = DllStructCreate("int X;int Y")



While 1
    Sleep(10)
    $tPOINT= _WinAPI_GetMousePos()

    $hWnd = _WinAPI_WindowFromPoint($tPOINT)
    ; Get the "real" parent window ( also from child of child :) )
    $hWnd2 = $hWnd
    Do 
        $hWnd = $hWnd2
        $hWnd2 = _WinAPI_GetParent($hWnd)
    Until $hWnd2=0
    $title = WinGetTitle($hWnd)
    ; Show Class for Window without Title
    If $title = "" Then $title = "[CLASS:"&_WinAPI_GetClassName($hWnd)&"]"
    ToolTip($title, 0, 0)
    
WEnd

Func Esc()
    Exit
EndFunc  ;==>Esc

[oMBRa]

yes, now works thx

[LarryDalooza]

Because a Parent can have a Parent... I use...

user32.dll - GetAncestor() with $GA_ROOT=2

Retrieves the root window by walking the chain of parent windows.

Lar.

[ProgAndy]

Hey. this is better... didn't know that it exists

#include <WinAPI.au3>
#include <WindowsConstants.au3>
HotKeySet('{F2}', 'Esc')

Global $tPOINT = DllStructCreate("int X;int Y")



While 1
    Sleep(10)
    $tPOINT= _WinAPI_GetMousePos()

    $hWnd = _WinAPI_WindowFromPoint($tPOINT)
    ; Get the "real" parent window ( also from child of child smile.gif )
    $hWnd2 = _WinAPI_GetAncestor($hWnd,2)
    If Not($hWnd2 = 0) Then $HWnd = $hWnd2
    $title = WinGetTitle($hWnd)
    ; Show Class for Window without Title
    If $title = "" Then $title = "[CLASS:"&_WinAPI_GetClassName($hWnd)&"]"
    ToolTip($title, 0, 0)
   
WEnd

Func Esc()
    Exit
EndFunc  ;==>Esc

Edited October 31, 2008 by ProgAndy

[oMBRa]

yes u are right:

#include <WinAPI.au3>
#include <WindowsConstants.au3>
HotKeySet('{F2}', 'Esc')

Global $tPOINT = DllStructCreate("int X;int Y")

While 1
    Sleep(10)
    $tPOINT = _WinAPI_GetMousePos()
    $hWnd = _WinAPI_WindowFromPoint($tPOINT)
    ToolTip('' & _WinAPI_GetWindowText(_WinAPI_GetAncestor($hWnd, 2)), 0, 0)
WEnd

Func Esc()
    Exit
EndFunc  ;==>Esc