23 replies to this topic

[llewxam]

For years I have been coding my own data backup tools, choosing to not use the tools that Microsoft has been bundling with their operating systems. I recently decided to switch tactics and go with USMT, and while I have only used it in real-world break-fix conditions for less than a week, I have decided that it may be the way to go.

There is a lot of fuss about how complicated it is to use. Well, I kinda agree, kinda don't, but decided to put this front end together mainly just to speed up the process. What you will need to do to use it is download the USMT Front End Extras.7z archive and extract that to @ScriptDir prior to compiling. The archive contains 32 and 64 bit versions of USMT 3.01 and USMT 4.01, as well as 7z.exe, 7z.dll, and a few simple JPGs used to pretty up the GUI a bit.

Please read the Technet docs on USMT if you have concerns about the data that it will migrate for you, as the only modification I have made to any of the XML files is to omit migrating Start Menu files, I just can't see the point of that one! Otherwise, all XMLs are bone-stock. Also be aware of the difference between USMT 3.01 and 4.01, click here for a quick reference.

I have also taken the liberty of tweaking the options used to suit my own purposes, which include creating a folder based on repair data used at my shop and specifying things such as /localonly which will exclude network shares etc. Ensure the options used here are what you need, and adjust accordingly!!

USMT Front End Extras.7z

AutoIt        expandcollapse  popup

#RequireAdmin
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_UseUpx=n
#AutoIt3Wrapper_Run_Tidy=y
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <StaticConstants.au3>

;~ User State Migration Tool Front End
;~ Coded by Ian Maxwell (llewxam @ AutoIt forum)

Local $TargetBrowse, $Target, $OfflineBrowse, $OfflinePath, $CreateGoButton, $MainGUI, $RestoreGoButton, $Offline, $CustName, $RepairNumber, $Tech, $Overwrite, $NoCompress, $TimesToRetry, $SecondsToWait, $MSG
$OfflineEnabled = False
$XPMode = False

$WhatFunction = GUICreate("USMT Front End - MaxImuM AdVaNtAgE SofTWarE 2011", 480, 150, @DesktopWidth / 2 - 240, @DesktopHeight / 2 - 15)
FileInstall("right.jpg", @TempDir & "\right.jpg", 1)
GUICtrlCreatePic(@TempDir & "\right.jpg", 50, 20, 160, 120)
GUICtrlSetState(-1, $GUI_DISABLE)
FileInstall("left.jpg", @TempDir & "\left.jpg", 1)
GUICtrlCreatePic(@TempDir & "\left.jpg", 270, 20, 160, 120)
GUICtrlSetState(-1, $GUI_DISABLE)
$Create = GUICtrlCreateButton("CREATE Backup", 75, 62, 110, 20)
$Restore = GUICtrlCreateButton("RESTORE Backup", 295, 62, 110, 20)
$Question = GUICtrlCreateButton("?", 460, 0, 20, 20)
GUICtrlSetBkColor(-1, 0x00f700)
GUISetBkColor(0xb2ccff, $WhatFunction)
GUISetState(@SW_SHOW, $WhatFunction)
Do
    $MSG = GUIGetMsg()
    If $MSG == $GUI_EVENT_CLOSE Then Exit
    If $MSG == $Question Then _Question()
    If $MSG == $Create Then
        GUIDelete($WhatFunction)
        _CreateGUI()
        ExitLoop
    EndIf
    If $MSG == $Restore Then
        GUIDelete($WhatFunction)
        _RestoreGUI()
        ExitLoop
    EndIf
Until 1 = 2

Do
    $MSG = GUIGetMsg()
    If $MSG == $GUI_EVENT_CLOSE Then Exit
    If $MSG == $Question Then _Question()
    If $MSG == $TargetBrowse Then
        $TargetLocation = FileSelectFolder("Choose the location to save the backup data", "", 1)
        GUICtrlSetData($Target, $TargetLocation)
    EndIf
    If $MSG == $OfflineBrowse Then
        $OfflineLocation = FileSelectFolder("Select the WINDOWS folder on the OFFLINE drive", "")
        GUICtrlSetData($OfflinePath, $OfflineLocation)
    EndIf
    If $MSG == $CreateGoButton Then
        _CreateExecute()
        GUIDelete($MainGUI)
    EndIf
    If $MSG == $RestoreGoButton Then
        _RestoreExecute()
        GUIDelete($MainGUI)
    EndIf

    If GUICtrlRead($Offline) == 1 And $OfflineEnabled == False Then
        $OfflineEnabled = True
        GUICtrlSetState($OfflinePath, $GUI_ENABLE)
        GUICtrlSetState($OfflineBrowse, $GUI_ENABLE)
    EndIf
    If GUICtrlRead($Offline) == 4 And $OfflineEnabled == True Then
        $OfflineEnabled = False
        GUICtrlSetState($OfflinePath, $GUI_DISABLE)
        GUICtrlSetState($OfflineBrowse, $GUI_DISABLE)
    EndIf
