Caps Toggle

[Paulie]

Well, I've been fiddling around with this for a long time now, and i can't get a result that works consistently.

Basically, I'm trying to make my capslock key function like a shift key (without mapping it to shift). What i want to happen, as long as the Caps key is held down, capslock will be on, but as soon as you release caps, it turns capslock off.

I'm doing this because I want to make capslock my Push-to-Talk hotkey for Ventrilo, but i don't want to have to push it twice to avoid typing in all caps all the time.

I made a script that sort of worked, but if i clicked the mouse when capslock was being held and then released capslock, it would turn the indicator light off, as though caps wasn't on but it would still type in all caps. I dunno... it was weird.

I've tried a billion things, but here is the closest I could get:

#include <Misc.au3>
Opt("sendcapslockmode", 0)
While 1
    If GETCAPSLOCK() = 1 And Not _ISPRESSED("14") Then
        ControlSend("", "", "", "{CAPSLOCK off}")
    EndIf
    Sleep(100)
WEnd

Func GETCAPSLOCK()
    Local $RET
    $RET = DllCall("user32.dll", "long", "GetKeyState", "long", "0x14")
    Return $RET[0]
EndFunc

Edited June 4, 2009 by Paulie

[MrCreatoR]

if i clicked the mouse when capslock was being held and then released capslock, it would turn the indicator light off, as though caps wasn't on but it would still type in all caps.

I can not confirm that, the example works fine for me ...

Perhaps it's happening on some specific window? Or everywhere?

[schilbiz]

Well, I've been fiddling around with this for a long time now, and i can't get a result that works consistently.

Basically, I'm trying to make my capslock key function like a shift key (without mapping it to shift). What i want to happen, as long as the Caps key is held down, capslock will be on, but as soon as you release caps, it turns capslock off.

I'm doing this because I want to make capslock my Push-to-Talk hotkey for Ventrilo, but i don't want to have to push it twice to avoid typing in all caps all the time.

I made a script that sort of worked, but if i clicked the mouse when capslock was being held and then released capslock, it would turn the indicator light off, as though caps wasn't on but it would still type in all caps. I dunno... it was weird.

I've tried a billion things, but here is the closest I could get:

#include <Misc.au3>
Opt("sendcapslockmode", 0)
While 1
    If GETCAPSLOCK() = 1 And Not _ISPRESSED("14") Then
        ControlSend("", "", "", "{CAPSLOCK off}")
    EndIf
    Sleep(100)
WEnd

Func GETCAPSLOCK()
    Local $RET
    $RET = DllCall("user32.dll", "long", "GetKeyState", "long", "0x14")
    Return $RET[0]
EndFunc

You could cheat and just edit the registry like this.

RegWrite("HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Keyboard Layout", "Scancode Map", "REG_BINARY", "0000000000000000020000002a003a0000000000")

Then reboot, and the Caps Lock will behave like a shift key but is still considered the Caps Lock.

To disable it just remove the key. Or run this.

RegDelete("HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Keyboard Layout", "Scancode Map")

As always please make a backup copy of your registry before you edit it. ;p

[Skruge]

This is what I use to make Capslock act like Shift without re-mapping the key.

#include <Misc.au3>
Opt("SendCapslockMode", 0)

Local $hUserDLL = DllOpen("user32.dll")
  Send("{CAPSLOCK off}")
HotKeySet("{CAPSLOCK}", "_HoldCAP")

While 1
    Sleep(100)
WEnd

Func _HoldCAP()
    HotKeySet("{CAPSLOCK}")
    Send("{CAPSLOCK on}")
    Do
        Sleep(100)
    Until Not _IsPressed("14", $hUserDLL)
    ControlSend("", "", "", "{CAPSLOCK off}")
    HotKeySet("{CAPSLOCK}", "_HoldCAP")
EndFunc   ;==>_HoldCAP

One unintended but welcome side effect is that Shift-Capslock will toggle Capslock normally, for those rare times when you actually want to type in caps.

Please let me know if it works for you. I don't have Ventrilo installed here, so I'll have to test it later tonight.

p.s. Thank you for your contributions to the community.

[oMBRa]

try also this:

#include <Misc.au3>
Opt("sendcapslockmode", 0)
$Toggle = False
While 1
    If _IsPressed("14") And $Toggle = False Then
        $Toggle = True
    EndIf
    If Not _IsPressed("14") And $Toggle = True Then
        ControlSend("", "", "", "{CAPSLOCK off}")
    EndIf
    Sleep(100)
WEnd

[Valuater]

wELL.... HERE'S A STAB AT IT

HotKeySet("{CAPSLOCK}", "_GETCAPSLOCK")

While 1
    Sleep(100)
WEnd

Func _GETCAPSLOCK()
    $Begin = TimerInit()
    While __ISPRESSED("14")
        Sleep(100)
    WEnd
    $Diff = Int(TimerDiff($Begin) / 1000)
    ToolTip($Diff, 20, 20)
    If $Diff <= 1 Then Return MsgBox(4096, "CAPS", "CAPLOCK SENT   ", 1)
    Return 0
EndFunc   ;==>GETCAPSLOCK

Func __IsPressed($sHexKey, $vDLL = 'user32.dll')
    Local $a_R = DllCall($vDLL, "int", "GetAsyncKeyState", "int", '0x' & $sHexKey)
    If Not @error And BitAND($a_R[0], 0x8000) = 0x8000 Then Return 1
    Return 0
EndFunc   ;==>__IsPressed

8)