Making a skin. How to make: an image on my "button" changes when I moves a mouse on it?

[GodlessSinner]

How to change an image on my "button" when I move a mouse cursor on it?

Trimmed example is listed below:

Attachments - 2 archived images(30kb).

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
Global $temp[2], $shown =0
AutoItSetOption("MouseCoordMode", 1)
#Region ### START Koda GUI section ### Form=
$img = @DesktopDir
$Form1 = GUICreate("Form1", 302, 158, 353, 305)
GUISetBkColor(0x000000)
$Pic = GUICtrlCreatePic($img & "\1.jpg", 104, 64, 75, 30, BitOR($SS_NOTIFY,$WS_GROUP,$WS_CLIPSIBLINGS))
$Info = GUICtrlCreateInput("", 10, 8, 280, 21)
$contpos = ControlGetPos("Form1", "", "[CLASS:Static; INSTANCE:1]")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


;MouseGetPos() in this example is result of hight(~50%) CPU usage:(  
While 1
    $pos = MouseGetPos()
    If $pos[0] <> $temp[0] Or $pos[1] <> $temp[1] Then; do something when mouse moved
        $winpos = WinGetPos("Form1")
        GUICtrlSetData($Info, "Abs.mouse coords:" & $pos[0] & "x" & $pos[1] & "   |   Button coords:" & $winpos[0] + $contpos[0] & "x" & $winpos[1] + $contpos[1])
        $temp = MouseGetPos() 
        If $pos[0] > $winpos[0] + $contpos[0] And $pos[0] < $winpos[0] + $contpos[0] + $contpos[2] And $pos[1] > $winpos[1] + $contpos[1] And $pos[1] < $winpos[1] +  $contpos[1] + $contpos[3] Then; when you move mouse to 'button', above button:(
            If $shown = 0 Then
                GUICtrlSetImage($Pic, $img & "\1.jpg")
                $shown = 1
            EndIf
        Else
            GUICtrlSetImage($Pic, $img & "\2.jpg")  
            $shown = 0
        EndIf   
    EndIf

As you see, an image changes when mouse moved above ~30px from button, because ControlGetPos returns

the control's position relative to it's client window

ButtonImages.rar

[MrCreatoR]

How to change an image on my "button" when I move a mouse cursor on it?

Look at «GUICtrlSetOnEvent UDF» in my signature.

[MrCreatoR]

And you don't need to check the control position, you have GUIGetCursorInfo() for that:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
;

Global $aOld_Mouse_Pos[2], $iPic_Is_Shown = 0
Global $sImage_Path = @ScriptDir

Opt("MouseCoordMode", 1)

$hForm = GUICreate("Form1", 302, 158, 353, 305)
GUISetBkColor(0x000000)

$Pic = GUICtrlCreatePic($sImage_Path & "\1.jpg", 104, 64, 75, 30, BitOR($SS_NOTIFY, $WS_GROUP, $WS_CLIPSIBLINGS))

$Info = GUICtrlCreateInput("", 10, 8, 280, 21)
$aCtrl_Pos = ControlGetPos($hForm, "", $Pic)

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
    
    $aMouse_Pos = MouseGetPos()
    
    If $aMouse_Pos[0] <> $aOld_Mouse_Pos[0] Or $aMouse_Pos[1] <> $aOld_Mouse_Pos[1] Then
        $aOld_Mouse_Pos = MouseGetPos() 
        $aWin_Pos = WinGetPos($hForm)
        
        $aCursorInfo = GUIGetCursorInfo($hForm)
        
        GUICtrlSetData($Info, _
            StringFormat("Abs.mouse coords:%ix%i      |   Button coords:%ix%i", _
                $aMouse_Pos[0], $aMouse_Pos[1], $aWin_Pos[0] + $aCtrl_Pos[0], $aWin_Pos[1] + $aCtrl_Pos[1]))
        
        If $aCursorInfo[4] = $Pic Then
            If $iPic_Is_Shown = 0 Then
                GUICtrlSetImage($Pic, $sImage_Path & "\1.jpg")
                $iPic_Is_Shown = 1
            EndIf
        Else
            GUICtrlSetImage($Pic, $sImage_Path & "\2.jpg")    
            $iPic_Is_Shown = 0
        EndIf    
    EndIf
WEnd

[MrCreatoR]

Using GUICtrlSetOnHover UDF:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <GUICtrlSetOnHover_UDF.au3>
;

Global $sImage_Path = @ScriptDir

Opt("MouseCoordMode", 1)

$hForm = GUICreate("Form1", 302, 158, 353, 305)
GUISetBkColor(0x000000)

$Pic = GUICtrlCreatePic($sImage_Path & "\2.jpg", 104, 64, 75, 30, BitOR($SS_NOTIFY, $WS_GROUP, $WS_CLIPSIBLINGS))
_GUICtrl_SetOnHover(-1, "_HoverPic_Proc", "_HoverPic_Proc")

$Info_Input = GUICtrlCreateInput("", 10, 8, 280, 21)

GUISetState(@SW_SHOW)
GUIRegisterMsg($WM_MOUSEMOVE, "WM_MOUSEMOVE")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func WM_MOUSEMOVE($hWnd, $iMsg, $wParam, $lParam)
    Local $aWin_Pos = WinGetPos($hForm)
    Local $aCtrl_Pos = ControlGetPos($hForm, "", $Pic)
    Local $aMouse_Pos = MouseGetPos()
    Local $aCursor_Info = GUIGetCursorInfo($hForm)
    
    GUICtrlSetData($Info_Input, _
        StringFormat("Abs.mouse coords:%ix%i      |   Button coords:%ix%i", _
            $aMouse_Pos[0], $aMouse_Pos[1], $aWin_Pos[0] + $aCtrl_Pos[0], $aWin_Pos[1] + $aCtrl_Pos[1]))
EndFunc

Func _HoverPic_Proc($iCtrlID, $iHoverMode)
    If $iHoverMode = 1 Then
        GUICtrlSetImage($Pic, $sImage_Path & "\1.jpg")
    Else
        GUICtrlSetImage($Pic, $sImage_Path & "\2.jpg") 
    EndIf
EndFunc

[froufrou]

Definitely look @ MrCreatoR GUICtrlSetOnHover UDF it fixed all my issues with the exact same questions your asking.Its a great UDF.