Until 1 = 2

Func _CreateGUI()
    If @OSVersion == "WIN_XP" Then
        FileInstall("XPTOXP.jpg", @TempDir & "\XPTOXP.jpg", 1)
        FileInstall("UPGRADE.jpg", @TempDir & "\UPGRADE.jpg", 1)
        $ToXPGUI = GUICreate("USMT Front End - MaxImuM AdVaNtAgE SofTWarE © 2011", 480, 150, @DesktopWidth / 2 - 240, @DesktopHeight / 2 - 15)
        GUICtrlCreatePic(@TempDir & "\XPTOXP.jpg", 50, 20, 160, 120)
        GUICtrlSetState(-1, $GUI_DISABLE)
        GUICtrlCreatePic(@TempDir & "\UPGRADE.jpg", 270, 20, 160, 120)
        GUICtrlSetState(-1, $GUI_DISABLE)
        $XPToXPChoice = GUICtrlCreateButton("XP to XP", 75, 62, 110, 20)
        $XPToNewerChoice = GUICtrlCreateButton("XP to Vista/7", 295, 62, 110, 20)
        $Question = GUICtrlCreateButton("?", 460, 0, 20, 20)
        GUICtrlSetBkColor(-1, 0x00f700)
        GUISetBkColor(0xb2ccff, $ToXPGUI)
        GUISetState(@SW_SHOW, $ToXPGUI)
        Do
            $MSG = GUIGetMsg()
            If $MSG == $GUI_EVENT_CLOSE Then Exit
            If $MSG == $Question Then _Question()
            If $MSG == $XPToXPChoice Then
                $XPMode = True
                GUIDelete($ToXPGUI)
                ExitLoop
            EndIf
            If $MSG == $XPToNewerChoice Then
                GUIDelete($ToXPGUI)
                ExitLoop
            EndIf
        Until 1 = 2
    EndIf

    $CreateGU = GUICreate("USMT Front End - MaxImuM AdVaNtAgE SofTWarE © 2011", 480, 400, @DesktopWidth / 2 - 240, @DesktopHeight / 2 - 200)
    GUICtrlCreateLabel("Specify the location to save the backup", 10, 10, 460, 20)
    $Target = GUICtrlCreateInput("", 10, 25, 430, 20)
    $TargetBrowse = GUICtrlCreateButton("...", 450, 25, 20, 20)
    GUICtrlCreateLabel("Customer Last Name:", 10, 55, 120, 20)
    $CustName = GUICtrlCreateInput("", 10, 70, 120, 20)
    GUICtrlCreateLabel("Repair Number:", 150, 55, 85, 20)
    $RepairNumber = GUICtrlCreateInput("", 150, 70, 85, 20)
    GUICtrlCreateLabel("Tech's Initials:", 255, 55, 85, 20)
    $Tech = GUICtrlCreateInput("", 255, 70, 85, 20)
    $Overwrite = GUICtrlCreateCheckbox("Overwrite any existing data in the save location", 10, 110, 460, 20)
    $NoCompress = GUICtrlCreateCheckbox("Do not compress the data (Faster)", 10, 130, 460, 20)
    GUICtrlSetState(-1, $GUI_CHECKED)
    GUICtrlCreateLabel("Number of times to retry when an error occurs:", 10, 152, 220, 20)
    GUICtrlCreateLabel("(0-100, Default=3)", 270, 152, 100, 20)
    $TimesToRetry = GUICtrlCreateInput("3", 230, 150, 30, 20, $ES_CENTER)
    GUICtrlCreateLabel("Seconds to wait before retrying when an error occurs:", 10, 172, 255, 20)
    GUICtrlCreateLabel("(0-100, Default=1)", 305, 172, 100, 20)
    $SecondsToWait = GUICtrlCreateInput("1", 265, 170, 30, 20, $ES_CENTER)
    $Offline = GUICtrlCreateCheckbox("Specify a path for Offline recovery if not backing up this computer (NO XP TO XP!)", 10, 215, 460, 20)
    GUICtrlCreateLabel("IE: C;\Windows.old, E:\Windows etc", 26, 235, 460, 20)
    $OfflinePath = GUICtrlCreateInput("", 10, 255, 430, 20)
    $OfflineBrowse = GUICtrlCreateButton("...", 450, 255, 20, 20)
    GUICtrlSetState($OfflinePath, $GUI_DISABLE)
    GUICtrlSetState($OfflineBrowse, $GUI_DISABLE)
    $CreateGoButton = GUICtrlCreateButton("GO", 200, 320, 80, 40)
    GUICtrlSetFont($CreateGoButton, 12)
    GUICtrlCreateLabel("(You can not downgrade to Windows XP from a newer version of Windows or migrate" & @CR & "from a 64bit OS to a 32bit OS with this tool)", 10, 365, 470, 40, $SS_CENTER)
    $Question = GUICtrlCreateButton("?", 460, 0, 20, 20)
    GUICtrlSetBkColor(-1, 0x00f700)
    GUISetBkColor(0xb2ccff, $CreateGU)
    GUISetState(@SW_SHOW, $CreateGU)
