Simple progress bar (in another thread)

[SpookMeister]

It is fairly self explanatory, but basically I'm just making the script write and execute a second script that is just a progress bar, then providing a method of killing that second script when you are done.

I guess you could also call it a "bailing wire and duct tape" form of multi-threading

expandcollapse popup

; When you want to notify the user that your main script will be busy for a while
_StartProgress("Sending Email...") ; Put whatever comment you want

; Here I am just simulating your main program still running while the progress bar does its thing
$timer = TimerInit()
$seconds = 25
While TimerDiff($timer) / 1000 < $seconds
    Sleep(100)
    ToolTip("Main program running for " & Int(TimerDiff($timer) / 1000) & " seconds")
WEnd

; When you want to get rid of the progress bar
_StopProgress()

; ------------------------------------------------------------
; stick the following code at the end of your script somewhere
; ------------------------------------------------------------

Func _StartProgress($s_comment = "Please Stand By")
    $s_path = @ScriptDir & "\progress.au3"
    $h_file = FileOpen($s_path, 2)
    $s_code = 'AutoItSetOption ("TrayIconHide",1)' & @CRLF & _
            'AutoItWinSetTitle("MyProgressBar")' & @CRLF & _
            'Dim $percent = 0' & @CRLF & _
            'ProgressOn("In Progress...", "' & $s_comment & '")' & @CRLF & _
            'While ProcessExists(' & @AutoItPID & ')' & @CRLF & _
            'ProgressSet($percent)' & @CRLF & _
            '$percent += 5' & @CRLF & _
            'If $percent > 100 Then $percent = 0' & @CRLF & _
            'Sleep(500)' & @CRLF & _
            'WEnd' & @CRLF
    FileWrite($h_file, $s_code)
    FileClose($h_file)
    Run(@AutoItExe & " /AutoIt3ExecuteScript progress.au3", @ScriptDir)
EndFunc   ;==>_StartProgress

Func _StopProgress()
    If WinExists("MyProgressBar") Then WinKill("MyProgressBar")
    FileDelete(@ScriptDir & "\progress.au3")
EndFunc   ;==>_StopProgress

The progress bar just continues to go from 0% to 100% until you tell it to stop.

Click on the attachment to see what the progress bar looks like

Edited March 27, 2009 by SpookMeister

[SpookMeister]

Edited initial code to make sure the progress bar quits if the main program dies before it can call the _StopProgress() function

[Emiel Wieldraaijer]

Thanks Spookmeister

Best regards,

EMiel

[rajeshontheweb]

Hi there, when i used this piece of code, i had added a code to the main program

Func OnAutoItExit ( )
 _StopProgress()
EndFunc

This is just in case there was an unforeseen error in the script and it terminates abruptly before the stop progress was actually called :-)