Context Menu on Hovered Control

[Floppy]

Hello,

I want to show the context menu on the control hovered by mouse.

I'm writed this script...but it doesn't work:

#include <GuiConstants.au3>

$main=GUICreate("Test Window",500,400)
GUICtrlCreateButton("Hello World!",100,100,50,50)
GUICtrlCreateLabel("Hello World!",300,100,50,50)
GUISetState(@SW_SHOW,$main)

$cursor_info2=GUIGetCursorInfo($main)
$ctrl_id=$cursor_info2[4]
$ctrl_menu=GUICtrlCreateContextMenu($ctrl_id)
GUICtrlCreateMenuItem("Test",$ctrl_menu)

While 1
    $m=GUIGetMsg()
    Select
    Case $m=$gui_event_close
        ExitLoop
    EndSelect
    WEnd

bye

#sorry for english#

Edited January 20, 2009 by FSoft

[MrCreatoR]

You can do it with GUICtrlSetOnHover UDF:

expandcollapse popup

#include <GuiConstants.au3>
#include <GUICtrlSetOnHover_UDF.au3>
;

Global $iShowMenu = False
Global $hHover_CtrlID = 0

$hGUI = GUICreate("GUICtrlSetOnHover - Show Menu Example",500,400)

$Button = GUICtrlCreateButton("Button", 100, 100, 50, 50)
GUICtrlSetOnHover(-1, "_ShowMenu_Proc")

$Label = GUICtrlCreateLabel("Label", 300, 100, -1, 15)
GUICtrlSetOnHover(-1, "_ShowMenu_Proc")

GUISetState(@SW_SHOW, $hGUI)

$Dummy_Ctrl = GUICtrlCreateDummy()

$Context_Menu = GUICtrlCreateContextMenu($Dummy_Ctrl)

$Some_CMItem = GUICtrlCreateMenuItem("Some Item", $Context_Menu)
$Exit_CMItem = GUICtrlCreateMenuItem("Exit", $Context_Menu)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE, $Exit_CMItem
            ExitLoop
    EndSwitch
    
    If $iShowMenu Then
        $iShowMenu = False
        _GUICtrlShowMenu($hGUI, $Context_Menu, $hHover_CtrlID)
    EndIf
WEnd

Func _ShowMenu_Proc($iCtrlID)
    $iShowMenu = True
    $hHover_CtrlID = $iCtrlID
EndFunc

; Show a menu in a given GUI window which belongs to a given GUI ctrl
Func _GUICtrlShowMenu($hWnd, $nContextID, $nContextControlID, $iMouse=0)
    Local $hMenu = GUICtrlGetHandle($nContextID)
    Local $iCtrlPos = ControlGetPos($hWnd, "", $nContextControlID)
    
    Local $iX = $iCtrlPos[0]
    Local $iY = $iCtrlPos[1] + $iCtrlPos[3]
    
    ; Convert the client (GUI) coordinates to screen (desktop) coordinates
    ;ClientToScreen
    Local $stPoint = DllStructCreate("int;int")
    
    DllStructSetData($stPoint, 1, $iX)
    DllStructSetData($stPoint, 2, $iY)

    DllCall("user32.dll", "int", "ClientToScreen", "hwnd", $hWnd, "ptr", DllStructGetPtr($stPoint))
    
    $iX = DllStructGetData($stPoint, 1)
    $iY = DllStructGetData($stPoint, 2)
    ;ClientToScreen
    
    If $iMouse Then
        $iX = MouseGetPos(0)
        $iY = MouseGetPos(1)
    EndIf
    
    DllCall("user32.dll", "int", "TrackPopupMenuEx", "hwnd", $hMenu, "int", 0, "int", $iX, "int", $iY, "hwnd", $hWnd, "ptr", 0)
EndFunc

[Floppy]

I get an error on line 46:

_GUICtrlShowMenu($hGUI, $Context_Menu, $hHover_CtrlID)

[MrCreatoR]

I get an error on line 46:

_GUICtrlShowMenu($hGUI, $Context_Menu, $hHover_CtrlID)

What error? and what version of GUICtrlSetOnHover you downloaded?