EndFunc   ;==>_CreateGUI

Func _RestoreGUI()
    $RestoreGUI = GUICreate("USMT Front End - MaxImuM AdVaNtAgE SofTWarE © 2011", 480, 400, @DesktopWidth / 2 - 240, @DesktopHeight / 2 - 200)
    GUICtrlCreateLabel("Specify the location to restore the backup from", 10, 10, 460, 20)
    $Target = GUICtrlCreateInput("", 10, 25, 430, 20)
    $TargetBrowse = GUICtrlCreateButton("...", 450, 25, 20, 20)
    GUICtrlCreateLabel("Number of times to retry when an error occurs:", 10, 57, 220, 20)
    GUICtrlCreateLabel("(0-100, Default=3)", 270, 57, 100, 20)
    $TimesToRetry = GUICtrlCreateInput("3", 230, 55, 30, 20, $ES_CENTER)
    GUICtrlCreateLabel("Seconds to wait before retrying when an error occurs:", 10, 77, 255, 20)
    GUICtrlCreateLabel("(0-100, Default=1)", 305, 77, 100, 20)
    $SecondsToWait = GUICtrlCreateInput("1", 265, 75, 30, 20, $ES_CENTER)
    $RestoreGoButton = GUICtrlCreateButton("GO", 200, 320, 80, 40)
    GUICtrlSetFont($RestoreGoButton, 12)
    GUICtrlCreateLabel("(You can not downgrade to Windows XP from a newer version of Windows or migrate" & @CR & "from a 64bit OS to a 32bit OS with this tool)", 10, 365, 470, 40, $SS_CENTER)
    $Question = GUICtrlCreateButton("?", 460, 0, 20, 20)
    GUICtrlSetBkColor(-1, 0x00f700)
    GUISetBkColor(0xb2ccff, $RestoreGUI)
    GUISetState(@SW_SHOW, $RestoreGUI)
EndFunc   ;==>_RestoreGUI

