Sign in to follow this  
Followers 0
layer

TaskMan

24 posts in this topic

:lmao: wow... i kind of remade the task manager with 31 lines of codes :) doesnt have all the process information but if you ever get one of those viruses that dont let you use Task Manager, id suggest this as your backup! definatley not supposed to be replaced with the "Windows Task Manager" though!

#include <GUIConstants.au3>
$main= GUICreate ("TaskMan", 200, 300)
$mem= MemGetStats ()
$status= GUICtrlCreateLabel ("RAM Left: ",1,284,129,16,BitOr($SS_SIMPLE,$SS_SUNKEN))
GUICtrlSetFont ($status, 8, 5, "", "Comic Sans MS")
$memstats= GUICtrlCreateLabel ("Memory Load: " & $mem[0] & "%",  2, 2)
GUICtrlSetFont ($memstats, 8, 5, "", "Comic Sans MS")
$AllProcesses= ProcessList ()
$Processes= GUICtrlCreateListView ("Processes", 1, 20, 200, 250)
$end= GUICtrlCreateButton ("End Process", 130, 275, -1, -1)
For $i= 1 to $AllProcesses[0][0]
$items= GUICtrlCreateListViewItem ($AllProcesses[$i][0], $Processes)
Next
GUISetState (@SW_SHOW, $main)
While 1
    GUICtrlSetData ($status, "RAM Left: " & $mem[2] & " KB", 1)
    $get= GUIGetMsg ()
    Select
        Case $get= -3 
            Exit
            Case $get= $end
                $getpid= ProcessExists (GUICtrlRead(GUICtrlRead ($Processes)))
                $warning= MsgBox (4 + 48, "WARNING", "Are you sure you want to close this process? Doing so may cause system unstability and unwanted data loss! Continue?")
                If $warning= 6 then 
                    ProcessClose ($getpid)
                Else
                    ContinueLoop
                    EndIf
                
            EndSelect
    WEnd

enjoy! o:):)


FootbaG

Share this post


Link to post
Share on other sites



