controlclick() [Question]

[sezercan19]

how to use controlclick() for only x , y position ?

e.g.

controlclick("Untitled -","","",x,y)

how use x and y ? any one help me

note : i dont use ClassNN or Class

[JohnOne]

In order to click a control using controlclick() you first have to tell autoit which control to click, its pretty much self explanitory.

[Yoriz]

the x and y is just within the control it clicks if you read the parameters properly

x [optional] The x position to click within the control. Default is center.

y [optional] The y position to click within the control. Default is center.

to just click using x & y and no controlID use MouseClick.

[goldenix]

Use autoit window info tool to get control names. Even tho I say controls, mostly they are buttons or radio buttons or check boxes = controls.

ControlClick("RF Online", "", "Button1") ; Window name, "", control name.

;~ Or if you cant find out control name. then you can use x & y coordinates
;~ -------------------------------------------------------------------------------------
Opt("MouseCoordMode", 1)        ;1=absolute, 0=relative to active window, 2=client
MouseClick("left", 0, 500, 2) ;, Left mouse,x,y, mouse movind speed

Edited April 24, 2010 by goldenix

[PsaltyDS]

ControlSend() is almost always preferable to Send() because it is more reliable and works on windows that are not active.

The X/Y position of a control can be used to identify it with an Advanced Control ID:

#include <GuiConstantsEx.au3>

$hGUI = GUICreate("Test", 300, 300)
For $n = 0 To 3
    ; Buttons are at X=100; Y=20, 70, 120, and 170
    GUICtrlCreateButton("Button_" & $n, 100, ($n * 50) + 20, 100, 30)
Next
$idTest = GUICtrlCreateButton("TEST", 100, 250, 100, 30)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $idTest
            $sTxt = ControlGetText($hGUI, "", "[X:100; Y:120]") 
            ConsoleWrite("Text = " & $sTxt & @LF) ; Should be Button_2
    EndSwitch
WEnd

When you click TEST on this demo, it reads the text of one button, identifying it by X/Y coordinate. That could just as easily be ControlClick() vice ControlGetText().

Note in this usage that X/Y are client area relative coordinates of the control itself (top/left corner), not just any point inside the control.

Edited April 26, 2010 by PsaltyDS

[sezercan19]

thanx all solved.