Jump to content
Sign in to follow this  
Followers 0
AndyS01

Trap the ENTER key via GUISetAccelerators() when in EventMode

By AndyS01, in AutoIt GUI Help and Support

Recommended Posts

AndyS01    0

AndyS01
Posted
I have a GUI with several input boxes and I want to trap the ENTER key so I can call handlers for each one.
 
However, when I put in a HotKeySet() to trap the ENTER key, it traps it OK, but I also get traps when I press the ENTER key anywhere else on my desktop, no matter what GUI has focus, so I changed the code to use GUISetAccelerators().  I cannot see how to attach a handler for the ENTER key for each of my input controls.
 
My real script uses event mode (Opt("GUIOnEventMode", 1)), so that's what I'm using in my test code.
 
Here is my test code:
#NoTrayIcon
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_UseUpx=n
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#include <GUIConstantsEx.au3>
#include <StructureConstants.au3>
OnAutoItExitRegister("ExitStageLeft")

Opt("GUICloseOnESC", 1)
Opt("GUIEventOptions", 1)
Opt("GUIOnEventMode", 1) ;; <=====
Opt("WinTitleMatchMode", 1)
Opt('MustDeclareVars', 1)

Global $hWnd_list1, $hWnd_input1, $hGUI, $sWinTitle
Global $iID_list1, $iID_input1

_Main()
Exit (1)

Func _Main()

    $sWinTitle = "ENTER key trap test"
    $hGUI = GUICreate($sWinTitle, 500, 230)

    GUICtrlCreateButton("Test", 5, 5, 50, 25)
    $iID_input1 = GUICtrlCreateInput("input1", 70, 5, 100, 25)
    $hWnd_input1 = GUICtrlGetHandle($iID_input1)

    $iID_list1 = GUICtrlCreateEdit("list1", 10, 40, 475, 190)
    $hWnd_list1 = GUICtrlGetHandle($iID_list1)
    GUICtrlSetData($iID_list1, "abcdefghijklmnopqrstuvwxyz" & @CRLF, 1)

    ConsoleWrite("+++: $iID_list1  = " & $iID_list1 & @CRLF)
    ConsoleWrite("+++: $iID_input1 = " & $iID_input1 & @CRLF)

    GUISetState()

    GUICtrlSetOnEvent($iID_list1, "handle_List1")
    GUICtrlSetOnEvent($iID_input1, "handle_Input1")

    GUISetOnEvent($GUI_EVENT_CLOSE, 'ExitStageLeft')

    Local $aAccelKeys[2][2]
    $aAccelKeys[0][0] = "{ENTER}"
    $aAccelKeys[0][1] = $iID_input1
    $aAccelKeys[1][0] = "{ENTER}"
    $aAccelKeys[1][1] = $iID_list1

    GUISetAccelerators($aAccelKeys)

    While (1)
        Sleep(250)
    WEnd
EndFunc   ;==>_Main

Func ExitStageLeft()
    Exit (0)
EndFunc   ;==>ExitStageLeft

Func handle_Input1()
    ConsoleWrite("+++: handle_Input1() entered" & @CRLF)
EndFunc   ;==>handle_Input1

Func handle_List1()
    ConsoleWrite("+++: handle_List1() entered" & @CRLF)
EndFunc   ;==>handle_List1

 

 

Share this post

Link to post
Share on other sites

BrewManNH    1,112

BrewManNH
Posted

You can't use the same hotkey or accellerator for 2 controls at the same time.

If I posted any code, assume that code was written using the latest release version unless stated otherwise. Also, if it doesn't work on XP I can't help with that because I don't have access to XP, and I'm not going to.
Give a programmer the correct code and he can do his work for a day. Teach a programmer to debug and he can do his work for a lifetime - by Chirag Gude
How to ask questions the smart way!

I hereby grant any person the right to use any code I post, that I am the original author of, on the autoitscript.com forums, unless I've specifically stated otherwise in the code or the thread post. If you do use my code all I ask, as a courtesy, is to make note of where you got it from.