Func _CreateExecute()
    $TargetPath = GUICtrlRead($Target)
    $CustomerArg = GUICtrlRead($CustName)
    $RepairArg = GUICtrlRead($RepairNumber)
    $TechArg = GUICtrlRead($Tech)
    If $TargetPath <> "" And $CustomerArg <> "" And $RepairArg <> "" And $TechArg <> "" Then
        If StringRight($TargetPath, 1) == "\" Then $TargetPath = StringTrimRight($TargetPath, 1)
        $TargetPath &= StringUpper("\" & $CustomerArg & "-" & $RepairArg & "-" & $TechArg & "-" & @MON & @MDAY & StringMid(@YEAR, 3, 2))
        $LogFile = $TargetPath & ".txt"
        $OverwriteArg = " "
        If GUICtrlRead($Overwrite) == 1 Then $OverwriteArg = " /o"
        $NoCompressArg = " "
        If GUICtrlRead($NoCompress) == 1 Then $NoCompressArg = " /nocompress "
        $TimesToRetryArg = 3
        If GUICtrlRead($TimesToRetry) <> "" Then $TimesToRetryArg = GUICtrlRead($TimesToRetry)
        $SecondsToWaitArg = 1
        If GUICtrlRead($SecondsToWait) <> "" Then $SecondsToWaitArg = GUICtrlRead($SecondsToWait)
        $OfflineArg = ""
        $OfflinePathArg = GUICtrlRead($OfflinePath)
        If GUICtrlRead($Offline) == 1 And $OfflinePathArg <> "" Then $OfflineArg = "/offlineWinDir:" & Chr(34) & $OfflinePathArg & Chr(34)
        GUICtrlDelete($CreateGoButton)

        If $XPMode == False Then
            _Extract($XPMode)
            ShellExecuteWait(@TempDir & "\USMT\scanstate.exe", Chr(34) & $TargetPath & Chr(34) & " /localonly /vsc /efs:decryptcopy" & $OverwriteArg & $NoCompressArg & $OfflineArg & " /r:" & $TimesToRetryArg & " /w:" & $SecondsToWaitArg & " /L:" & Chr(34) & $LogFile & Chr(34) & " /v:13 /c /all /i:" & @TempDir & "\USMT\MigApp.xml /i:" & @TempDir & "\USMT\MigDocs.xml /i:" & @TempDir & "\USMT\MigUser.xml", @TempDir)
        Else
            _Extract($XPMode)
            ShellExecuteWait(@TempDir & "\USMT\scanstate.exe", Chr(34) & $TargetPath & Chr(34) & " /targetxp /localonly /efs:decryptcopy" & $OverwriteArg & $NoCompressArg & " /r:" & $TimesToRetryArg & " /w:" & $SecondsToWaitArg & " /L:" & Chr(34) & $LogFile & Chr(34) & " /v:13 /c /all /i:" & @TempDir & "\USMT\MigApp.xml /i:" & @TempDir & "\USMT\MigSys.xml /i:" & @TempDir & "\USMT\MigUser.xml", @TempDir)
        EndIf

        Do
            Sleep(1000)
        Until Not ProcessExists("scanstate.exe")
        MsgBox(0, "Done", "Finished backing up.")
        Exit
    EndIf
EndFunc   ;==>_CreateExecute

Func _RestoreExecute()
    $TargetPath = GUICtrlRead($Target)
    If $TargetPath <> "" Then
        $TargetBreak = StringSplit($TargetPath, "\")
        $Last = $TargetBreak[0]
        $LogFile = "c:\" & $TargetBreak[$Last] & ".txt"
        $TimesToRetryArg = 3
        If GUICtrlRead($TimesToRetry) <> "" Then $TimesToRetryArg = GUICtrlRead($TimesToRetry)
        $SecondsToWaitArg = 1
        If GUICtrlRead($SecondsToWait) <> "" Then $SecondsToWaitArg = GUICtrlRead($SecondsToWait)
        $NoCompressArg = ""
        $FileCount = DirGetSize($TargetPath, 1)
        If $FileCount[1] > 1 Then $NoCompressArg = "/nocompress "
        GUICtrlDelete($RestoreGoButton)

        If @OSVersion == "WIN_XP" Then
            $XPMode = True
            _Extract($XPMode)
            ShellExecuteWait(@TempDir & "\USMT\loadstate.exe", Chr(34) & $TargetPath & Chr(34) & " /lac /lae " & $NoCompressArg & "/r:" & $TimesToRetryArg & " /w:" & $SecondsToWaitArg & " /L:" & Chr(34) & $LogFile & Chr(34) & " /v:13 /c /all /i:" & @TempDir & "\USMT\MigApp.xml /i:" & @TempDir & "\USMT\MigSys.xml /i:" & @TempDir & "\USMT\MigUser.xml", @TempDir)
        Else
            _Extract($XPMode)
            ShellExecuteWait(@TempDir & "\USMT\loadstate.exe", Chr(34) & $TargetPath & Chr(34) & " /lac /lae " & $NoCompressArg & "/r:" & $TimesToRetryArg & " /w:" & $SecondsToWaitArg & " /L:" & Chr(34) & $LogFile & Chr(34) & " /v:13 /c /all /i:" & @TempDir & "\USMT\MigApp.xml /i:" & @TempDir & "\USMT\MigDocs.xml /i:" & @TempDir & "\USMT\MigUser.xml", @TempDir)
        EndIf

        Do
            Sleep(1000)
        Until Not ProcessExists("loadstate.exe")
        MsgBox(0, "Done", "Finished restoring.")
        Exit
    EndIf
EndFunc   ;==>_RestoreExecute

Func _Extract($XPMode)
    FileInstall("7z.exe", @TempDir & "\7z.exe", 1)
    FileInstall("7z.dll", @TempDir & "\7z.dll", 1)
    DirRemove(@TempDir & "\USMT", 1)
    DirCreate(@TempDir & "\USMT")

    If $XPMode == True Then
        If @OSArch == "X86" Then
            FileInstall("USMT301x86.7z", @TempDir & "\USMT301x86.7z", 1)
            ShellExecuteWait(@TempDir & "\7z.exe", "e " & @TempDir & "\USMT301x86.7z", @TempDir & "\USMT")
        Else
            FileInstall("USMT301x64.7z", @TempDir & "\USMT301x64.7z", 1)
            ShellExecuteWait(@TempDir & "\7z.exe", "e " & @TempDir & "\USMT301x64.7z", @TempDir & "\USMT")
        EndIf
    Else
        If @OSArch == "X86" Then
            FileInstall("USMT401x86.7z", @TempDir & "\USMT401x86.7z", 1)
            ShellExecuteWait(@TempDir & "\7z.exe", "e " & @TempDir & "\USMT401x86.7z", @TempDir & "\USMT")
        Else
            FileInstall("USMT401x64.7z", @TempDir & "\USMT401x64.7z", 1)
            ShellExecuteWait(@TempDir & "\7z.exe", "e " & @TempDir & "\USMT401x64.7z", @TempDir & "\USMT")
        EndIf
    EndIf

    Sleep(500)
EndFunc   ;==>_Extract

Func _Question()
    $QuestionGUI = GUICreate("USMT Front End - MaxImuM AdVaNtAgE SofTWarE © 2011", 480, 400, @DesktopWidth / 2 - 240, @DesktopHeight / 2 - 200)
    GUICtrlCreateLabel("Build Date 01/26/2011", 355, 10, 460, 20)
    GUICtrlCreateLabel("This application is a front end for Microsoft's User State Migration Tool, and contains all USMT files. The User State Migration Tool is a Microsoft command line utility to copy user files and settings from one computer to another  USMT transfers user accounts, E-mai messages, settings, and contacts, photos, music, videos, Windows settings, program data files and settings, and Internet settings." & @CR & @CR & "This tool is designed to work with USMT 3.01 and USMT 4.01, the key difference between the versions being which versions of Windows they restore to.  USMT 3.01 is able to migrate Windows 2000 - Vista to Windows XP and Windows Vista.  USMT 4.01 is able to migrate Windows XP - 7 to Vista and 7.  USMT 4.01 is also able to migrate an " & Chr(34) & "offline" & Chr(34) & " drive, meaning a drive that is not the one being booted from." & @CR & @CR & "The options used in this front end have been customized for backing up only local user account data, so do not use this tool as-is in a network environment where capturing domain user data is important.  The XML files have also not been modified except to not migrate Start Menu files, so this tool may not be suitable if you need to include additional application settings or data than the default items for the respective versions of USMT.  Please refer to the various Microsoft Technet articles concerning USMT for details." & @CR & @CR & "The specific command lines used with all front end options set as default are as follows:" & @CR & @CR & "scanstate.exe $TargetPath /localonly /vsc /efs:decryptcopy /o /nocompress /r:3 /w:1 /L:$LogFile /v:13 /c /all /i:MigApp.xml /i:MigUser.xml /i:MigDocs.xml (or /i:MigSys.xml)" & @CR & @CR & "loadstate.exe $TargetPath /lac /lae /r:3 /w:1 /L:$LogFile /v:13 /c /all /i:MigApp.xml /i:MigUser.xml /i:MigDocs.xml (or /i:MigSys.xml)", 10, 40, 460, 360)
    GUISetBkColor(0xb2ccff, $QuestionGUI)
    GUISetState(@SW_SHOW, $QuestionGUI)
    Do
        $MSG = GUIGetMsg()
        If $MSG == $GUI_EVENT_CLOSE Then
            GUIDelete($QuestionGUI)
            ExitLoop
        EndIf
    Until 1 = 2
EndFunc   ;==>_Question

Enjoy!
Ian

Edited by llewxam, 31 January 2011 - 07:49 PM.

[storme]

G'day Ian

Looks good, I like the interface very minimalist.

Just curious what happens if you try to migrate an XP user to Windows 7 that uses Outlook Express?
I.E what happens to the Emails?

Does it work from "safe mode"....

Am I right in guessing that this can't be used to a dead system as it has to be run from inside the work OLD system?
If so I can still see a use for your old backup program.
Are you still developing it? If so IM me as I've got a few ideas I'd like to run past you.

Yeah I know I can answer all these by RTFM but you already have.

It's a shame you didn't have this out a few days ago. I coudl have given it a full work out for you.
Ahh well there will be another computer coming along soom I'm sure that I can try this on.

Keep up the great work!
John Morrison
aka
Storm-E

[llewxam]

Just curious what happens if you try to migrate an XP user to Windows 7 that uses Outlook Express?
I.E what happens to the Emails?

I'd be lying if I said I knew exactly, don't think I've looked for that scenario, but instict tells me they would import to Windows Mail since I know you can do that.

Does it work from "safe mode"....

Haven't tried that either, but a forum post via Google indicated that it should work.

Am I right in guessing that this can't be used to a dead system as it has to be run from inside the work OLD system?

Wellllll....... USMT 3.01 must be run from the computer you intend to back up from. USMT 4.01 allows the offline mode which can work on a non-booting drive. The annoying thing is that 4.01 will not work on XP, and I still have a lot of machines coming in for repair that have XP, so I find that pretty frustrating. In those cases, the old db5 backup app will get some use.

If so I can still see a use for your old backup program. Are you still developing it? If so IM me as I've got a few ideas I'd like to run past you.

I am not actively working on it, actually haven't touched it since posting it here in November, but if you have suggestions I'm all ears!

Thanks!
Ian

[storme]

I'd be lying if I said I knew exactly, don't think I've looked for that scenario, but instict tells me they would import to Windows Mail since I know you can do that.

Nope No "Windows Mail" on windows 7... You have to install "Windows Live Mail" so if you do get a chance to do an xp to windows 7 let me know what happens to the emails...

Wellllll....... USMT 3.01 must be run from the computer you intend to back up from. USMT 4.01 allows the offline mode which can work on a non-booting drive. The annoying thing is that 4.01 will not work on XP, and I still have a lot of machines coming in for repair that have XP, so I find that pretty frustrating. In those cases, the old db5 backup app will get some use.

DAM..... the most likely sinario is that a customer wants to move from an old dead XP computer to a new Windows 7 computer... sigh...

[llewxam]

DAM..... the most likely sinario is that a customer wants to move from an old dead XP computer to a new Windows 7 computer... sigh...

No, that will work fine! Again the issue is this - to migrate BACK TO Windows XP you must capture the source using USMT 3.01, since that is the only version able RESTORE to XP, and 3.01 does not support offline use. But, with your scenario, you would be able to use this tool since you are RESTORING to 7!

To summarize, both versions can CAPTURE XP, but only 3.01 will RESTORE to XP. Since you would be migrating to 7, life is good.

Ian

(Oh, and you can not use USMT 3.01 to restore a migration created with USMT 4.01, just to be clear. Using 4.01's offline feature and restoring with 3.01 on XP isn't gonna work!)

[llewxam]

First post updated with a bugfix in handling offline drives, I just got a chance to use it in real life for the first time and.....well, yeah, it works better now

Ian

[storme]

No, that will work fine! Again the issue is this - to migrate BACK TO Windows XP you must capture the source using USMT 3.01, since that is the only version able RESTORE to XP, and 3.01 does not support offline use. But, with your scenario, you would be able to use this tool since you are RESTORING to 7!

To summarize, both versions can CAPTURE XP, but only 3.01 will RESTORE to XP. Since you would be migrating to 7, life is good.

Ian

(Oh, and you can not use USMT 3.01 to restore a migration created with USMT 4.01, just to be clear. Using 4.01's offline feature and restoring with 3.01 on XP isn't gonna work!)

OK that makes sense now. 4 can make backups of everything but can only restore to the new systems. Gotcha!
M$ would do that as they want everyone to move up and not stay with the "old" stuff.
I'm even contemplating moving to Windows 7 now..... but I do love my old XP...

Edited by storme, 25 January 2011 - 03:48 AM.

[llewxam]

Does it work from "safe mode"....

We just had a chance to test this in the real world for the first time, Safe Mode on XP worked like a champ.

Ian

[llewxam]

First post updated with new code. Among the simple changes are some variable and function names are different, also changed the wording in the Question routine.

A bigger change, and something that may serve as a handy "cheat" for offline XP usage, is I now have the /nocompress option set as default. I initially did that just for speed, but today during some testing I realized that you can just browse the data being saved with the /nocompress option being used, it isn't packaged in any way. Well, that makes me think that you could offline a non-booting XP hard drive with this tool using the /nocompress option, wipe/reload, then just manually recreate the user accounts and copy the data over! I will hopefully get a chance to try it soon, as this is a fairly common situation.

Another bugfix was in the restoration of /nocompress backups, previously I forgot to look for that when restoring so it is now addressed.

Enjoy
Ian

[storme]

I used an old verison of the front end and it backed up ok but wouldn't restore.
Well not quite true.
I was going from XP to Win7 and the dront end looked like it may have hit an error but it was too quick.
When I simply clicked the backup file win7 installed the files for me.

So looks like there may be some syntax problem with teh frontend program.

Source : XP (backup done from here)
Destination : Win7
Compression : ON

But looks great!

THANKS
John Morrison

[llewxam]

I used an old verison of the front end and it backed up ok but wouldn't restore.
Well not quite true.
I was going from XP to Win7 and the dront end looked like it may have hit an error but it was too quick.
When I simply clicked the backup file win7 installed the files for me.

So looks like there may be some syntax problem with teh frontend program.

Source : XP (backup done from here)
Destination : Win7
Compression : ON

But looks great!

THANKS
John Morrison

FYI, when (hopefully never ) there is an error, see the log file that is created in the location where the save is going to ($TargetPath). That will reveal any syntax errors. I have found several since posting the first version, which is why I keep updating it. This is one of those tools where I couldn't test everything prior to posting but am diligent in fixing issues as they happen.

Ian

[llewxam]

gggrrrrr, another very minor tweak had to be made for the /offlinewindor flag, but it is working and that is what matters
Any users, please update!

Thanks
Ian

[NDog]

Tried using your tool to migrate from xp box to windows 7 laptop today

1) plug in external USB 500GB hard disk with existing 400GB of data into Windows XP box, logged onto the user profile I wanted to backup
2) run the backup xp->7 option
3) Backup backed up c$ and user related files, however it started backing up the d$ (external usb drive), which has no information related to the profile, so I closed the usmt front end + the DOS window

