I need more help with gui!

[LeHuynhNam]

I have a gui like that

and when i click expand button it appears

and when i click contract button it returns gui 1

What can i do to do this?

[Bert]

You can use 2 different methods to handle this problem.

Method 1: Have 2 GUIs and only one is shown. The small screen would be shown by default. When the "Expand" button is clicked, the GUI that is the small screen is hidden while the GUI that is the big screen is shown. Use GUISetState to do this. You will need to make sure you use unique IDs for all the controls in both GUIS so that there is no conflict.

Method 2: Use one GUI, but when the "Expand" button is clicked, have the GUI resize itself with WinMove, and move the controls with GUICtrlSetPos. When the "Contract" button is clicked, you will need to move the controls back.

Either method will work, but it depends on how you want to do it.

[MrCreatoR]

Method 2 example:

expandcollapse popup

#include <GuiConstants.au3>
#include <ButtonConstants.au3>
#include <WindowsConstants.au3>
#include <GuiImageList.au3>
;

Global $hImageList

$hGUI = GUICreate("Expand GUI Example", 300, 200, -1, -1, -1, $WS_EX_TOOLWINDOW)

#Region Expanded controls
$sOld_Opt_GRM = Opt("GUIResizeMode", $GUI_DOCKALL)

$Expand_Button = GUICtrlCreateButton("Expand", 20, 80, 80, 22, $BS_ICON)
_GUICtrlButton_SetImageEx($hImageList, $Expand_Button, @SystemDir & "\rasdlg.dll", 14)

GUICtrlCreateButton("Some Button", 20, 240, 80)
GUICtrlCreateButton("Other Button", 120, 240, 80)
GUICtrlCreateInput("Some Input", 20, 200, 200, 20)

Opt("GUIResizeMode", $sOld_Opt_GRM)
#EndRegion Expanded controls
;

GUISetState()

While 1
    $Msg = GUIGetMsg()
    
    Switch $Msg
        Case -3
            _GUIImageList_Destroy($hImageList)
            Exit
        Case $Expand_Button
            _Toggle_ExpandControls_Proc($hGUI, 300, 200, $Expand_Button)
    EndSwitch
WEnd

Func _Toggle_ExpandControls_Proc($hWnd,$iInitWndHeight,$iExpndHeight,$iExpndCtrlID,$sExpndText="Expand",$sCntrctText="Contract")
    Local $iHeight, $sButtonText, $aSysCaptMetrics, $aSysBordMetrics
    
    Local Const $SM_CYCAPTION       = 4 ;Caption (Title) heigth
    Local Const $SM_CXFIXEDFRAME    = 7 ;Window border size
    
    $aSysCaptMetrics = DllCall('user32.dll', 'int', 'GetSystemMetrics', 'int', $SM_CYCAPTION)
    $aSysBordMetrics = DllCall('user32.dll', 'int', 'GetSystemMetrics', 'int', $SM_CXFIXEDFRAME)
    
    $aGuiPos = WinGetPos($hWnd)
    
    If $aGuiPos[3] < $iInitWndHeight + $aSysCaptMetrics[0] Then
        _GUICtrlButton_SetImageEx($hImageList, $Expand_Button, @SystemDir & "\rasdlg.dll", 16)
        
        $iHeight = $iInitWndHeight + $aSysCaptMetrics[0] + $aSysBordMetrics[0]
        $sButtonText = $sCntrctText
    Else
        _GUICtrlButton_SetImageEx($hImageList, $Expand_Button, @SystemDir & "\rasdlg.dll", 14)
        
        $iHeight = $iExpndHeight + $aSysCaptMetrics[0] + $aSysBordMetrics[0] + 2
        $sButtonText = $sExpndText
    EndIf
    
    GUICtrlSetData($iExpndCtrlID, $sButtonText)
    WinMove($hWnd, "", $aGuiPos[0], $aGuiPos[1], $aGuiPos[2], $iHeight)
EndFunc

Func _GUICtrlButton_SetImageEx(ByRef $hImageList, $nCtrl, $sIconFile, $nIconID=0, $nAlign=-1)
    If $hImageList Then _GUIImageList_Destroy($hImageList)
    
    $hImageList = _GUIImageList_Create(16, 16, 5, 1)
    _GUIImageList_AddIcon($hImageList, $sIconFile, $nIconID)
    
    Local $stBIL = DllStructCreate("dword;int[4];uint")
    
    DllStructSetData($stBIL, 1, $hImageList)
    DllStructSetData($stBIL, 2, 1, 1)
    DllStructSetData($stBIL, 2, 1, 2)
    DllStructSetData($stBIL, 2, 1, 3)
    DllStructSetData($stBIL, 2, 1, 4)
    DllStructSetData($stBIL, 3, $nAlign)
    
    Return GUICtrlSendMsg($nCtrl, $BCM_SETIMAGELIST, 0, DllStructGetPtr($stBIL))
EndFunc

[LeHuynhNam]

Thanks for quick reply but when i have a skin with this gui, can it changed?