Back up and restore Windows user files _Array.au3 - Modified array functions that include support for 2D arrays.  -  ColorChooser - An add-on for SciTE that pops up a color dialog so you can select and paste a color code into a script.  -  Customizable Splashscreen GUI w/Progress Bar - Create a custom "splash screen" GUI with a progress bar and custom label.  -  _FileGetProperty - Retrieve the properties of a file  -  SciTE Toolbar - A toolbar demo for use with the SciTE editor  -  GUIRegisterMsg demo - Demo script to show how to use the Windows messages to interact with controls and your GUI.  -   Latin Square password generator

Share this post

Link to post
Share on other sites

LarsJ    613

LarsJ
Posted

Try this:

#NoTrayIcon
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_UseUpx=n
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#include <WinAPI.au3>
#include <GUIConstantsEx.au3>
#include <StructureConstants.au3>
OnAutoItExitRegister("ExitStageLeft")

Opt("GUICloseOnESC", 1)
Opt("GUIEventOptions", 1)
Opt("GUIOnEventMode", 1) ;; <=====
Opt("WinTitleMatchMode", 1)
Opt('MustDeclareVars', 1)

Global $hWnd_list1, $hWnd_input1, $hGUI, $sWinTitle
Global $iID_list1, $iID_input1, $iID_Enter

_Main()
Exit (1)

Func _Main()

    $sWinTitle = "ENTER key trap test"
    $hGUI = GUICreate($sWinTitle, 500, 230)

    GUICtrlCreateButton("Test", 5, 5, 50, 25)
    $iID_input1 = GUICtrlCreateInput("input1", 70, 5, 100, 25)
    $hWnd_input1 = GUICtrlGetHandle($iID_input1)

    $iID_list1 = GUICtrlCreateEdit("list1", 10, 40, 475, 190)
    $hWnd_list1 = GUICtrlGetHandle($iID_list1)
    GUICtrlSetData($iID_list1, "abcdefghijklmnopqrstuvwxyz" & @CRLF, 1)

    ConsoleWrite("+++: $iID_list1  = " & $iID_list1 & @CRLF)
    ConsoleWrite("+++: $iID_input1 = " & $iID_input1 & @CRLF)

    GUISetState()

    GUISetOnEvent($GUI_EVENT_CLOSE, 'ExitStageLeft')

    $iID_Enter = GUICtrlCreateDummy()
    GUICtrlSetOnEvent($iID_Enter, "handle_Enter")
    Local $aAccelKeys[1][2]
    $aAccelKeys[0][0] = "{ENTER}"
    $aAccelKeys[0][1] = $iID_Enter

    GUISetAccelerators($aAccelKeys)

    While (1)
        Sleep(250)
    WEnd
EndFunc   ;==>_Main

Func ExitStageLeft()
    Exit (0)
EndFunc   ;==>ExitStageLeft

Func handle_Enter()
  Local $hCtrl = ControlGetHandle( $hGUI, "", ControlGetFocus( $hGUI ) )
  Local $iCtrl = _WinAPI_GetDlgCtrlID( $hCtrl )
  Switch $iCtrl
    Case $iID_list1
      ConsoleWrite("+++: handle_List1() entered" & @CRLF)
    Case $iID_input1
      ConsoleWrite("+++: handle_Input1() entered" & @CRLF)
  EndSwitch
EndFunc
  • Like 1

Compiled code: Accessing AutoIt variables,  DotNet.au3 UDF,  Using C# and VB code
Windows Explorer: Automating and examples,  Implementing right pane,  Implementing address bar
Shell menus: The Context menu,  The Favorites menu.  Shell related: Control Panel,  System Image Lists
Graphics related: Rubik's Cube,  OpenGL without external libraries,  Navigating in an image,  Non-rectangular selections
Control related: Hot-Track Enabled Toolbar Menu,  Simulating a modeless Choose Color Dialog,  Colors and fonts in TreeViews
ListView controls: Colors and fonts,  Multi-line header,  Multi-line items,  Checkboxes and icons,  Incremental search
ListView controls: Virtual ListViews,  Editing cells,  Data display functions

Share this post

Link to post
Share on other sites

AndyS01    0

AndyS01
Posted