4) plug in external USB drive to Windows 7 and start restore. Popped up for about 40 seconds then disappeared saying process completed.

This didn't work for me so I think you need to consider the syntax regarding external USB drives perhaps?

Another question

Could I use a USB drive caddy to plug an existing windows xp drive and do a straight restore to an existing windows 7 platform and SELECT the user profile I wanted to restore (to the current Windows 7 profile).. very nice

Thanks for your hard works

[llewxam]

Tried using your tool to migrate from xp box to windows 7 laptop today

1) plug in external USB 500GB hard disk with existing 400GB of data into Windows XP box, logged onto the user profile I wanted to backup
2) run the backup xp->7 option
3) Backup backed up c$ and user related files, however it started backing up the d$ (external usb drive), which has no information related to the profile, so I closed the usmt front end + the DOS window

4) plug in external USB drive to Windows 7 and start restore. Popped up for about 40 seconds then disappeared saying process completed.

This didn't work for me so I think you need to consider the syntax regarding external USB drives perhaps?

Another question

Could I use a USB drive caddy to plug an existing windows xp drive and do a straight restore to an existing windows 7 platform and SELECT the user profile I wanted to restore (to the current Windows 7 profile).. very nice

Thanks for your hard works

Kinda, but not quite, good news for you.....

First, unfortunately USMT does not allow being as specific as telling it to only back up certain profiles, so I saw where you were going once you said "logged onto the user profile I wanted to backup". USMT is all-or-nothing. I think the reason it failed to restore is that once you cancelled the backup process, the catalog file would have been damaged and the restoration would have failed.

