Sign in to follow this  
Followers 0
nitekram

combo populating an input box

8 posts in this topic

Is there a way to do this? I want to be able to populate the input box if the combo exists - if it does not exist then create a new combo and let the user fill out the input box.

Here is what I have so far: thanks for your help

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>




$teamcombo = 'zero|one|two|three|four'
;$teamlocation = '

Dim $aTempTeams[5][2]

$aTempTeams[0][0] = 'zero'
$aTempTeams[0][1] = 'Location test zero'
$aTempTeams[1][0] = 'one'
$aTempTeams[1][1] = 'Location test one'
$aTempTeams[2][0] = 'two'
$aTempTeams[2][1] = 'Location test two'
$aTempTeams[3][0] = 'three'
$aTempTeams[3][1] = 'Location test three'
$aTempTeams[4][0] = 'four'
$aTempTeams[4][1] = 'Location test four'




GUICreate('Test')
$LableTeamCombo = GUICtrlCreateCombo('Pick one', 0, 0)
;GUICtrlSetData(-1, "item2|item3", "item3")
GUICtrlSetData( -1, $teamcombo, 'TESTING')
$LableLocationInput = GUICtrlCreateInput('', 0, 50)

GUISetState(@SW_SHOW)


While 1
Sleep(20)
    $msg = GUIGetMsg()

    If $msg = $GUI_EVENT_CLOSE Then ExitLoop


    If GUICtrlRead($LableTeamCombo) <> '' Then


        GUICtrlSetData($LableLocationInput, '')
        GUICtrlSetState($LableLocationInput, $GUI_DISABLE)
        For $i = 0 To UBound($aTempTeams) - 1
            ;Sleep(1000)
            If $aTempTeams[$i][0] = GUICtrlRead($LableTeamCombo) Then
                GUICtrlSetData($LableLocationInput, '')
                $aTempLocation = StringSplit($aTempTeams[$i][1], ',')
                ;_ArrayDisplay($aTempLocation, 'showing location info')
                ;GUICtrlSetData($LableLocation, '')
                GUICtrlSetData($LableLocationInput, $aTempLocation[1], $aTempLocation[1])
                ;GUICtrlSetState($LableID, $GUI_FOCUS)
                ;$stop = 1
                
            EndIf
            
        Next
        GUICtrlSetState($LableLocationInput, $GUI_ENABLE)
        ;GUICtrlSetData($LableTeam,GetTeamList())
    EndIf
    
    
WEnd

GUIDelete()

All by me:

"Sometimes you have to go back to where you started, to get to where you want to go." 

"Everybody catches up with everyone, eventually" 

"As you teach others, you are really teaching yourself."

From my dad

"Do not worry about yesterday, as the only thing that you can control is tomorrow."

 

WindowsError.gif

WIKI | Tabs; | Arrays; | Strings | Wiki Arrays | How to ask a Question | Forum Search | FAQ | Tutorials | Original FAQ | ONLINE HELP | UDF's Wiki | AutoIt PDF

AutoIt Snippets | Multple Guis | Interrupting a running function | Another Send

StringRegExp | StringRegExp Help | RegEXTester | REG TUTOR | Reg TUTOT 2

AutoItSetOption | Macros | AutoIt Snippets | Wrapper | Autoit  Docs

SCITE | SciteJump | BB | MyTopics | Programming | UDFs | AutoIt 123 | UDFs Form | UDF

Learning to script | Tutorials | Documentation | IE.AU3 | Games? | FreeSoftware | Path_Online | Core Language

Programming Tips

Excel Changes

ControlHover.UDF

GDI_Plus

Draw_On_Screen

GDI Basics

GDI_More_Basics

GDI Rotate

GDI Graph

GDI  CheckExistingItems

GDI Trajectory

Replace $ghGDIPDll with $__g_hGDIPDll

DLL 101?

Array via Object

GDI Swimlane

GDI Plus French 101 Site

GDI Examples UEZ

GDI Basic Clock

GDI Detection

Ternary operator

Share this post


Link to post
Share on other sites



nitekram,

A nice puzzle for a snowy afternoon: :D

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiComboBox.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>

Global $aTempTeams[1][2]
Global $teamcombo = ""

#cs
; For testing
ReDim $aTempTeams[5][2]
$aTempTeams[0][0] = 'zero'
$aTempTeams[0][1] = 'Location test zero'
$aTempTeams[1][0] = 'one'
$aTempTeams[1][1] = 'Location test one'
$aTempTeams[2][0] = 'two'
$aTempTeams[2][1] = 'Location test two'
$aTempTeams[3][0] = 'three'
$aTempTeams[3][1] = 'Location test three'
$aTempTeams[4][0] = 'four'
$aTempTeams[4][1] = 'Location test four'
; For testing
#ce

