[Solved] StringRegExpReplace() Question

[KaFu]

HiHo Community,

I want to create an Input Control which allows only positive 5 digit numbers with max. 2 digit decimal as input. $ES_NUMBER does not allow digits, so i thought I'll define a wm_notify or loop using StringRegExpReplace(), but I could not figure out the correct pattern. Maybe someone with deeper RegEx knowledge could help me out?

Valid:

99999.99 (only 1 dot allowed)

1.1

1

0.1 (forcing a 0 in front if . is entered first possible? Possible for sure , whats the pattern?)

Invalid:

Non-Numeric and not dot

-1

using something like

guictrlsetdata($input,StringRegExpReplace(guictrlread($input),"???","$1.$2"))

Best Regards

Edit: The "forcing 0 in front" part is in fact quiet easy, after StringRegExpReplace() I'll just append an

if stringleft(guictrlread($input,1),1) = "." then guictrlsetdata($input,0 & guictrlread($input)) , so skip that.

Edit 2: Appended (not working correct yet) test code.

So literally the expression would be something like (1-5 digits AND/OR 1 dot AND 0-2 digits).

#include<GUIConstantsEx.au3>

GUICreate("Test")
$input = GUICtrlCreateInput("", 10, 10, 100)
$input_save = ""
GUISetState()

Do
    Sleep(10)
    $input_read = GUICtrlRead($input)
    if $input_save <> $input_read Then
        $input_read = StringRegExpReplace($input_read,"[^\d]","$1")
        if stringleft($input_read,1) = "." then $input_read = 0 & $input_read
        GUICtrlSetData($input, $input_read)
        $input_save = $input_read
    endif
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Edited May 13, 2009 by KaFu

[oMBRa]

how should we replace a number with more than 5 digit like 99999999.99, or a negative one?

[KaFu]

99999.99 is max (delete/ignore 6th digit) and negative values should not be allowed.

Edited May 12, 2009 by KaFu

[SmOke_N]

$input_read = StringRegExpReplace($input_read,"^(\D*)(\d{0,5})(\d+)?(\.)?(\d{0,2})?(.*?)\z","\2\4\5")

Edit:

Interesting enough, I had to change that up a bit:

$input_read = StringRegExpReplace($input_read,"^(\D*)(\d(?:\d?\d?\d?\d?))(\d+)?(\.)?(\d{0,2})?(.*?)\z","\2\4\5")

Edited May 12, 2009 by SmOke_N

[MrCreatoR]

Check the UDF RestrictControlRegExp, and use it as following:

#include <GUIConstantsEx.au3>
#include <RestrictControlRegExp.au3>
;

_RegEx_RestrictControl_Setup()

GUICreate("Test")

$input = GUICtrlCreateInput("", 10, 10, 100)
_RegEx_RestrictControl_Add($input, "^[0-9]{1,5}\.[0-9]{0,2}$", "99999.99")

$input_save = ""

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

It's almost what you need, except the behaviour on entered dot at the begining.

[KaFu]

Interesting enough, I had to change that up a bit

Perfect , seems to fit my needs. Thanks a lot!

#include<GUIConstantsEx.au3>

GUICreate("Test")
$input = GUICtrlCreateInput("", 10, 10, 100)
$input_save = ""
GUISetState()

Do
    $input_read = GUICtrlRead($input)
    if $input_save <> $input_read Then
        if stringleft($input_read,1) = "." then $input_read = 0 & $input_read
        $input_read = StringRegExpReplace($input_read,"^(\D*)(\d(?:\d?\d?\d?\d?))(\d+)?(\.)?(\d{0,2})?(.*?)\z","\2\4\5")
        GUICtrlSetData($input, $input_read)
        $input_save = $input_read
    endif
Until GUIGetMsg() = $GUI_EVENT_CLOSE

in a wm_notify if the input looses focus.

[KaFu]

It's almost what you need, except the behaviour on entered dot at the begining.

What should be solved with an

if stringleft($input_read,1) = "." then $input_read = 0 & $input_read

somewhere within that function too, will definitely check it out. Thanks to you too ...

[MrCreatoR]

$input_read = StringRegExpReplace($input_read,"^(\D*)(\d{0,5})(\d+)?(\.)?(\d{0,2})?(.*?)\z","\2\4\5")

Edit:

Interesting enough, I had to change that up a bit:

$input_read = StringRegExpReplace($input_read,"^(\D*)(\d(?:\d?\d?\d?\d?))(\d+)?(\.)?(\d{0,2})?(.*?)\z","\2\4\5")

You keeping amaze me with those RegExp patterns every time, you are the best in it!