[SOLVED] MouseClicks thru the GUI

[MrCreatoR]

Hi,

I have one little(?) task to do - I am trying to allow mouse clicks thru my GUI. Here is an example of what i have tried:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <Constants.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
;

Global $aOld_Mouse_Pos = MouseGetPos()
Global $iMoveWithCursor = True

HotKeySet("^+m", "_MoveWithCursorToggle_Proc")

$hGUI = GUICreate("Test GUI", 500, 300, -1, -1, _
    BitOR($WS_POPUP, $WS_SIZEBOX), BitOR($WS_EX_TOPMOST, $WS_EX_TOOLWINDOW))

WinSetTrans($hGUI, "", 100)
GUISetBkColor(0xFF0000, $hGUI)
GUISetCursor(0, 1, $hGUI)
GUISetIcon("Shell32.dll", -35, $hGUI)

GUISetState(@SW_SHOW, $hGUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_SECONDARYUP
            _MouseClickInBkWnd($hGUI, "Secondary")
        Case $GUI_EVENT_PRIMARYUP
            _MouseClickInBkWnd($hGUI, "Main")
    EndSwitch
    
    If $iMoveWithCursor Then
        $aMouse_Pos = MouseGetPos()
        
        If $aMouse_Pos[0] <> $aOld_Mouse_Pos[0] Or $aMouse_Pos[1] <> $aOld_Mouse_Pos[1] Then
            $aGUI_Pos = WinGetPos($hGUI)
            
            Local $i_Left, $i_Top
            
            If $aMouse_Pos[0] > $aOld_Mouse_Pos[0] Then
                $i_Left = $aGUI_Pos[0] + ($aMouse_Pos[0] - $aOld_Mouse_Pos[0])
            Else
                $i_Left = $aGUI_Pos[0] - ($aOld_Mouse_Pos[0] - $aMouse_Pos[0])
            EndIf
            
            If $aMouse_Pos[1] > $aOld_Mouse_Pos[1] Then
                $i_Top = $aGUI_Pos[1] + ($aMouse_Pos[1] - $aOld_Mouse_Pos[1])
            Else
                $i_Top = $aGUI_Pos[1] - ($aOld_Mouse_Pos[1] - $aMouse_Pos[1])
            EndIf
            
            WinMove($hGUI, "", $i_Left, $i_Top)
            
            $aOld_Mouse_Pos = $aMouse_Pos
        EndIf
    EndIf
WEnd

Func _MoveWithCursorToggle_Proc()
    $iMoveWithCursor = Not $iMoveWithCursor
    $aOld_Mouse_Pos = MouseGetPos()
EndFunc

Func _MouseClickInBkWnd($sTitle, $sButton="Main", $iClicks=2)
    Local $iOld_MCM = Opt("MouseCoordMode", 1)
    Local $aMouse_Pos = MouseGetPos()
    
    WinSetState($sTitle, "", @SW_HIDE)
    
    Local $hBkWnd = DllCall("user32.dll", "int", "WindowFromPoint", "long", $aMouse_Pos[0], "long", $aMouse_Pos[1])
    $hBkWnd = _WinAPI_GetAncestor($hBkWnd[0], $GA_ROOT)
    
    Opt("MouseCoordMode", $iOld_MCM)
    
    Local $stPoint = DllStructCreate("int X;int Y")
    
    DllStructSetData($stPoint, "X", $aMouse_Pos[0])
    DllStructSetData($stPoint, "Y", $aMouse_Pos[1])
    
    _WinAPI_ScreenToClient($hBkWnd, $stPoint)
    
    Local $iX = DllStructGetData($stPoint, "X")
    Local $iY = DllStructGetData($stPoint, "Y")
    
    $iX += 2
    $iY -= 26
    
    If $sButton <> "Main" Then ControlClick($hBkWnd, "", "", "Main", $iClicks, $iX, $iY)
    ControlClick($hBkWnd, "", "", $sButton, $iClicks, $iX, $iY)
    
    WinSetState($sTitle, "", @SW_SHOWNOACTIVATE)
EndFunc

As you can see, in this example the GUI is following after mouse pointer, «Ctrl + Shift + M» hotkeys toggles this behaviour. But when the pointer inside GUI, i want it act like if there was no GUI, all clicks (and even dragging the mouse) must go thru the GUI and work for background window. I tried to build a function (_MouseClickInBkWnd()) that will do it - the idea here is to hide my GUI, get the background handle by WindowFromPoint, translate Mouse coords to client window coords, click in that coords and show back my GUI. But as you can see we have here lot of problems (blinking window, not always the clicks are passed to the bk window and few more bugs).

Any ideas of how this *can be done(?*) better?

Edited June 8, 2009 by MrCreatoR

[torels]

is this it ?

http://www.autoitscript.com/forum/index.php?showtopic=93630

[MrCreatoR]

is this it ?

Yes! It's was so simple . Thank you. Edited June 8, 2009 by MrCreatoR

[MrCreatoR]

Ok, and what if i need be able to click thru the GUI, but in the same time have the ability to resize my GUI (when $WS_SIZEBOX is used)?

[wraithdu]

Child (MDI?) gui inside a normal GUI so you have an active frame? No idea if this will work...

[martin]

Ok, and what if i need be able to click thru the GUI, but in the same time have the ability to resize my GUI (when $WS_SIZEBOX is used)?

I assume you don't want to be able to click through the sizing border.

I would make a window with the styles WS_POPUP and WS_SIZEBOX. You could make that window transparent as well but it would still be possible to resize it. Then apply a mask to make the client area transparent. Fit the transparent window in place of the client area, and use WM_NCCALCSIZE to know when the size has changed to adjust the size and position of the transparent window. You would also need to register WM_MOVE so that the border can be kept with the 'client' area.

[MrCreatoR]

Child (MDI?) gui inside a normal GUI so you have an active frame?

Thanks for the idea, i don't know about MDI childs, but using GUIHole it's can be done (not perfect, but it's a start)

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
;

HotKeySet("^+e", "_Exit_Proc")

$hGUI = GUICreate("Resizing Transparent GUI Example", 500, 300, -1, -1, _
    $WS_POPUP, BitOR($WS_EX_TOPMOST, $WS_EX_TOOLWINDOW, $WS_EX_TRANSPARENT))

$hFrame_GUI = GUICreate("Frame", 500, 300, -1, -1, _
    BitOR($WS_POPUP, $WS_SIZEBOX), BitOR($WS_EX_TOPMOST, $WS_EX_TOOLWINDOW))

_GUICreateHole($hFrame_GUI, 4, 4, 497, 297)
_GUISetOptions_Proc()

GUISetState(@SW_SHOW, $hGUI)
GUISetState(@SW_SHOW, $hFrame_GUI)

WM_SIZE()

GUIRegisterMsg($WM_SIZE, "WM_SIZE")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _GUISetOptions_Proc()
    Local $aHWnds[2] = [$hGUI, $hFrame_GUI]
    
    For $i = 0 To 1
        WinSetTrans($aHWnds[$i], "", 100)
        GUISetBkColor(0xFF0000, $aHWnds[$i])
        GUISetCursor(0, 1, $aHWnds[$i])
    Next
EndFunc

Func _GUICreateHole($hWin, $i_X, $i_Y, $i_SizeW, $i_SizeH)
    Local $aWinPos, $aOuter_Rgn, $aInner_Rgn, $aCombined_Rgn
    
    Local Const $RGN_AND = 1
    Local Const $RGN_OR = 2
    Local Const $RGN_XOR = 3
    Local Const $RGN_DIFF = 4
    Local Const $RGN_COPY = 5
    
    $aWinPos = WinGetPos($hWin)
    
    $aOuter_Rgn = DllCall("gdi32.dll", "long", "CreateRectRgn", "long", 0, "long", 0, "long", $aWinPos[2], "long", $aWinPos[3])
    $aInner_Rgn = DllCall("gdi32.dll", "long", "CreateRectRgn", "long", _
        $i_X, "long", $i_Y, "long", $i_X + $i_SizeW, "long", $i_Y + $i_SizeH)
    
    $aCombined_Rgn = DllCall("gdi32.dll", "long", "CreateRectRgn", "long", 0, "long", 0, "long", 0, "long", 0)
    
    DllCall("gdi32.dll", "long", "CombineRgn", _
        "long", $aCombined_rgn[0], "long", $aOuter_Rgn[0], "long", $aInner_Rgn[0], "int", $RGN_DIFF)
    
    DllCall("user32.dll", "long", "SetWindowRgn", "hwnd", $hWin, "long", $aCombined_Rgn[0], "int", 1)
EndFunc

Func WM_SIZE($hWnd=0, $MsgID=0, $wParam=0, $lParam=0)
    Local $aGUI_Pos = WinGetPos($hGUI)
    Local $aFrameGUI_Pos = WinGetPos($hFrame_GUI)
    
    GUIRegisterMsg($WM_SIZE, "")
    
    If $hWnd = $hGUI Then
        WinMove($hFrame_GUI, "", $aGUI_Pos[0], $aGUI_Pos[1], $aGUI_Pos[2], $aGUI_Pos[3])
    Else
        WinMove($hGUI, "", $aFrameGUI_Pos[0], $aFrameGUI_Pos[1], $aFrameGUI_Pos[2], $aFrameGUI_Pos[3])
    EndIf
    
    If IsHWnd($hWnd) Then _GUICreateHole($hFrame_GUI, 4, 4, $aGUI_Pos[2]-10, $aGUI_Pos[3]-10)
    
    GUIRegisterMsg($WM_SIZE, "WM_SIZE")
EndFunc

Func _Exit_Proc()
    Exit
EndFunc

[wraithdu]

This is with an MDI child. I think it's really close (except the window frame changes after the create hole function).

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
;

HotKeySet("^+e", "_Exit_Proc")



$hFrame_GUI = GUICreate("Frame", 500, 300, -1, -1, _
    BitOR($WS_POPUP, $WS_SIZEBOX), BitOR($WS_EX_TOPMOST, $WS_EX_TOOLWINDOW))

$hGUI = GUICreate("Resizing Transparent GUI Example", 500, 300, 4, 4, _
    $WS_POPUP, BitOR($WS_EX_MDICHILD, $WS_EX_TOOLWINDOW, $WS_EX_TRANSPARENT), $hFrame_GUI)

_GUICreateHole($hFrame_GUI, 4, 4, 497, 297)
_GUISetOptions_Proc()

GUISetState(@SW_SHOW, $hGUI)
GUISetState(@SW_SHOW, $hFrame_GUI)

WM_SIZE($hFrame_GUI)

GUIRegisterMsg($WM_SIZE, "WM_SIZE")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _GUISetOptions_Proc()
    Local $aHWnds[2] = [$hGUI, $hFrame_GUI]

    For $i = 0 To 1
        WinSetTrans($aHWnds[$i], "", 100)
        GUISetBkColor(0xFF0000, $aHWnds[$i])
        GUISetCursor(0, 1, $aHWnds[$i])
    Next
EndFunc

Func _GUICreateHole($hWin, $i_X, $i_Y, $i_SizeW, $i_SizeH)
    Local $aWinPos, $aOuter_Rgn, $aInner_Rgn, $aCombined_Rgn

    Local Const $RGN_AND = 1
    Local Const $RGN_OR = 2
    Local Const $RGN_XOR = 3
    Local Const $RGN_DIFF = 4
    Local Const $RGN_COPY = 5

    $aWinPos = WinGetPos($hWin)

    $aOuter_Rgn = DllCall("gdi32.dll", "long", "CreateRectRgn", "long", 0, "long", 0, "long", $aWinPos[2], "long", $aWinPos[3])
    $aInner_Rgn = DllCall("gdi32.dll", "long", "CreateRectRgn", "long", _
        $i_X, "long", $i_Y, "long", $i_X + $i_SizeW, "long", $i_Y + $i_SizeH)

    $aCombined_Rgn = DllCall("gdi32.dll", "long", "CreateRectRgn", "long", 0, "long", 0, "long", 0, "long", 0)

    DllCall("gdi32.dll", "long", "CombineRgn", _
        "long", $aCombined_rgn[0], "long", $aOuter_Rgn[0], "long", $aInner_Rgn[0], "int", $RGN_DIFF)

    DllCall("user32.dll", "long", "SetWindowRgn", "hwnd", $hWin, "long", $aCombined_Rgn[0], "int", 1)
EndFunc

Func WM_SIZE($hWnd=0, $MsgID=0, $wParam=0, $lParam=0)
    Switch $hWnd
        Case $hFrame_GUI
            Local $aFrameGUI_Pos = WinGetPos($hFrame_GUI)
            _GUICreateHole($hFrame_GUI, 4, 4, $aFrameGUI_Pos[2]-8, $aFrameGUI_Pos[3]-8)
            WinMove($hGUI, "", $aFrameGUI_Pos[0] + 4, $aFrameGUI_Pos[1] + 4, $aFrameGUI_Pos[2] - 8, $aFrameGUI_Pos[3] - 8)
    EndSwitch
EndFunc

Func _Exit_Proc()
    Exit
EndFunc

Edited June 16, 2009 by wraithdu