If $aTempTeams[0][0] <> "" Then
    For $i = 0 To UBound($aTempTeams) - 1
        $teamcombo &= $aTempTeams[$i][0] & "|"
    Next
EndIf

GUICreate('Test')

$LabelTeamCombo = GUICtrlCreateCombo('', 10, 10, 200, 20, $CBS_DROPDOWNLIST)
GUICtrlSetData(-1, $teamcombo)

$LabelLocationInput = GUICtrlCreateInput('', 10, 50, 200, 20, $ES_READONLY)

$hButton_Input = GUICtrlCreateButton("Add", 10, 100, 80, 30)

GUISetState(@SW_SHOW)

; Go stright ti input if no array exists
If $aTempTeams[0][0] = "" Then _Input()

$CurrentCombo = ""

While 1

    ;Sleep(20) ; Not needed if you use GUIGetMsg - that adds its own Sleep!!!!
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton_Input
            _Input()
    EndSwitch

    ; Check if combo has changed AND is shut
    If GUICtrlRead($LabelTeamCombo) <> "" And _GUICtrlComboBox_GetDroppedState($LabelTeamCombo) = False Then

        ; Reset current combo selection
        $CurrentCombo = GUICtrlRead($LabelTeamCombo)
        ; Search for location data
        For $i = 0 To UBound($aTempTeams) - 1
            If $aTempTeams[$i][0] = GUICtrlRead($LabelTeamCombo) Then
                $aTempLocation = StringSplit($aTempTeams[$i][1], ',')
                GUICtrlSetData($LabelLocationInput, $aTempLocation[1])
                ; Stop looking
                ExitLoop
            EndIf
        Next
    EndIf

WEnd

Func _Input()

    ; Change button text
    GUICtrlSetData($hButton_Input, "Save")
    ; Create inputs
    GUICtrlSetState($LabelTeamCombo, $GUI_HIDE)
    GUICtrlSetState($LabelLocationInput, $GUI_HIDE)
    $hInput_Team = GUICtrlCreateInput('', 10, 10, 200, 20)
    $hInput_Location = GUICtrlCreateInput('', 10, 50, 200, 20)

    While 1

        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
            Case $hButton_Input

                ; Add button pressed so check we have 2 inputs
                If GUICtrlRead($hInput_Team) <> "" And GUICtrlRead($hInput_Location) <> "" Then
                    ; Resize the array
                    Local $iNewSize = UBound($aTempTeams) + 1
                    ReDim $aTempTeams[$iNewSize][2]
                    ; Add new data
                    $aTempTeams[$iNewSize - 1][0] = GUICtrlRead($hInput_Team)
                    $aTempTeams[$iNewSize - 1][1] = GUICtrlRead($hInput_Location)
                    ; Add team to combo
                    $teamcombo &= GUICtrlRead($hInput_Team) & "|"
                    GUICtrlSetData($LabelTeamCombo, "|" & $teamcombo)
                    ; Clear up
                    GUICtrlSetData($hButton_Input, "Add")
                    GUICtrlDelete($hInput_Team)
                    GUICtrlDelete($hInput_Location)
                    GUICtrlSetState($LabelTeamCombo, $GUI_SHOW)
                    GUICtrlSetState($LabelLocationInput, $GUI_SHOW)
                    _GUICtrlComboBox_SetEditText($LabelTeamCombo, 'Choose a team')
                    GUICtrlSetData($LabelLocationInput, "")
                    ; Return from function
                    Return
                EndIf
        EndSwitch
    WEnd

EndFunc

Ask if anything is unclear.

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Thanks for your help @Melba23 - is there anyway to do this without having to press the add button? I was hoping that the end user would not have to press a button, but just start typing, and if it was not a match then have the input box not look for a match and allow the end user to fill in whatever they wanted.

Thanks again...


All by me:

"Sometimes you have to go back to where you started, to get to where you want to go." 

"Everybody catches up with everyone, eventually" 

"As you teach others, you are really teaching yourself."

From my dad

"Do not worry about yesterday, as the only thing that you can control is tomorrow."

 

WindowsError.gif

WIKI | Tabs; | Arrays; | Strings | Wiki Arrays | How to ask a Question | Forum Search | FAQ | Tutorials | Original FAQ | ONLINE HELP | UDF's Wiki | AutoIt PDF

AutoIt Snippets | Multple Guis | Interrupting a running function | Another Send