Very nice. A friend of mine just made one similar to this a few weeks ago (too bad he won't give out even the compiled version...). The only thing that I see missing is an (automatic) refresh of the process list. I'll take a look at the code to see what I can do...


Writing AutoIt scripts since
_DateAdd("d", -2, _NowCalcDate())

Share this post


Link to post
Share on other sites

i can definatley adjust that, i totally forgot :"> ill change it in a bit, sort of bussy right now :lmao:


FootbaG

Share this post


Link to post
Share on other sites

#4 ·  Posted (edited)

#include <GUIConstants.au3>
$main = GUICreate ("TaskMan", 200, 300)
While 1
    GUISetState (@SW_SHOW, $main)
    $status = GUICtrlCreateLabel ("RAM Left: ",1,284,129,16,BitOr($SS_SIMPLE,$SS_SUNKEN))
    GUICtrlSetFont ($status, 8, 5, "", "Comic Sans MS")
    $mem = MemGetStats ()
    $memstats = GUICtrlCreateLabel ("Memory Load: " & $mem[0] & "%",  2, 2)
    GUICtrlSetFont ($memstats, 8, 5, "", "Comic Sans MS")
    $AllProcesses = ProcessList()
    $Processes = GUICtrlCreateListView ("Processes", 1, 20, 200, 250)
    $end = GUICtrlCreateButton ("End Process", 130, 275, -1, -1)
    For $i = 1 to $AllProcesses[0][0]
        $items = GUICtrlCreateListViewItem ($AllProcesses[$i][0], $Processes)
    Next
    GUICtrlSetData ($status, "RAM Left: " & $mem[2] & " KB", 1)
    $get= GUIGetMsg ()
    Select
        Case $get= -3
            Exit
            Case $get= $end
                $getpid= ProcessExists (GUICtrlRead(GUICtrlRead ($Processes)))
                $warning= MsgBox (4 + 48, "WARNING", "Are you sure you want to close this process? Doing so may cause system unstability and unwanted data loss! Continue?")
                If $warning= 6 then
                    ProcessClose ($getpid)
                Else
                    ContinueLoop
                    EndIf
                
            EndSelect
WEnd

I'm wondering about just restarting the loop every 10 seconds (TimerDiff() function), and/or when someone presses end process button. yes, I know it wasn't an extravigant change...in fact it performs a bit worse than the first version...

Edited by MSLx Fanboy

Writing AutoIt scripts since
_DateAdd("d", -2, _NowCalcDate())

Share this post


Link to post
Share on other sites

yikes! that wouldnt work, you wouldnt be able to exit or end a process but i was thinking the same exact thing... later.. im tired :lmao:


FootbaG

Share this post


Link to post
Share on other sites

Geez, it flickers like mad. Do what I was told to do, ONLY change when the values have changed.


"I thoroughly disapprove of duels. If a man should challenge me, I would take him kindly and forgivingly by the hand and lead him to a quiet place and kill him." - Mark TwainPatient: "It hurts when I do $var_"Doctor: "Don't do $var_" - Lar.

Share this post


Link to post
Share on other sites

Yea, I noticed the flashing...my friend had the same problem, and didn't bother doing it. the only thing he could think of is reloading the entire gui


Writing AutoIt scripts since
_DateAdd("d", -2, _NowCalcDate())

Share this post


Link to post
Share on other sites

dont worry, ill fix it when tomorrow comes! :lmao:


FootbaG

Share this post


Link to post
Share on other sites

Super cool script man! Would have loved to see some other information like user or Mem Usuage for each process.

:whistle: You rock!

Share this post


Link to post
Share on other sites

Really nice :whistle:

Though I edited some parts (like shorten the if conditional for the msgbox and the flickering).

#include <GUIConstants.au3>
$mem= MemGetStats ()
$AllProcesses= ProcessList ()
$main= GUICreate ("TaskMan", 200, 300)
$status= GUICtrlCreateLabel ("RAM Left: " & Round($mem[2]/1024) & " MB",1,284,129,16,BitOr($SS_SIMPLE,$SS_SUNKEN))
GUICtrlSetFont ($status, 8, 5, "", "Comic Sans MS")
$memstats= GUICtrlCreateLabel ("Memory Load: " & $mem[0] & "%",  2, 2,100,16)
GUICtrlSetFont ($memstats, 8, 5, "", "Comic Sans MS")
$Processes= GUICtrlCreateListView ("Processes", 1, 20, 200, 250)
$end= GUICtrlCreateButton ("End Process", 130, 275, -1, -1)
    For $i= 1 to $AllProcesses[0][0]
        $items= GUICtrlCreateListViewItem ($AllProcesses[$i][0], $Processes)
    Next
GUISetState (@SW_SHOW, $main)
While 1
    $memNew = MemGetStats()
    $ProcessListNew = ProcessList()
    $get= GUIGetMsg ()
    Select
        Case $get= -3
            Exit
        Case $get= $end
                $getpid= ProcessExists (GUICtrlRead(GUICtrlRead ($Processes)))
                If MsgBox (4 + 48, "WARNING", "Are you sure you want to close this process? Doing so may cause system unstability and unwanted data loss! Continue?") = 6 then
                    ProcessClose ($getpid)
                EndIf
        Case $memNew[0] <> $mem[0]
            $mem = MemGetStats()
            GUICtrlSetData($memstats,"Memory Load: " & $mem[0] & "%")
        Case Round($memNew[2]/1024)+1 < Round($mem[2]/1024) OR Round($memNew[2]/1024)-1 > Round($mem[2]/1024)
                $mem = MemGetStats()
                GUICtrlSetData ($status, "RAM Left: " & Round($mem[2]/1024) & " MB", 1)
        Case $ProcessListNew[0][0] <> $AllProcesses[0][0]
            $AllProcesses = ProcessList()
    EndSelect
WEnd

Another thing you could actually add would be sorting the listview and also making the listviewitemheader larger.

Greetz,

FaNtA

Share this post


Link to post
Share on other sites

i tried it, nice but it didnt really kill the process.. (this only happens using XxXFaNtA script..)

tried killing alg.exe, nothing happens but the memory loads gets higher from 27% goes up to 72% and thats all

Share this post


Link to post
Share on other sites

Well it works perfectly for me when I try to kill the AutoIt.exe :whistle:

Share this post


Link to post
Share on other sites

Hey, This is just a fast solution i came up with,Using onevent and adlibs u can update the list and still be able to end a process:

#include <Guilistview.au3>
#include <GUIConstants.au3>
Opt("GUIOnEventMode", 1)
$main = GUICreate("TaskMan", 200, 400)
Global $updatestatus
$status = GUICtrlCreateLabel("RAM Left: ", 1, 284, 129, 16, BitOR($SS_SIMPLE, $SS_SUNKEN))
GUICtrlSetFont($status, 8, 5, "", "Comic Sans MS")
$mem = MemGetStats()
$memstats = GUICtrlCreateLabel("Memory Load: " & $mem[0] & "%", 2, 2)
GUICtrlSetFont($memstats, 8, 5, "", "Comic Sans MS")
$Processes = GUICtrlCreateListView("Processes", 1, 20, 200, 250)
$end = GUICtrlCreateButton("End Process", 130, 275, -1, -1)
$Update = GUICtrlCreateCheckbox("Update every 2 sec", 0, 300)
Newlist()
GUICtrlSetData($status, "RAM Left: " & $mem[2] & " KB", 1)
GUISetOnEvent($GUI_EVENT_CLOSE, "quit")
GUICtrlSetOnEvent($end, "end")
GUICtrlSetOnEvent($Update, "Update")

GUISetState(@SW_SHOW, $main)


Func Update()
    If GUICtrlRead($Update) = $GUI_CHECKED Then
        $updatestatus = 1
        AdlibEnable("Adlibs", 2000)
    EndIf

    If Not GUICtrlRead($Update) = $GUI_CHECKED Then
        If $updatestatus = 1 Then AdlibDisable()
        $updatestatus = 0
    EndIf

EndFunc  ;==>Update
Func Adlibs()
    Newlist()
    updatemem()
EndFunc  ;==>Adlibs
Func updatemem()
    $mem = MemGetStats()
    GUICtrlSetData($status, "RAM Left: " & $mem[2] & " KB", 1)
EndFunc  ;==>updatemem
Func Newlist()
    
    _GUICtrlListViewDeleteAllItems($Processes)
    $AllProcesses = ProcessList()
    For $i = 1 To $AllProcesses[0][0]
        $items = GUICtrlCreateListViewItem($AllProcesses[$i][0], $Processes)
    Next
EndFunc  ;==>Newlist
Func quit()
    Exit
EndFunc  ;==>quit

Func end()
    $getpid = ProcessExists(GUICtrlRead(GUICtrlRead($Processes)))
    $warning = MsgBox(4 + 48, "WARNING", "Are you sure you want to close this process? Doing so may cause system unstability and unwanted data loss! Continue?")
    If $warning = 6 Then
        ProcessClose($getpid)
    Else
        Return 0
    EndIf
EndFunc  ;==>end

While 1
    Sleep(100)
WEnd

My Scripts:Radioblog Club Music DownloaderOther stuff:Fun movieIm serious read the help file it helps :PFight 'Till you drop. Never stop, You Cant give up. Til you reach the top Fight! you’re the best in town Fight!

Share this post


Link to post
Share on other sites

#14 ·  Posted (edited)

#region comments
; This software was written entirely by Ben Perkins, AKA: The Magician
; With the exception of the memory optimization function.
; You can contact me at magician13134@gmail.com
; or visit www.magicsoftinc.com
; if you have questions, comments, feedback, etc.
;
; Thanks!
; The Magician
#endregion comments

#region include
#include <GUIConstants.au3>
#Include <GuiTab.au3>
#include "compinfo.au3"
#include "CPU.au3"
#include <Process.au3>
#Include <GuiListView.au3>
#include <File.au3>
#include <constants.au3>
#endregion include

#region variables
opt("RunErrorsFatal", 0)
$count = 100
$edit = 0
$serial = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion", "ProductId")
$mem = MemGetStats()
$array = _ProcessListCPU($sProcess, 0)
Dim $OSs
_ComputerGetOSs($OSs)
$manufacturer = $OSs[1][28]
$company = $OSs[1][34]
$SystemDrive = $OSs[1][54]
$version = $OSs[1][58]
#endregion variables

#region GUI create
$ttm = GUICreate("Total Task Manager by Ben Perkins", 320, 430 )
opt("trayiconhide", 1)
GUISetState( @SW_SHOW )
opt("TrayMenuMode",1)
opt("trayiconhide", 1)
$TrayMenu_HideIcon = TrayCreateItem("Hide tray icon?", -1, -1, 1)
TrayCreateItem("")
$TrayMenu_Exit = TrayCreateItem("Complete Exit", -1, -1, 1)
TraySetState()
TraySetToolTip("Total Task Manager")
#endregion GUI create

#region GUI build
$label = GUICtrlCreateLabel( "Loading Windows Files...", 5, 175 )
$progressbar1 = GUICtrlCreateProgress (5,190,300,20, $PBS_SMOOTH)
$color = 000000
for $i = 0 to 100
    GUICtrlSetData ($progressbar1,$i)
    GUICtrlSetColor($progressbar1, $color)
    $color+=2.55
    sleep(Random(1, 10))
Next
GUICtrlDelete( $progressbar1 )
GUICtrlDelete( $label )

$memlabel = GUICtrlCreateLabel(int($mem[1]/1000) & "mb total RAM       " & $mem[0] & "% being used", 10, 27, 290, 15)
$cpu = GUICtrlCreateProgress( 10, 5, 290, 20, $PBS_SMOOTH)
$cpu2 = GUICtrlCreateProgress(10, 45, 290, 20, $PBS_SMOOTH)
GUICtrlSetColor($cpu, 0x1111CC)
GUICtrlSetColor($cpu2, 0x1111CC)
GUICtrlSetBkColor($cpu, 0xCCCCCC)
GUICtrlSetBkColor($cpu2, 0xCCCCCC)
$cpulabel = GUICtrlCreateLabel($array[0][1] & "% of your CPU is being used", 10, 67, 290, 15)
$BottomLabel = GUICtrlCreateLabel("Total Task Manager written by Ben Perkins && Magic Soft Inc.", 15, 408)

$maintab = GUICtrlCreateTab(6, 85, 308, 315)

#region computer
$computer = GUICtrlCreateTabItem("Computer")
GUICtrlCreateLabel("Windows Product ID:", 10, 110 )
$input1 = GUICtrlCreateInput($serial, 10, 125, 180 )
GUICtrlSetState($input1, $GUI_DISABLE) 
$copy1 = GUICtrlCreateButton("Copy", 195, 124, 50, 22)
$edit1 = GUICtrlCreateButton("Edit", 250, 124, 50, 22)
GUICtrlCreateLabel("Liscened Company:", 10, 150 )
$input2 = GUICtrlCreateInput($company, 10, 165, 180 )
GUICtrlSetState($input2, $GUI_DISABLE) 
$copy2 = GUICtrlCreateButton("Copy", 195, 164, 50, 22)
$edit2 = GUICtrlCreateButton("Edit", 250, 164, 50, 22)
GUICtrlSetState($edit2, $GUI_DISABLE) 
GUICtrlCreateLabel("Your OS is made by: " & $manufacturer, 10, 190 )
GUICtrlCreateLabel("Your primary drive is: " & $SystemDrive & "\", 10, 205 )
GUICtrlCreateLabel("You're running Windows " & $version, 10, 220 )
GUICtrlCreateLabel("Your computer is called: " & @ComputerName, 10, 235 )
GUICtrlCreateLabel("Your IP Address is: " & @IPAddress1, 10, 250 )
GUICtrlCreateLabel("Your screen size is: " & @Desktopwidth & "x" & @DesktopHeight, 10, 265 )
GUICtrlCreateLabel("     Depth: " & @DesktopDepth & " bit", 10, 280 )
GUICtrlCreateLabel("Your OS info is: " & @OSVersion & " " & @OSServicePack, 10, 295 )
$admin = ""
if IsAdmin() <> 1 Then $admin = "do not "
GUICtrlCreateLabel("You " & $admin & "have admin privileges", 10, 310)
$shutdown = GUICtrlCreateButton("Shutdown", 15, 365, 90, 26)
$restart = GUICtrlCreateButton("Restart", 115, 365, 90, 26)
$logoff = GUICtrlCreateButton("Log Off", 215, 365, 90, 26)
#endregion computer

#region performance
GUICtrlCreateTabItem("Performance")
$optimize = GUICtrlCreateButton(">>>>>Optimize Memory<<<<<", 15, 365, 290)

#endregion performance

#region task manager
$taskman = GUICtrlCreateTabItem( "Task Manager" )
$processes = GUICtrlCreateListView("Process Name             | PID   | Priority   |   ", 10, 130, 297, 230, "", 0x00000020 )
Dim $B_DESCENDING[_GUICtrlListViewGetSubItemsCount ($processes) ]
_GUICtrlListViewSort($processes, $B_DESCENDING, GUICtrlGetState($processes))
#comments-start
$process = ProcessList()
$number = $process
for $i = 1 to $process[0][0]
    if $process[$i][0] <> "" and $process[$i][0] <> "[System Process]" Then
        $priority = _ProcessGetPriority ($process[$i][1])
        if $priority == -1 Then $priority = "N/A"           
        if $priority == 0 Then $priority = "Idle/Low"
        if $priority == 1 Then $priority = "Below Normal"
        if $priority == 2 Then $priority = "Normal"
        if $priority == 3 Then $priority = "Above Normal"
        if $priority == 4 Then $priority = "High"
        if $priority == 5 Then $priority = "Realtime"
        $item = GUICtrlCreateListViewItem($process[$i][0] & "|" & $process[$i][1] & "|" & $priority ,$processes)
    EndIf
Next
#comments-end
$processlabel = GUICtrlCreateLabel(_GUICtrlListViewGetItemCount($processes) & " processes running", 15, 113)
$refresh = GUICtrlCreateButton("Refresh", 15, 367, 65)
$close = GUICtrlCreateButton("End", 90, 367, 65)
$info = GUICtrlCreateButton("Info", 165, 367, 65)
$prioritybutton = GUICtrlCreateButton("Priority", 240, 367, 65) 
list()
#endregion task manager

#region options
GUICtrlCreateTabItem("Options")
$RefreshDesk = GUICtrlCreateButton(" Refresh desktop ", 15, 120)
$RunTaskMan = GUICtrlCreateButton(" Run Task Manager ", 115, 120)
$save = GUICtrlCreateButton("  Save Stats  ", 230, 120)
$splash = GUICtrlCreateCheckbox("Display splash on exit?", 15, 150)
GUICtrlSetState($splash, 0)
$HideIcon = GUICtrlCreateCheckbox("Hide tray icon?", 15, 170)
GUICtrlSetState($HideIcon, 1)
$ChangeColor = GUICtrlCreateCheckbox("Change progress bar colors?", 15, 190)
GUICtrlSetState($ChangeColor, 1)
$top = GUICtrlCreateCheckbox("Always on top?", 15, 210)
GUICtrlSetState($top, 1)
$ReplaceTaskMan = GUICtrlCreateCheckbox("Replace Task Manager?", 15, 230)
GUICtrlSetState($ReplaceTaskMan, 0)
$TaskManName = GUICtrlCreateInput("Task Manager Name", 35, 276)
$TaskManNameLabel = GUICtrlCreateLabel("Task Manager's name:", 35, 256)
GUICtrlSetData($TaskManName, "taskmgr.exe")
#endregion options

#region about
GUICtrlCreateTabItem("Help/About")
GUICtrlCreateLabel("Total Task Manager was written entirely by Ben Perkins," & @LF & _ 
                    "owner and founder of Magic Soft Inc." & @LF & @LF & _
                    "If you enjoyed this software, you can visit" & @LF & _
                    "www.magicsoftinc.com for more great software. Thank you." & @LF & @LF & @LF & "-Ben Perkins" & @LF & "AKA: The Magician", 15, 120)
GUICtrlCreateIcon("MSI.ICO", -1, 33, 255, 252, 73)
$help = GUICtrlCreateButton("Help", 110, 360, 100)
#endregion about
GUICtrlCreateTabItem("")


#endregion GUI build

#region main loop
While 1
; Update stats
    GUISetState(@SW_SHOW, $ttm)
    $RunPriority = 0
    $count+=1; Used for processor/RAM updates
    $mem = MemGetStats()
    if $count >= 50 Then; Update the processor/RAM progress bars
        $array = _ProcessListCPU($sProcess, 0)
        GUICtrlSetData($memlabel, int($mem[1]/1000) & _ 
        "mb total RAM                                        " & $mem[0] & "% being used")
        GUICtrlSetData($cpulabel, $array[0][1] & "% of your CPU is being used")
        GUICtrlSetData($cpu, $mem[0])
        GUICtrlSetData($cpu2, $array[0][1])
        $count = 0; Reset counter
        if GUICtrlRead($ChangeColor) == 1 Then
        ; Change RAM color
            If $mem[0] <= 33 Then
                GUICtrlSetColor($CPU, 0x11CC11)
            ElseIf $mem[0] > 33 and $mem[0] <= 66 Then
                GUICtrlSetColor($CPU, 0x1111CC)
            Else
                GUICtrlSetColor($CPU, 0xCC1111)
            EndIf
        ; Change CPU color
            If $array[0][1] <= 33 Then
                GUICtrlSetColor($CPU2, 0x11CC11)
            ElseIf $array[0][1] > 33 and $array[0][1] <= 66 Then
                GUICtrlSetColor($CPU2, 0x1111CC)
            Else
                GUICtrlSetColor($CPU2, 0xCC1111)
            EndIf
        Else
            GUICtrlSetColor($CPU2, 0x1111CC)
            GUICtrlSetColor($CPU2, 0x1111CC)
        EndIf
    EndIf
    
    
    $msg = GUIGetMsg(); Retrieves buttons, etc
    $menu = TrayGetMsg(); Retrieves tray button menu items
    if GUICtrlRead($HideIcon) == 1 Then opt("trayiconhide", 1); Hide tray icon
    if GUICtrlRead($HideIcon) <> 1 Then opt("trayiconhide", 0); Show tray icon
    If $msg = $GUI_EVENT_CLOSE Then _Exit()
    If $msg = $copy1 Then ClipPut( $serial )
    If $msg = $copy2 Then ClipPut( $company )
    If $msg = $optimize Then MemoryOptimize()
    If $msg = $info Then info()
    If $msg = $close Then kill()
    If $msg = $refresh Then list()
    If $msg = $save Then save()
    If $msg = $RunTaskMan Then RunTaskMan()
    If $msg = $processes Then _GUICtrlListViewSort($processes, $B_DESCENDING, GUICtrlGetState($processes))
    If $msg = $help Then
        WinSetOnTop("Total Task Manager by Ben Perkins", "", 0)
        help()
    EndIf
    If $menu = $TrayMenu_Exit Then TrayExit()
    If $menu = $TrayMenu_HideIcon Then
        opt("trayiconhide", 1)
        GUICtrlSetState($HideIcon, 1)
    EndIf
    If $msg = $prioritybutton Then ChangeProcessPriority()
    If $msg = $RefreshDesk Then
        WinSetState("Program Manager", "", @SW_HIDE)
        WinSetState("Program Manager", "", @SW_SHOW)
        GUICtrlSetState ( $RefreshDesk, $GUI_FOCUS )
    EndIf
    if GUICtrlRead($top) == 1 Then
        WinSetOnTop("Total Task Manager by Ben Perkins", "", 1)
    Else
        WinSetOnTop("Total Task Manager by Ben Perkins", "", 0)
    EndIf
    If $msg = $shutdown Then
        WinSetOnTop("", "", 0)
        $power = MsgBox(1, "Shutdown?", "Shutdown?")
        if $power == 1 Then shutdown(1)
    EndIf
    If $msg = $restart Then
        WinSetOnTop("", "", 0)
        $power = MsgBox(1, "Restart?", "Restart?")
        if $power == 1 Then shutdown(2)
    EndIf
    If $msg = $logoff Then
        WinSetOnTop("", "", 0)
        $power = MsgBox(1, "Log Off?", "Log Off?")
        if $power == 1 Then shutdown(0)
    EndIf
    If $msg = $edit1 and $edit = 0 Then 
        GUICtrlSetState($input1, $GUI_ENABLE)
        GUICtrlSetState($input1, $GUI_FOCUS)
        ControlSetText("Total Task Manager by Ben Perkins", "", $edit1, "Done")
        $edit = 1
        $msg = ""
    EndIf
    If $msg = $edit1 and $edit <> 0 Then 
        GUICtrlSetState($input1, $GUI_DISABLE)
        ControlSetText("Total Task Manager by Ben Perkins", "", $edit1, "Edit")
        $serial = ControlGetText("","",$input1)
        RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion", "ProductId", "REG_SZ", $serial)
        $edit = 0
    EndIf
    if GUICtrlRead($ReplaceTaskMan) <> 1 Then
        GUICtrlSetState($TaskManName, $GUI_HIDE)
        GUICtrlSetState($TaskManNameLabel, $GUI_HIDE)
    ElseIf GUICtrlGetState($taskManName) <> 80 Then
        GUICtrlSetState($TaskManName, $GUI_SHOW)
        GUICtrlSetState($TaskManNameLabel, $GUI_SHOW)
    EndIf
Wend
#endregion main loop

#region functions
Func kill(); Kills a process from task manager
    WinSetOnTop ("Total Task Manager by Ben Perkins", "", 0)
    $selected = stringLeft(GUICtrlRead(GUICtrlRead($processes)),StringInStr(GUICtrlRead(GUICtrlRead($processes)),"|",)-1)
    if MsgBox(1, "Close " & $selected & "?", "Closing a process may cause undesired results, are you sure you want to continue?") == 1 Then
        $ProToKill = stringLeft(GUICtrlRead(GUICtrlRead($processes)),StringInStr(GUICtrlRead(GUICtrlRead($processes)),"|",)-1)
        ProcessClose( $ProToKill )
        _GUICtrlListViewDeleteItemsSelected($ProToKill)
        sleep(5)
        ProcessClose( $ProToKill )
        sleep(5)
        GUICtrlSetData($processlabel, _GUICtrlListViewGetItemCount($processes) & " processes running")
    EndIf
EndFunc
Func info(); Gives a process' information
    $window = 0
    $selected = ControlListView("", "", $processes, "GetSelected")
    $selected = ControlListView("", "", $processes, "GetText", $selected, 1)
    if $selected <> "" Then
        $Windows = WinList()
        for $i = 1 to $Windows[0][0]
            $PID = WinGetProcess($Windows[$i][0])
            if $PID = $selected Then
                $window = 1
                $WinName = $Windows[$i][0]
                ExitLoop
            EndIf
        Next
        
        WinSetOnTop ("Total Task Manager by Ben Perkins", "", 0)
        $priority = _ProcessGetPriority ($selected)
        if $priority == -1 Then $priority = " N/A"          
        if $priority == 0 Then $priority = " Idle/Low"
        if $priority == 1 Then $priority = " Below Normal"
        if $priority == 2 Then $priority = " Normal"
        if $priority == 3 Then $priority = " Above Normal"
        if $priority == 4 Then $priority = " High"
        if $priority == 5 Then $priority = " Realtime"
        if $window == 0 Then
            $selected = ControlListView("", "", $processes, "GetSelected")
            $selected = ControlListView("", "", $processes, "GetText", $selected, 0)
            MsgBox(0, "Info about " & $selected, $selected & _
                        " has no window associated with it." & _
                        @LF & "It has a Priority of" & $priority)
        Else
            $exe = ControlListView("", "", $processes, "GetSelected")
            $exe = ControlListView("", "", $processes, "GetText", $exe, 0)
            $pos = WingetPos($WinName)
            $message = MsgBox(4, "Info about " & $WinName, $exe & " has window called " & _
                        $WinName & @LF & "X pos: " & $pos[0] & @LF & "Y pos: " & $pos[1] & _
                        @LF & "Width: " & $pos[2] & @LF & "Height: " & $pos[3] & _
                        @LF & "The Process ID (PID) is: " & $selected & @LF & @LF & _
                        "View window text?")
            if $message == 6 then Msgbox(0, "Window Text for " & $WinName, "The window text is:" & @CRLF & WinGetText($WinName))
        EndIf
    EndIf
EndFunc
Func list(); Refreshes the task manager
    $process = ProcessList()
    $number = _GUICtrlListViewGetItemCount($processes)
    $ColorCount=0
    for $i = 1 to $number
        _GUICtrlListViewDeleteItem($processes, $i=2)
    Next
    for $i = 1 to $process[0][0]
        if $process[$i][0] <> "" Then;and $process[$i][0] <> "[System Process]" Then
            $ColorCount+=1
            $priority = _ProcessGetPriority ($process[$i][1])
            if $priority == -1 Then $priority = "N/A"           
            if $priority == 0 Then $priority = "Idle/Low"
            if $priority == 1 Then $priority = "Below Normal"
            if $priority == 2 Then $priority = "Normal"
            if $priority == 3 Then $priority = "Above Normal"
            if $priority == 4 Then $priority = "High"
            if $priority == 5 Then $priority = "Realtime"
            $item = GUICtrlCreateListViewItem($process[$i][0] & "|" & $process[$i][1] & "|" & $priority & "",$processes)
            If $ColorCount == 1 Then; Color every onther row
                GUICtrlSetBkColor(-1, 0xEDF3FE)
                GUICtrlSetColor(-1, 0x000000)
            Else; Color every other row
                GUICtrlSetBkColor(-1, 0xffffff)
                GUICtrlSetColor(-1, 0x000000)
                $ColorCount = 0
            EndIf
        EndIf
    Next
    GUICtrlSetData($processlabel, _GUICtrlListViewGetItemCount($processes) & " processes running")
EndFunc
Func save()
    $filename = @MON & "-" & @MDAY & " _ " & @HOUR & "-" & @MIN & " stats.txt"
    _FileCreate($filename)
    $file = FileOpen($filename, 1)
    If $file = -1 Then
        MsgBox(0, "Error", "Unable to open file.")
    Else
        FileWrite($filename, "Permanent stats:" & @LF)
        FileWrite($filename, "Your OS is made by: " & $manufacturer & @LF)
        FileWrite($filename, "Your primary drive is: " & $SystemDrive & "\" & @LF)
        FileWrite($filename, "You're running Windows " & $version & @LF)
        FileWrite($filename, "Your computer is called: " & @ComputerName & @LF)
        FileWrite($filename, "Your IP Address is: " & @IPAddress1 & @LF)
        FileWrite($filename, "Your screen size is: " & @Desktopwidth & "x" & @DesktopHeight & @LF)
        FileWrite($filename, "   With a " & @DesktopDepth & " bit resolution" & @LF)
        FileWrite($filename, "Your OS info is: " & @OSVersion & " " & @OSServicePack & @LF)
        FileWrite($filename, @LF & @LF)
        FileWrite($filename, "Temporary stats" & @LF)
        FileWrite($filename, "Your processor is running at " & $array[0][1] & "%" & @LF)
        FileWrite($filename, "Your RAM is " & $mem[0] & "% full" & @LF)
        FileWrite($filename, "You have " & $process[0][0] & " processes running." & @LF)
        FileClose($file)
    EndIf
EndFunc 
Func ChangeProcessPriority()
    $selected = ControlListView("", "", $processes, "GetSelected")
    $selected = ControlListView("", "", $processes, "GetText", $selected, 0)
    $ParentPos = WinGetPos("Total Task Manager by Ben Perkins")
    $PriorityGUI = GUICreate( "Change Process Priority", 150, 180, $ParentPos[0], $ParentPos[1], "", "", $ttm)
    GUISetState(@SW_SHOW)
    $idle = GUICtrlCreateRadio("Idle", 10, 10, 90)
    $BelowNormal = GUICtrlCreateRadio("Below Normal", 10, 28, 90)
    $normal = GUICtrlCreateRadio("Normal", 10, 46, 90)
    $AboveNormal = GUICtrlCreateRadio("Above Normal", 10, 64, 90)
    $high = GUICtrlCreateRadio("High", 10, 82, 90)
    $RealTime = GUICtrlCreateRadio("Realtime", 10, 100, 90)
    GUICtrlCreateLabel("Change priority of:" & @LF & $selected, 10, 125) 
    GUISetState ()
    while 1
        $msg = GUIGetMsg()
        Select
            Case $msg = $idle And BitAND(GUICtrlRead($idle), $GUI_CHECKED) = $GUI_CHECKED
                ProcessSetPriority($selected, 0)
                GUIDelete($PriorityGUI)
                Exitloop
            Case $msg = $BelowNormal And BitAND(GUICtrlRead($BelowNormal), $GUI_CHECKED) = $GUI_CHECKED
                ProcessSetPriority($selected, 1)
                GUIDelete($PriorityGUI)
                Exitloop
            Case $msg = $Normal And BitAND(GUICtrlRead($Normal), $GUI_CHECKED) = $GUI_CHECKED
                ProcessSetPriority($selected, 2)
                GUIDelete($PriorityGUI)
                Exitloop
            Case $msg = $AboveNormal And BitAND(GUICtrlRead($AboveNormal), $GUI_CHECKED) = $GUI_CHECKED
                ProcessSetPriority($selected, 3)
                GUIDelete($PriorityGUI)
                Exitloop
            Case $msg = $High And BitAND(GUICtrlRead($High), $GUI_CHECKED) = $GUI_CHECKED
                ProcessSetPriority($selected, 4)
                GUIDelete($PriorityGUI)
                Exitloop
            Case $msg = $RealTime And BitAND(GUICtrlRead($RealTime), $GUI_CHECKED) = $GUI_CHECKED
                ProcessSetPriority($selected, 5)
                GUIDelete($PriorityGUI)
                Exitloop
        EndSelect
    WEnd
    list()
EndFunc
Func help()
    $TTMWindowPos = WinGetPos($ttm)
    GUICreate("Help", 300, 400, $TTMWindowPos[0], $TTMWindowPos[1], "", $WS_EX_CONTEXTHELP, $ttm)
    GUISetState()
    sleep(1000)
    GUIdelete()
EndFunc 
Func MemoryOptimize(); Reduces memory usage, I did NOT write the code to the memory optimize!
    #region optimize fx
    ControlSetText("Total Task Manager by Ben Perkins", "", $optimize, ">   Optimize Memory <")
    sleep(150)
    ControlSetText("Total Task Manager by Ben Perkins", "", $optimize, " >   Optimize Memory   < ")
    sleep(150)
    ControlSetText("Total Task Manager by Ben Perkins", "", $optimize, "  >  Optimize Memory  <  ")
    sleep(150)
    ControlSetText("Total Task Manager by Ben Perkins", "", $optimize, "   > Optimize Memory <   ")
    sleep(150)
    ControlSetText("Total Task Manager by Ben Perkins", "", $optimize, "    >Optimize Memory<   ")
    sleep(150)
    ControlSetText("Total Task Manager by Ben Perkins", "", $optimize, ">   >Optimize Memory<   <")
    sleep(150)
    ControlSetText("Total Task Manager by Ben Perkins", "", $optimize, " >  >Optimize Memory<  < ")
    sleep(150)
    ControlSetText("Total Task Manager by Ben Perkins", "", $optimize, "  > >Optimize Memory< <  ")
    sleep(150)
    ControlSetText("Total Task Manager by Ben Perkins", "", $optimize, "   >>Optimize Memory<<   ")
    sleep(150)
    ControlSetText("Total Task Manager by Ben Perkins", "", $optimize, ">  >>Optimize Memory<<  <")
    sleep(150)
    ControlSetText("Total Task Manager by Ben Perkins", "", $optimize, " > >>Optimize Memory<< < ")
    sleep(150)
    ControlSetText("Total Task Manager by Ben Perkins", "", $optimize, "  >>>Optimize Memory<<<  ")
    sleep(150)
    ControlSetText("Total Task Manager by Ben Perkins", "", $optimize, "> >>>Optimize Memory<<< <")
    sleep(150)
    ControlSetText("Total Task Manager by Ben Perkins", "", $optimize, " >>>>Optimize Memory<<<< ")
    sleep(150)
    ControlSetText("Total Task Manager by Ben Perkins", "", $optimize, ">>>>>Optimize Memory<<<<<")
    #endregion optimize fx
    $memory1 = MemGetStats ( )
    Do
      ReduceMemory()
      $list = ProcessList()
      For $i=1 To $list[0][0]
       ReduceMemory($list[$i][1])
      Next
      $memory2 = $memory1
      $memory1 = MemGetStats ( )
    Until $memory1[2] >= $memory2[2]
EndFunc
Func ReduceMemory($i_PID = -1)
    If $i_PID <> -1 Then
        Local $ai_Handle = DllCall("kernel32.dll", 'int', 'OpenProcess', 'int', 0x1f0fff, 'int', False, 'int', $i_PID)
        Local $ai_Return = DllCall("psapi.dll", 'int', 'EmptyWorkingSet', 'long', $ai_Handle[0])
        DllCall('kernel32.dll', 'int', 'CloseHandle', 'int', $ai_Handle[0])
    Else
        Local $ai_Return = DllCall("psapi.dll", 'int', 'EmptyWorkingSet', 'long', -1)
    EndIf
    
    Return $ai_Return[0]
EndFunc
Func RunTaskMan()
    $taskman = GUICtrlread($TaskManName)
    $success = Run($taskman)
    if $success == 0 Then
        $success = Run("taskmgr.exe")
        if $success == 0 Then
            WinSetOnTop("Total Task Manager by Ben Perkins", "", 0)
            MsgBox(0, "Fatal error", "Could not locate task manager!" & @LF & _
            "You can try to manually launch it with Ctrl+Alt+Del")
        EndIf
    EndIf
EndFunc
Func TrayExit()
    opt("trayiconhide", 1)
    $splash = GUICtrlRead($splash)
    GUIDelete()
    if $splash == 1 Then
        SplashImageOn("", "final.gif", 659, 156, (@DesktopWidth-659)/2, (@DesktopHeight-156)/2, 1)
        sleep(5000)
    EndIf
    Exit
EndFunc
Func _Exit(); Exits the progam and displays splash according to splash display option
    $exit = GUICtrlRead($ReplaceTaskMan)
    if $exit <> 1 Then
        opt("trayiconhide", 1)
        $splash = GUICtrlRead($splash)
        GUIDelete()
        if $splash == 1 Then
            SplashImageOn("", "final.gif", 659, 156, (@DesktopWidth-659)/2, (@DesktopHeight-156)/2, 1)
            sleep(5000)
        EndIf
        Exit
    Else
        $taskman = GUICtrlread($TaskManName)
        GUISetState(@SW_HIDE, $ttm)
        while 1
            If  Not ProcessExists($taskman) Then
                If Not ProcessExists("taskmgr.exe") Then
                    $menu = TrayGetMsg(); Retrieves tray button menu items
                    $msg = GUIGetMsg()
                    If $menu = $TrayMenu_HideIcon Then
                        opt("trayiconhide", 1)
                        GUICtrlSetState($HideIcon, 1)
                    EndIf
                    If $menu = $TrayMenu_Exit Then TrayExit()
                Else
                $taskman = GUICtrlread($TaskManName)
                ProcessClose("taskmgr.exe")
                sleep(25)
                $taskman = GUICtrlread($TaskManName)
                ProcessClose("taskmgr.exe")
                list()
                ExitLoop
                EndIf
            else
                $taskman = GUICtrlread($TaskManName)
                ProcessClose($taskman)
                sleep(25)
                $taskman = GUICtrlread($TaskManName)
                ProcessClose($taskman)
                list()
                ExitLoop
            EndIf
        WEnd
    EndIf
EndFunc
#endregion functions

I wrote this one awhile ago, there's a few includes you may need to grab and an image or two you'll have to do without (nothing important), if you like this, that's an old one, I can bring the new one down from upstairs...

(Wow, I just ran it, and it looks pretty bad, I guess I'm used to the newer versions I have upstairs... sorry)

Edited by magician13134

Share this post


Link to post
Share on other sites

#15 ·  Posted (edited)

magician13134

Hi, great script you have there :whistle: ... (put your code please in [autоit]code[/autоit] tags, that will not look so big).

Where can i get the includes that it needs? (mostly i am intersted in "compinfo.au3" and "CPU.au3"). Thanks.

I am trying to do something like that in my self.. it will be like taskmgr, but more infoabale (include more info :P ).

Edited by MsCreatoR

 

Spoiler

Using OS: Win 7 Professional, Using AutoIt Ver(s): 3.3.6.1 / 3.3.8.1

AutoIt_Rus_Community.png AutoIt Russian Community

My Work...

Spoiler

AutoIt_Icon_small.pngProjects: ATT - Application Translate Tool {new}| BlockIt - Block files & folders {new}| SIP - Selected Image Preview {new}| SISCABMAN - SciTE Abbreviations Manager {new}| AutoIt Path Switcher | AutoIt Menu for Opera! | YouTube Download Center! | Desktop Icons Restorator | Math Tasks | KeyBoard & Mouse Cleaner | CaptureIt - Capture Images Utility | CheckFileSize Program

AutoIt_Icon_small.pngUDFs: OnAutoItErrorRegister - Handle AutoIt critical errors {new}| AutoIt Syntax Highlight {new}| Opera Library! | Winamp Library | GetFolderToMenu | Custom_InputBox()! | _FileRun UDF | _CheckInput() UDF | _GUIInputSetOnlyNumbers() UDF | _FileGetValidName() UDF | _GUICtrlCreateRadioCBox UDF | _GuiCreateGrid() | _PathSplitByRegExp() | _GUICtrlListView_MoveItems - UDF | GUICtrlSetOnHover_UDF! | _ControlTab UDF! | _MouseSetOnEvent() UDF! | _ProcessListEx - UDF | GUICtrl_SetResizing - UDF! | Mod. for _IniString UDFs | _StringStripChars UDF | _ColorIsDarkShade UDF | _ColorConvertValue UDF | _GUICtrlTab_CoverBackground | CUI_App_UDF | _IncludeScripts UDF | _AutoIt3ExecuteCode | _DragList UDF | Mod. for _ListView_Progress | _ListView_SysLink | _GenerateRandomNumbers | _BlockInputEx | _IsPressedEx | OnAutoItExit Handler | _GUICtrlCreateTFLabel UDF | WinControlSetEvent UDF | Mod. for _DirGetSizeEx UDF
 
AutoIt_Icon_small.pngExamples: 
ScreenSaver Demo - Matrix included | Gui Drag Without pause the script | _WinAttach()! | Turn Off/On Monitor | ComboBox Handler Example | Mod. for "Thinking Box" | Cool "About" Box | TasksBar Imitation Demo

Like the Projects/UDFs/Examples? Please rate the topic (up-right corner of the post header: Rating AutoIt_Rating.gif)

* === My topics === *

==================================================
My_Userbar.gif
==================================================

 

 

 

AutoIt is simple, subtle, elegant. © AutoIt Team

Share this post


Link to post
Share on other sites

#16 ·  Posted (edited)

magician13134

Hi, great script you have there :P ... (put your code please in [autоit]code[/autоit] tags, that will not look so big).

Where can i get the includes that it needs? (mostly i am intersted in "compinfo.au3" and "CPU.au3"). Thanks.

I am trying to do something like that in my self.. it will be like taskmgr, but more infoabale (include more info :D ).

Here is one example I found in these forums. I had to modify it a little bit, but It is okay now.

Thanks for creator of a original code! It was :whistle:

#comments-start
Program lists all running processes.
User can kill prosesses and program makes sure it's ok.

I found orginal code from AutoIT's Forums and changed it a little bit.
#comments-end

#include <GUIConstants.au3>


; systray menu
Opt("TrayMenuMode",1)
Opt("TrayAutoPause",0)

$exititem   = TrayCreateItem("Exit")
TraySetState()

;GUI
$hGui = GUICreate("Process listing"                             , 331, 290)
    GUISetState ()
    GUICtrlCreateGroup("Processes"                              , 123,   1, 205, 284)
    $list=GUICtrlCreateList (""                                 , 126,  15, 198, 266)
    GUICtrlSetLimit(-1,200); to limit horizontal scrolling
    GUICtrlSetData(-1, _FormatProcessList())
    $Button_1 = GUICtrlCreateButton ("Refresh list"             ,   5,   5,  70,  20)
    GUICtrlSetState(-1, $GUI_FOCUS)
    $Button_2 = GUICtrlCreateButton ("Kill chosen process"                  ,   5,  40, 115,  20)
    $Button_3 = GUICtrlCreateButton ("Open new process"     ,   5,  75, 115,  20)
    $Exit = GUICtrlCreateButton ("Exit"                         ,   5, 264,  60,  20)

While 1
    $msg = GUIGetMsg()

    Switch $Msg
                Case $Button_1
                    GUICtrlSetData($List, "")
                    GUICtrlSetData($List, _FormatProcessList())
                
                Case $Button_2
                    $selected = GUICtrlRead($list)
                    If $Selected = "" Then
                        MsgBox(0, "Processes", "Pick a process to kill.")
                    Else
                        $processkill = MsgBox(4, "Processes", "Do yoy really want to kill process " & $selected & "?")
                        if $processkill = 6 Then
                            ProcessClose($selected)
                            GUICtrlSetData($List, "")
                            GUICtrlSetData($List, _FormatProcessList())
                        EndIf
                    EndIf   
                Case $Button_3
                    $fileopen = FileOpenDialog("Open program", @MyDocumentsDir, "Programs (*.exe;*.com)", 3)
                If Not @error Then run($fileopen)
                
                Case $Exit
                    ExitLoop
            EndSwitch

    $msg = TrayGetMsg()
        Select
            Case $msg = 0
                ContinueLoop
            Case $msg = $exititem
                ExitLoop
        EndSelect
    Wend

; Funktioita
Func Refresh()
    GUICtrlSetData($List, "")
    GUICtrlSetData($List, _FormatProcessList())
EndFunc

Func _FormatProcessList()
    Local $list = ProcessList()
    Local $retstr = 0
    For $i = 1 To $list[0][0]
        $retstr = $retstr & $list[$i][0]
        If $i < $list[0][0] Then $retstr = $retstr & "|"
    Next
    Return $retstr
EndFunc

Does this help?

Edited by freeman7

-------------------------------------------------------People keeping order at their stuff are just too lazy to search anything...Test these:Easy-to-use notepad

Share this post


Link to post
Share on other sites

#17 ·  Posted (edited)

magician13134

Hi, great script you have there :whistle: ... (put your code please in [autоit]code[/autоit] tags, that will not look so big).

Where can i get the includes that it needs? (mostly i am intersted in "compinfo.au3" and "CPU.au3"). Thanks.

I am trying to do something like that in my self.. it will be like taskmgr, but more infoabale (include more info :P ).

There was another task manager written here that gave quite a bit of info. Mine only gives info on processes with window...

@freeman - Yoy?

$processkill = MsgBox(4, "Processes", "Do yoy really want to kill process " & $selected & "?")

Edited by magician13134

Share this post


Link to post
Share on other sites

freeman7

Here is one example I found in these forums. I had to modify it a little bit, but It is okay now.

Thanks, but i need somthing much complicated :D (i don't realy need it, but i do :P ).

magician13134

There was another task manager written here that gave quite a bit of info. Mine only gives info on processes with window...

I can not find these includes, the Include <Cpu.au3> in your script what for? it include function that returns some info about CPU usage/load?

What in general i need, is to find a quick way to get CPU usage info (for each process and for all process generaly).

Thanks anyway, i already find some usefull info in your script :whistle:


 

Spoiler

Using OS: Win 7 Professional, Using AutoIt Ver(s): 3.3.6.1 / 3.3.8.1

AutoIt_Rus_Community.png AutoIt Russian Community

My Work...

Spoiler

AutoIt_Icon_small.pngProjects: ATT - Application Translate Tool {new}| BlockIt - Block files & folders {new}| SIP - Selected Image Preview {new}| SISCABMAN - SciTE Abbreviations Manager {new}| AutoIt Path Switcher | AutoIt Menu for Opera! | YouTube Download Center! | Desktop Icons Restorator | Math Tasks | KeyBoard & Mouse Cleaner | CaptureIt - Capture Images Utility | CheckFileSize Program

AutoIt_Icon_small.pngUDFs: OnAutoItErrorRegister - Handle AutoIt critical errors {new}| AutoIt Syntax Highlight {new}| Opera Library! | Winamp Library | GetFolderToMenu | Custom_InputBox()! | _FileRun UDF | _CheckInput() UDF | _GUIInputSetOnlyNumbers() UDF | _FileGetValidName() UDF | _GUICtrlCreateRadioCBox UDF | _GuiCreateGrid() | _PathSplitByRegExp() | _GUICtrlListView_MoveItems - UDF | GUICtrlSetOnHover_UDF! | _ControlTab UDF! | _MouseSetOnEvent() UDF! | _ProcessListEx - UDF | GUICtrl_SetResizing - UDF! | Mod. for _IniString UDFs | _StringStripChars UDF | _ColorIsDarkShade UDF | _ColorConvertValue UDF | _GUICtrlTab_CoverBackground | CUI_App_UDF | _IncludeScripts UDF | _AutoIt3ExecuteCode | _DragList UDF | Mod. for _ListView_Progress | _ListView_SysLink | _GenerateRandomNumbers | _BlockInputEx | _IsPressedEx | OnAutoItExit Handler | _GUICtrlCreateTFLabel UDF | WinControlSetEvent UDF | Mod. for _DirGetSizeEx UDF
 
AutoIt_Icon_small.pngExamples: 
ScreenSaver Demo - Matrix included | Gui Drag Without pause the script | _WinAttach()! | Turn Off/On Monitor | ComboBox Handler Example | Mod. for "Thinking Box" | Cool "About" Box | TasksBar Imitation Demo

Like the Projects/UDFs/Examples? Please rate the topic (up-right corner of the post header: Rating AutoIt_Rating.gif)

* === My topics === *

==================================================
My_Userbar.gif
==================================================

 

 

 

AutoIt is simple, subtle, elegant. © AutoIt Team

Share this post


Link to post
Share on other sites

#19 ·  Posted (edited)

Here ya go...

I'm still working on making a CPU graph that doesn't max out the CPU, when I do, I'll upload the final source code. Good luck on your project

Here's the other I was talking about:

http://www.autoitscript.com/forum/index.php?showtopic=11274

CPU.au3

CompInfo.au3

Edited by magician13134

Share this post


Link to post
Share on other sites

Wow man! it's amaizing script! thank you wery much, i found there many many usefull stuff, and whole new spectrom of AutoIt view (for me) :whistle:

P.S

When i finish my project, i will post it here on the forum! (with your help, it will be something new, better then standard taskmgr - i hope you don't mind :"> ).

Thanks again!


 

Spoiler

Using OS: Win 7 Professional, Using AutoIt Ver(s): 3.3.6.1 / 3.3.8.1

AutoIt_Rus_Community.png AutoIt Russian Community

My Work...

Spoiler

AutoIt_Icon_small.pngProjects: ATT - Application Translate Tool {new}| BlockIt - Block files & folders {new}| SIP - Selected Image Preview {new}| SISCABMAN - SciTE Abbreviations Manager {new}| AutoIt Path Switcher | AutoIt Menu for Opera! | YouTube Download Center! | Desktop Icons Restorator | Math Tasks | KeyBoard & Mouse Cleaner | CaptureIt - Capture Images Utility | CheckFileSize Program

AutoIt_Icon_small.pngUDFs: OnAutoItErrorRegister - Handle AutoIt critical errors {new}| AutoIt Syntax Highlight {new}| Opera Library! | Winamp Library | GetFolderToMenu | Custom_InputBox()! | _FileRun UDF | _CheckInput() UDF | _GUIInputSetOnlyNumbers() UDF | _FileGetValidName() UDF | _GUICtrlCreateRadioCBox UDF | _GuiCreateGrid() | _PathSplitByRegExp() | _GUICtrlListView_MoveItems - UDF | GUICtrlSetOnHover_UDF! | _ControlTab UDF! | _MouseSetOnEvent() UDF! | _ProcessListEx - UDF | GUICtrl_SetResizing - UDF! | Mod. for _IniString UDFs | _StringStripChars UDF | _ColorIsDarkShade UDF | _ColorConvertValue UDF | _GUICtrlTab_CoverBackground | CUI_App_UDF | _IncludeScripts UDF | _AutoIt3ExecuteCode | _DragList UDF | Mod. for _ListView_Progress | _ListView_SysLink | _GenerateRandomNumbers | _BlockInputEx | _IsPressedEx | OnAutoItExit Handler | _GUICtrlCreateTFLabel UDF | WinControlSetEvent UDF | Mod. for _DirGetSizeEx UDF
 
AutoIt_Icon_small.pngExamples: 
ScreenSaver Demo - Matrix included | Gui Drag Without pause the script | _WinAttach()! | Turn Off/On Monitor | ComboBox Handler Example | Mod. for "Thinking Box" | Cool "About" Box | TasksBar Imitation Demo

Like the Projects/UDFs/Examples? Please rate the topic (up-right corner of the post header: Rating AutoIt_Rating.gif)

* === My topics === *

==================================================
My_Userbar.gif
==================================================

 

 

 

AutoIt is simple, subtle, elegant. © AutoIt Team

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0