Thank you very much!  Using a dummy control to handle the ENTER key only when it's pressed somewhere on the main GUI did the trick.  I'll add this little gem to my collection of tips and workarounds.

 

Share this post

Link to post
Share on other sites

Chimp    474

Chimp
Posted

also have a look >here

small minds discuss people average minds discuss events great minds discuss ideas.... and use AutoIt....

Share this post

Link to post
Share on other sites

AndyS01    0

AndyS01
Posted

I ran into a problem implementing LarsJ's code.  If I don't handle the ENTER key for a certain control and I want that control to receive an actual ENTER key event, the ENTER key is ignored.  If I Send("{ENTER}") to those controls, I get into an infinite loop.

Here is my handler code:

Func handle_ENTERKey($iCtrl)
    local $handled = False

    Switch $iCtrl
        Case $iID_list1
            ConsoleWrite("+++: handle_List1() entered" & @CRLF)
            $handled = true
        Case $iID_input1
            ConsoleWrite("+++: handle_Input1() entered" & @CRLF)
            ;;$handled = true
    EndSwitch

    if (not $handled) Then
        Send("{CRLF}")
    EndIf
EndFunc   ;==>handle_ENTERKey
 

I call this code from the dummy control's handle_ENTER() handler, with $iCtrl as its parameter..

If I handle the event, everything is OK, but if I want the ENTER key to go into my list control, sending a "{ENTER}" key gets me into a loop because that will call the ENTER key handler again.

How can I pass the ENTER key to controls I don't want to do any special handling for?

 

Share this post

Link to post
Share on other sites

Chimp    474

Chimp
Posted (edited)

I ran into a problem implementing LarsJ's code.  If I don't handle the ENTER key for a certain control and I want that control to receive an actual ENTER key event, the ENTER key is ignored.  If I Send("{ENTER}") to those controls, I get into an infinite loop.

. . . . .

How can I pass the ENTER key to controls I don't want to do any special handling for?

 

you should disable accelerators,  ControlSend {ENTER} to control with focus and reenable accelerators again

....have a look to link I posted above ....

edit:

also look to post >#8 of the above topic for an explanation

Edited by PincoPanco

small minds discuss people average minds discuss events great minds discuss ideas.... and use AutoIt....

Share this post

Link to post
Share on other sites

AndyS01    0

AndyS01
Posted (edited)

Right-o.  I changed my Enter key handler to look something like this:

Func handle_ENTERKey($iCtrl)
    local $handled = False

    Switch $iCtrl
        Case $iID_list1
            ConsoleWrite("+++: ENTER while on list1" & @CRLF)
            ;;  $handled = true
        Case $iID_input1
            ConsoleWrite("+++: ENTER while on Input1" & @CRLF)
            $handled = true
    EndSwitch

    if (not $handled) Then
        GUISetAccelerators(0)
        ConsoleWrite("+++: sending {ENTER} to control ID " & $iCtrl & @CRLF)
        Send("{ENTER}")
        GUISetAccelerators($AccelKeys) ;
    EndIf
EndFunc   ;==>handle_ENTERKey

Works like I want it to.  Thanks, PincoPanco

Edited by AndyS01