StringRegExp | StringRegExp Help | RegEXTester | REG TUTOR | Reg TUTOT 2

AutoItSetOption | Macros | AutoIt Snippets | Wrapper | Autoit  Docs

SCITE | SciteJump | BB | MyTopics | Programming | UDFs | AutoIt 123 | UDFs Form | UDF

Learning to script | Tutorials | Documentation | IE.AU3 | Games? | FreeSoftware | Path_Online | Core Language

Programming Tips

Excel Changes

ControlHover.UDF

GDI_Plus

Draw_On_Screen

GDI Basics

GDI_More_Basics

GDI Rotate

GDI Graph

GDI  CheckExistingItems

GDI Trajectory

Replace $ghGDIPDll with $__g_hGDIPDll

DLL 101?

Array via Object

GDI Swimlane

GDI Plus French 101 Site

GDI Examples UEZ

GDI Basic Clock

GDI Detection

Ternary operator

Share this post


Link to post
Share on other sites

nitekram,

You want fries with that? :huggles:

You will have to wait until tomorrow at least.......some people are never satisfied. :D

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

I really thank you for your time...I will wait until you have time - no rush, just need it today :D


All by me:

"Sometimes you have to go back to where you started, to get to where you want to go." 

"Everybody catches up with everyone, eventually" 

"As you teach others, you are really teaching yourself."

From my dad

"Do not worry about yesterday, as the only thing that you can control is tomorrow."

 

WindowsError.gif

WIKI | Tabs; | Arrays; | Strings | Wiki Arrays | How to ask a Question | Forum Search | FAQ | Tutorials | Original FAQ | ONLINE HELP | UDF's Wiki | AutoIt PDF

AutoIt Snippets | Multple Guis | Interrupting a running function | Another Send

StringRegExp | StringRegExp Help | RegEXTester | REG TUTOR | Reg TUTOT 2

AutoItSetOption | Macros | AutoIt Snippets | Wrapper | Autoit  Docs

SCITE | SciteJump | BB | MyTopics | Programming | UDFs | AutoIt 123 | UDFs Form | UDF

Learning to script | Tutorials | Documentation | IE.AU3 | Games? | FreeSoftware | Path_Online | Core Language

Programming Tips

Excel Changes

ControlHover.UDF

GDI_Plus

Draw_On_Screen

GDI Basics

GDI_More_Basics

GDI Rotate

GDI Graph

GDI  CheckExistingItems

GDI Trajectory

Replace $ghGDIPDll with $__g_hGDIPDll

DLL 101?

Array via Object

GDI Swimlane

GDI Plus French 101 Site

GDI Examples UEZ

GDI Basic Clock

GDI Detection

Ternary operator

Share this post


Link to post
Share on other sites

nitekram,

Cannot stand "SlumDog Millionaire" so you are in luck! :D

This is as good as I think I can get. You must have a button at some point to indicate that you have finished entering the data - unless we enter the area of mind control I cannot think of another way to do that! :

If you enter some text which is not even a possible entry in the combo, the input opens for user input and the "Add" button appears. When you have entered the new location, pres the button and the new entry is in the array.

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiComboBox.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <Array.au3>

Global $aTeamInfo[1][2]
Global $sComboList = ""

;#cs
; For testing
ReDim $aTeamInfo[5][2]
$aTeamInfo[0][0] = 'zero'
$aTeamInfo[0][1] = 'Location test zero'
$aTeamInfo[1][0] = 'one'
$aTeamInfo[1][1] = 'Location test one'
$aTeamInfo[2][0] = 'two'
$aTeamInfo[2][1] = 'Location test two'
$aTeamInfo[3][0] = 'three'
$aTeamInfo[3][1] = 'Location test three'
$aTeamInfo[4][0] = 'four'
$aTeamInfo[4][1] = 'Location test four'
; For testing
;#ce

If $aTeamInfo[0][0] <> "" Then
    For $i = 0 To UBound($aTeamInfo) - 1
        $sComboList &= $aTeamInfo[$i][0] & "|"
    Next
EndIf

$hGUI = GUICreate('Test')

$hCombo_Team = GUICtrlCreateCombo('', 10, 10, 200, 20)
GUICtrlSetData(-1, $sComboList)

$hInput_Location = GUICtrlCreateInput('', 10, 50, 200, 20, $ES_READONLY)

GUISetState(@SW_SHOW)

$sCurrCombo = ""

; Go stright t0 input if no array exists
If $aTeamInfo[0][0] = "" Then _Input()