What you COULD do in the situation where you want to only RESTORE certain profiles is use the USMT Front End to create the backup, being sure to ENABLE the compression option and choosing the XP-Vista/7 option, then allow the backup to finish. Then on the 7 machine, just double-click the .MIG file and the "Windows Easy Transfer" tool will open. By default USMT (and therefore this tool) will automatically create and import any user accounts that do not yet exist, but with Windows Easy Transfer you can choose which to import.

The above steps may have been more work than necessary if all you cared about was your data, as USMT is also designed to handle things such as emails, contacts, and system settings. If all you needed to do was copy some user data from an old profile to a new one, allow a shameless plug and try my Sync Tool, which I have just posted a minor update to...

Thanks!
Ian

Edited by llewxam, 08 March 2011 - 01:18 PM.

[storme]

G'day Ian
I've been using this a bit lately and I love it! Much better than old systems.
I have had a few problems (listed below) but I've taken the precaution of using your backup program to give me another source just in case everything goes bad.

Areas that I had problems. (Isn't there always )

• Sometimes 1/2 creates new users
• Sometimes doesn't copy Email into the right place/program
• Needs some Error checking on the output of the program (maybe just a text window)

Sorry I don't have details on all this it's been a bit hectic and I was rushing through. Here is what I remember.

1. Sometimes the restore process only 1/2 creates users being restored from the backup.
All the files are under the user name, The name isn't on the logon screen and the user name can't be used to create another user.
Have you seen this?

2. EMail not copied over corrently. If the original system is XP and the new is Win7 the system doesn't import the mail to Windows live mail. BUT it does put it where Outlook Express "could" find it IF OE could be installed on Win7.
Maybe this needs some post restore script to fix it.

3. When selecting the restore directory I didn't understand what directory I was to select (I know now). However, the program took the selection tried to run it and came up "finished" and exited. Leaving me me with no explaination of why it didn't do anything.

Same thing with the offline backup. I kept selecting C: not C:\Windows and wonding why it didn't work (YES I did read the info on the screen...AFTER )


Anyway thought you should know about them. Keep up the great work!
John Morrison

P.S
What's happening with inf program? or/and the updater?
One (XP/7) of the restores doesn't work because there is a XML file missing from the USMT directory. I think it was a ?DOC? XML file.
I eventually grabbed the command line from the program (After thinking I had messed up somehow)) and from that worked out what XML was missing.

