detect if user have cliked on start button

[FireFox]

Hi,

I want to know if its possible to detect if user have clicked on start button, i've already think to this :

Check click with _IsPressed("01") and check if cursor is on start button...

Check if start menu exists [CLASS:DV2ControlHost]

But this isnt precise for detect if user have clicked on start button

Thanks for anyhelp

[Aladdin]

a nice example by ChrisL

#566895

search the forum for more results.

[MrCreatoR]

But this isnt precise for detect if user have clicked on start button

Try this:

expandcollapse popup

#include <Misc.au3>

HotKeySet("^q", "Quit")

Global $iTimer = -1

Global $hDllOpen = DllOpen("User32.dll")
Global $hStart_Button = ControlGetHandle("[CLASS:Shell_TrayWnd]", "", "Button1")

While 1
    Sleep(10)
    
    If _IsPressed(01, $hDllOpen) Then
        ToolTip("")
        $iTimer = -1
        
        If _GetHovered_hWnd() = $hStart_Button Then
            ToolTip("Start Button IsPressed!", 0, 0, "Start Button", 1, 6)
            $iTimer = TimerInit()
        EndIf
    EndIf
    
    If $iTimer <> -1 And TimerDiff($iTimer) >= 3000 Then
        ToolTip("")
        $iTimer = -1
    EndIf
WEnd

Func _GetHovered_hWnd()
    Local $iOld_Opt_MCM = Opt("MouseCoordMode", 1)
    
    Local $iRet = DllCall("user32.dll", "int", "WindowFromPoint", _
        "long", MouseGetPos(0), _
        "long", MouseGetPos(1))
    
    Opt("MouseCoordMode", $iOld_Opt_MCM)
    
    Return $iRet[0]
EndFunc

Func Quit()
    DllClose($hDllOpen)
    
    Exit
EndFunc

Edit: Changed a little bit the example.

Edited December 19, 2008 by MrCreatoR

[FireFox]

@Aladdin

Thanks for reply but example of ChrisL doesn't work for me

@MrCreatoR

Thanks it works fine !

Edited December 19, 2008 by FireFox

[rasim]

@MrCreatoR

But if user has pressed the Windows button?

@FireFox

Another way:

#include <GuiButton.au3>

HotKeySet("{Esc}", "_Exit")

$hButton = ControlGetHandle("[Class:Shell_TrayWnd]", "", "[Class:Button;Instance:1]")

While 1
    If BitAND(_GUICtrlButton_GetState($hButton), $BST_PUSHED) Then
        ToolTip("Button is pressed", 10, 0, "Start button state", 1)
    ElseIf _GUICtrlButton_GetState($hButton) = 0 Then
        ToolTip("Button is not pressed", 10, 0, "Start button state", 1)
    EndIf
    
    Sleep(50)
WEnd

Func _Exit()
    ToolTip("")
    Exit
EndFunc

[FireFox]

@rasim

Thanks ! thats better than one by MrCreatoR !

[MrCreatoR]

rasim

Another way:

Nice!