While 1

    ;Sleep(20) ; Not needed if you use GUIGetMsg - that adds its own Sleep!!!!
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    ; Check if combo has changed AND is shut
    If GUICtrlRead($hCombo_Team) <> $sCurrCombo And _GUICtrlComboBox_GetDroppedState($hCombo_Team) = False Then

        ; Reset current combo selection
        $sCurrCombo = GUICtrlRead($hCombo_Team)
        ; Check if valid entry in array
        $fFound = False
        For $i = 0 To UBound($aTeamInfo) - 1
            If $aTeamInfo[$i][0] = GUICtrlRead($hCombo_Team) Then
                ; get location info
                $aTempLocation = StringSplit($aTeamInfo[$i][1], ',')
                GUICtrlSetData($hInput_Location, $aTempLocation[1])
                ; Stop looking
                $fFound = True
                ExitLoop
            EndIf
        Next

        ; If not found - check if partial entry
        If $fFound = False And $sCurrCombo <> "" Then
            $iIndex = _ArraySearch($aTeamInfo, $sCurrCombo, 0, 0, 0, 1)
            If $iIndex = -1 Then
                ; Not even partial entry so must be new entry
                _Input()
            EndIf
        EndIf
    EndIf

WEnd

Func _Input()

    GUICtrlSetState($hInput_Location, $GUI_HIDE)
    Local $hInput_New_Location = GUICtrlCreateInput('', 10, 50, 200, 20)
    Local $hButton_Add = GUICtrlCreateButton("Add", 10, 80, 80, 30)

    While 1

        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
            Case $hButton_Add
                ; Add button pressed so check we have 2 inputs
                If GUICtrlRead($hCombo_Team) <> "" And GUICtrlRead($hInput_New_Location) <> "" Then
                    ; Resize the array
                    Local $iNewSize = UBound($aTeamInfo) + 1
                    ReDim $aTeamInfo[$iNewSize][2]
                    ; Add new data
                    $aTeamInfo[$iNewSize - 1][0] = GUICtrlRead($hCombo_Team)
                    $aTeamInfo[$iNewSize - 1][1] = GUICtrlRead($hInput_New_Location)
                    ; Add team to combo
                    $sComboList &= GUICtrlRead($hCombo_Team) & "|"
                    GUICtrlSetData($hCombo_Team, "|" & $sComboList)
                    ; Clear up
                    GUICtrlDelete($hButton_Add)
                    GUICtrlDelete($hInput_New_Location)
                    _GUICtrlComboBox_SetEditText($hCombo_Team, 'Choose a team')
                    $sCurrCombo = 'Choose a team'
                    GUICtrlSetState($hInput_Location, $GUI_SHOW)
                    GUICtrlSetData($hInput_Location, "")
                    ; Return from function
                    Return
                EndIf
        EndSwitch
    WEnd

EndFunc   ;==>_Input

Anything else? :huggles:

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

#7 ·  Posted (edited)

nitekram,

Had a brainwave! :D

Press "Enter" when data input is finished - no buttons! :huggles:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiComboBox.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <Array.au3>

Global $aTeamInfo[1][2]
Global $sComboList = ""

;#cs
; For testing
ReDim $aTeamInfo[5][2]
$aTeamInfo[0][0] = 'zero'
$aTeamInfo[0][1] = 'Location test zero'
$aTeamInfo[1][0] = 'one'
$aTeamInfo[1][1] = 'Location test one'
$aTeamInfo[2][0] = 'two'
$aTeamInfo[2][1] = 'Location test two'
$aTeamInfo[3][0] = 'three'
$aTeamInfo[3][1] = 'Location test three'
$aTeamInfo[4][0] = 'four'
$aTeamInfo[4][1] = 'Location test four'
; For testing
;#ce

If $aTeamInfo[0][0] <> "" Then
    For $i = 0 To UBound($aTeamInfo) - 1
        $sComboList &= $aTeamInfo[$i][0] & "|"
    Next
EndIf

$hGUI = GUICreate('Test')

$hCombo_Team = GUICtrlCreateCombo('', 10, 10, 200, 20)
GUICtrlSetData(-1, $sComboList)

$hInput_Location = GUICtrlCreateInput('', 10, 50, 200, 20, $ES_READONLY)

GUISetState(@SW_SHOW)

$sCurrCombo = ""

; Go stright t0 input if no array exists
If $aTeamInfo[0][0] = "" Then _Input()