[llewxam]

Thanks as always for the feedback! I started putting together a different Front End, which would have a Simple interface (basically the one used now) and an Advanced interface where ALL options could be adjusted. Unfortunately that all required a bit more restructuring than I wanted, so I haven't touched it in a few weeks....

The problems you mentioned have only come up once or twice for me, and I think those were both on occasions where I used the Offline mode in order to pull data from a machine that could not boot. The annoying thing about when problems arise is I really can't do anything about it, as this is just a GUI for an MS tool, and all of the actual work is done on their end. When it works great it is awesome, when it doesn't....we have to go back to older ways.

One thing I am doing now (and have set as default on my test build versions) is I ALWAYS run the backup now Uncompressed - this is quite a bit quicker to do the backup, and the files can be browsed through easily even from an XP machine in the event that an automatic Restore doesn't go so well. On XP, I usually end up manually creating the user accounts, logging in to make Windows create a folder structure, and moving the backups myself. For Vista/7, I have no problems (mentally, that is) with using LoadState (auto Restore).


As for the driver tool, I have your code for the updater ready to go, and am just waiting on KickArse to contribute some parsing code so the scan results are more accurate. Sorry, hopefully that will happen soon.

Thanks!
Ian

[storme]

Thanks as always for the feedback! I started putting together a different Front End, which would have a Simple interface (basically the one used now) and an Advanced interface where ALL options could be adjusted. Unfortunately that all required a bit more restructuring than I wanted, so I haven't touched it in a few weeks....