Share this post

Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
Sign in to follow this  
Followers 0
Go To Topic Listing AutoIt GUI Help and Support

  • Similar Content

    • therks
      GUIsetaccelerators doesn't work for Ctrl+Shift+0 (zero)
      By therks
      So I'm working on an application and I've hot keyed all the numbers, and for some reason this particular combination doesn't work. All the other numbers with Ctrl+Shift work fine, and all other combinations of modifiers work with 0. Has anyone else encountered this? It's very strange. 
      Guicreate('', 300, 300) $button = GUICtrlCreateButton('Button', 0, 0) Dim $accel = [ [ '^+0', $button ] ] GUIsetaccelerators($accel) Do $gm = guigetmsg()  If $gm = $button then msgbox(0,'','test') Until $gm = - 3 Sorry for the ugly code, i typed this up on my phone. 😅
    • AndyS19
      Pass unused Accelerator keys back to the system
      By AndyS19
      I have a script that traps ^A and ^C accelerator keys via the GUISetAccelerators() function, and in the key handlers, I check to see if the focus is on the control that I want the keys to operate on.
      However, when I see that I'm not on that control, I want to pass the ^C and ^A back to the system so I can copy and past data on other controls.
      Here is my test script.  I have it applying ^A and ^C only to the ListView control.  When I put focus on the Input control, I want to be able to copy and paste normally.
      Opt("GUICloseOnESC", 1) ; ESC does not close the GUI Opt("GUIOnEventMode", 1) ; Change to OnEvent mode Opt('MustDeclareVars', 1) OnAutoItExitRegister("ExitStageLeft") #include <Array.au3> #include <GuiListBox.au3> #include <GUIConstantsEx.au3> #include <ListBoxConstants.au3> #include <WindowsConstants.au3> #include <GuiListView.au3> Global $hGUI, $iInput, $iList, $hInput, $hList _Main() Func _Main() Local $str, $parts $hGUI = GUICreate("", 250, 500) $iInput = GUICtrlCreateInput("2", 90, 5, 50, 20) $hInput = GUICtrlGetHandle($iInput) $iList = GUICtrlCreateListView("First Column ", 5, 30, 240, 470, $LBS_EXTENDEDSEL) $hList = GUICtrlGetHandle($iList) For $ndx = 1 To 100 $str = StringFormat("%s ABC", $ndx) Local $ret = _GUICtrlListView_AddItem($hList, $str) Next setupSpecialKeysHandlers() GUISetOnEvent($GUI_EVENT_CLOSE, "ExitStageLeft") GUISetState(@SW_SHOW) While (1) Sleep(250) WEnd EndFunc ;==>_Main Func ExitStageLeft() Exit (1) EndFunc ;==>ExitStageLeft Func setupSpecialKeysHandlers() Local $aAccelKeys[1][2] Local $ar, $parts, $key, $handler, $id ; Create a table of Special keys and their handlers $ar = StringSplit("", "") _ArrayAdd($ar, "{ENTER} - handle_ENTER_key ") _ArrayAdd($ar, "^a - handle_CTRL_A_key ") _ArrayAdd($ar, "^c - handle_CTRL_C_key ") ReDim $aAccelKeys[UBound($ar) - 1][2] ; Now, create $aAccelKeys array with the table data. ; For each entry, create a Dummy GUI and associate its ; ID with the special key. For $ndx = 1 To UBound($ar) - 1 $parts = StringSplit($ar[$ndx], "-", 2) $key = StringStripWS($parts[0], 8) $handler = StringStripWS($parts[1], 8) $id = GUICtrlCreateDummy() $aAccelKeys[$ndx - 1][0] = $key $aAccelKeys[$ndx - 1][1] = $id GUICtrlSetOnEvent($id, $handler) Next ; Dump the contents of the $aAccelKeys array For $ndx = 0 To UBound($aAccelKeys) - 1 logMsg("$aAccelKeys" _ & " [" & $ndx & "][0] = " & StringFormat("%-8s", $aAccelKeys[$ndx][0]) _ & " [" & $ndx & "][1] = " & $aAccelKeys[$ndx][1]) Next GUISetAccelerators($aAccelKeys) ; Setup the Special keys hooks EndFunc ;==>setupSpecialKeysHandlers Func logMsg($msg, $lnum = @ScriptLineNumber) ConsoleWrite("+++:" & $lnum & ": " & $msg & @CRLF) EndFunc ;==>logMsg Func handle_ENTER_key() logMsg("+++: handle_ENTER_key() entered") EndFunc ;==>handle_ENTER_key Func handle_CTRL_A_key() logMsg("+++: handle_CTRL_A_key() entered") If (Not isCtrlFocused($hList)) Then Return selectAllGLVItems() EndFunc ;==>handle_CTRL_A_key Func handle_CTRL_C_key() logMsg("+++: handle_CTRL_C_key() entered") If (isCtrlFocused($hList)) Then extractSelListViewGamesToClip() Else EndIf EndFunc ;==>handle_CTRL_C_key Func isCtrlFocused($hWnd) Local $hCtrl $hCtrl = ControlGetHandle($hGUI, "", ControlGetFocus($hGUI)) Return ($hWnd = $hCtrl) ? True : False EndFunc ;==>isCtrlFocused Func selectAllGLVItems() Local $hWnd = $hList, $iIndex For $iIndex = 0 To _GUICtrlListView_GetItemCount($hWnd) _GUICtrlListView_SetItemSelected($hWnd, $iIndex) Next EndFunc ;==>selectAllGLVItems Func extractSelListViewGamesToClip() Local $hWnd = $hList Local $iIndex, $item, $str, $sep = "" $str = "" For $iIndex = 0 To _GUICtrlListView_GetItemCount($hWnd) If (_GUICtrlListView_GetItemSelected($hWnd, $iIndex)) Then $item = _GUICtrlListView_GetItemText($hWnd, $iIndex) $str &= $sep & $item $sep = @CRLF EndIf Next ClipPut($str) logMsg("Copied " & StringLen($str) & " bytes to the Clipboard:" & @CRLF & $str) EndFunc ;==>extractSelListViewGamesToClip  
    • John C.
      _ArrayDisplay use Enter key to copy the highlighted item
      By John C.
      ;Adding $BS_DEFPUSHBUTTON doesn't work
              $idCopy_Data = GUICtrlCreateButton("Copy Data Only", $iButtonWidth_2, $aiGUISize[1] - $iButtonMargin, $iButtonWidth_2, 20, $BS_DEFPUSHBUTTON)
      ;Adding these two lines doesn't work either
               Local $aAccelKeys[2][2] = [["{enter}", $idCopy_Data], ["^{enter}", $idCopy_ID]]
              GUISetAccelerators($aAccelKeys)
       
    • vindicta
      Help Needed with GUISetAccelerators
      By vindicta
      Hello everyone,
      I am trying to setup a GUI accelerator to close the utility as soon as esc is pressed.  It works fine with hotkey but I want to make sure that the utility only exits if its window was active when esc was pressed. My utility has 2 buttons, Backup and Restore.
      The exit function checks if the button clicked was Backup or Restore and then displays an error message accordingly.
      If pressed backup, $button = 1
      if pressed restore, $button = 2
      the value of $button is set inside backup() or restore() functions
      Opt("GUIOnEventMode", 1) Opt("GUICoordMode", 1) $Form1 = GUICreate("Form1", 419, 124, 238, 194, $WS_DLGFRAME) $B_backup = GUICtrlCreateButton("Backup", 48, 40, 145, 41) $B_restore = GUICtrlCreateButton("Restore", 224, 40, 145, 41) ;================ > HotKeySet('{ESC}', "terminate") GUICtrlSetOnEvent($B_backup, "Backup") GUICtrlSetOnEvent($B_restore, "Restore") GUISetState(@SW_SHOW) Dim $accelKey[1][2] = [["{ESC}", terminate()]] GUISetAccelerators($accelKey) While 1     Switch GUIGetMsg()         Case $GUI_EVENT_CLOSE             Exit     EndSwitch WEnd  
      Exit function:
      func terminate() Do     $msg = GUIGetMsg() Until $msg <> 0 While 1         If $button = 1 Then             ProcessClose("robocopy.exe")             MsgBox(16, "Abort!", "Backup Aborted!")             exit         ElseIf $button = 2 Then             ProcessClose("robocopy.exe")             MsgBox(16, "Abort!", "Restore Aborted!")             exit         Else             While 1                 For $i = 3 To 1 Step -1                     SplashTextOn("Closing Utility...", $i, 130, 54, -1, -1, 0, "Calibri", "", 900)                     Sleep(1000)                 Next                 ExitLoop             WEnd             SplashOff()             Exit Endif WEnd What am I doing wrong here? The utility closes as soon as it launches with Splash text.
    • Skysnake
      [solved] GUISetAccelerators(0) ; Remove accelerator link
      By Skysnake
      Hi All
      Question, the Help file contains this:
      So, is it necessary to put 
      GUISetAccelerators(0) ; Remove accelerator link in the GUI?  Once the GUI is deleted, the Accelerators are gone...?
      Enter like tab discussion contains this item.  Is it essential?
×