While 1

    ;Sleep(20) ; Not needed if you use GUIGetMsg - that adds its own Sleep!!!!
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    ; Check if combo has changed AND is shut
    If GUICtrlRead($hCombo_Team) <> $sCurrCombo And _GUICtrlComboBox_GetDroppedState($hCombo_Team) = False Then

        ; Reset current combo selection
        $sCurrCombo = GUICtrlRead($hCombo_Team)
        ; Check if valid entry in array
        $fFound = False
        For $i = 0 To UBound($aTeamInfo) - 1
            If $aTeamInfo[$i][0] = GUICtrlRead($hCombo_Team) Then
                ; get location info
                $aTempLocation = StringSplit($aTeamInfo[$i][1], ',')
                GUICtrlSetData($hInput_Location, $aTempLocation[1])
                ; Stop looking
                $fFound = True
                ExitLoop
            EndIf
        Next

        ; If not found - check if partial entry
        If $fFound = False And $sCurrCombo <> "" Then
            $iIndex = _ArraySearch($aTeamInfo, $sCurrCombo, 0, 0, 0, 1)
            If $iIndex = -1 Then
                ; Not even partial entry so must be new entry
                _Input()
            EndIf
        EndIf
    EndIf

WEnd

Func _Input()

    GUICtrlSetState($hInput_Location, $GUI_HIDE)
    Local $hInput_New_Location = GUICtrlCreateInput('', 10, 50, 200, 20)

    ; Set an accelerator key to mark the end of the data input
    Local $hDum = GUICtrlCreateDummy()
    Local $accels[1][2] = [["{ENTER}", $hDum]]
    GUISetAccelerators($accels)

    While 1

        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
            Case $hDum
                ; Add button pressed so check we have 2 inputs
                If GUICtrlRead($hCombo_Team) <> "" And GUICtrlRead($hInput_New_Location) <> "" Then
                    ; Resize the array
                    Local $iNewSize = UBound($aTeamInfo) + 1
                    ReDim $aTeamInfo[$iNewSize][2]
                    ; Add new data
                    $aTeamInfo[$iNewSize - 1][0] = GUICtrlRead($hCombo_Team)
                    $aTeamInfo[$iNewSize - 1][1] = GUICtrlRead($hInput_New_Location)
                    ; Add team to combo
                    $sComboList &= GUICtrlRead($hCombo_Team) & "|"
                    GUICtrlSetData($hCombo_Team, "|" & $sComboList)
                    ; Clear up
                    GUICtrlDelete($hInput_New_Location)
                    _GUICtrlComboBox_SetEditText($hCombo_Team, 'Choose a team')
                    $sCurrCombo = 'Choose a team'
                    GUICtrlSetState($hInput_Location, $GUI_SHOW)
                    GUICtrlSetData($hInput_Location, "")
                    ; Unset accelerators
                    GUISetAccelerators(0)
                    ; Return from function
                    Return
                EndIf
        EndSwitch
    WEnd

EndFunc   ;==>_Input

M23

Edit: Oops! Minor code change.

Edited by Melba23

Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

I have not had a chance to look at either code, but your first one will work for my project - now to bring your code into mine LOL. :\

I want to thank you again for all the time you spent on this - I hope to learn from the code and stop asking so many questions :D


All by me:

"Sometimes you have to go back to where you started, to get to where you want to go." 

"Everybody catches up with everyone, eventually" 

"As you teach others, you are really teaching yourself."

From my dad

"Do not worry about yesterday, as the only thing that you can control is tomorrow."

 

WindowsError.gif

WIKI | Tabs; | Arrays; | Strings | Wiki Arrays | How to ask a Question | Forum Search | FAQ | Tutorials | Original FAQ | ONLINE HELP | UDF's Wiki | AutoIt PDF

AutoIt Snippets | Multple Guis | Interrupting a running function | Another Send

StringRegExp | StringRegExp Help | RegEXTester | REG TUTOR | Reg TUTOT 2

AutoItSetOption | Macros | AutoIt Snippets | Wrapper | Autoit  Docs

SCITE | SciteJump | BB | MyTopics | Programming | UDFs | AutoIt 123 | UDFs Form | UDF

Learning to script | Tutorials | Documentation | IE.AU3 | Games? | FreeSoftware | Path_Online | Core Language

Programming Tips

Excel Changes

ControlHover.UDF

GDI_Plus

Draw_On_Screen

GDI Basics

GDI_More_Basics

GDI Rotate

GDI Graph

GDI  CheckExistingItems

GDI Trajectory

Replace $ghGDIPDll with $__g_hGDIPDll

DLL 101?

Array via Object

GDI Swimlane

GDI Plus French 101 Site

GDI Examples UEZ

GDI Basic Clock

GDI Detection

Ternary operator

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0