No Problem. I understand perfectly.

The problems you mentioned have only come up once or twice for me, and I think those were both on occasions where I used the Offline mode in order to pull data from a machine that could not boot. The annoying thing about when problems arise is I really can't do anything about it, as this is just a GUI for an MS tool, and all of the actual work is done on their end. When it works great it is awesome, when it doesn't....we have to go back to older ways.

yeah I think it was off-line that caused the problem here too.
That is why I suggested you capture the output from USMT and display that for the user OR better parse it to see if there is a fault.

One thing I am doing now (and have set as default on my test build versions) is I ALWAYS run the backup now Uncompressed - this is quite a bit quicker to do the backup, and the files can be browsed through easily even from an XP machine in the event that an automatic Restore doesn't go so well. On XP, I usually end up manually creating the user accounts, logging in to make Windows create a folder structure, and moving the backups myself. For Vista/7, I have no problems (mentally, that is) with using LoadState (auto Restore).

I think uncommpressed is a great idea and would help with the "email problem" I outlined in the last email as it's accessable to import.
The User Creation problem I've run into a few times now. The biggest problem is you can't create the user that was only 1/2 created.
HMM wouldn't be hard to write a user creator prepressor.........OOPS I siad that last time.
Maybe I'll dig arround and find the code I made up last time to create users. If you're interested.

As for the driver tool, I have your code for the updater ready to go, and am just waiting on KickArse to contribute some parsing code so the scan results are more accurate. Sorry, hopefully that will happen soon.

No problem as long as it's moving forward.
I'm using it more and more and it's annoying to have no feedback with the updates. But I didn't want to add it if you were doign something.


Thanks for the reply
John Morrison

[hnyr]

helloo sir

i installed autoit v3 and trying to make this script working but it is not working and even does not start

how to make it works (opened the file and compile it but still not even starts) is there a settings need to manitain to make it starts????

thank u

[llewxam]

helloo sir

i installed autoit v3 and trying to make this script working but it is not working and even does not start

how to make it works (opened the file and compile it but still not even starts) is there a settings need to manitain to make it starts????

thank u

Did you download the extras archive linked in the first post? That must be downloaded and extracted to the script folder in order for it to work properly.

Ian

[ericjensen]

Getting 404 when trying to download the extras