timer and array

[ReDFlaG]

Hi

Little issue with that simple code, may someone tell me why i can' t have the array displayed ?

#include <Timers.au3>
#include <Array.au3>
#include <GUIConstantsEx.au3>


$mainwindow = GUICreate("TEST", 400, 320)
GUISetState(@SW_SHOW)

global $arr_switch[5] = ["Item 0", "Item 1", "Item 2", "Item 3", "Item 4"]

Func _AutoRefresh($hWnd, $Msg, $iIDTimer, $dwTime)
    #forceref $hWnd, $Msg, $iIDTimer, $dwTime
    _ArrayDisplay($arr_switch)
EndFunc

$autorefresh=_Timer_SetTimer ($mainwindow,6000,"_AutoRefresh")

While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
WEnd

Thanks

[Danyfirex]

Use consolewrite.  don't pause your script.

saludos

[Danyfirex]

or use adlibregister

#include <Timers.au3>
#include <Array.au3>
#include <GUIConstantsEx.au3>


$mainwindow = GUICreate("TEST", 400, 320)
GUISetState(@SW_SHOW)

global $arr_switch[5] = ["Item 0", "Item 1", "Item 2", "Item 3", "Item 4"]


Func _AutoRefresh()
    _ArrayDisplay($arr_switch)
EndFunc

AdlibRegister("_AutoRefresh",6000)

While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
WEnd
AdlibUnRegister("_AutoRefresh")

I keep thinking best way is use consolewrite.

saludos

[jguinch]

Or use put the _ArrayDisplay in the main loop :

#include <Timers.au3>
#include <Array.au3>
#include <GUIConstantsEx.au3>

$iDisplay = 0

$mainwindow = GUICreate("TEST", 400, 320)
GUISetState(@SW_SHOW)

global $arr_switch[5] = ["Item 0", "Item 1", "Item 2", "Item 3", "Item 4"]

Func _AutoRefresh($hWnd, $Msg, $iIDTimer, $dwTime)
    #forceref $hWnd, $Msg, $iIDTimer, $dwTime
    $iDisplay = 1
EndFunc

$autorefresh=_Timer_SetTimer ($mainwindow,6000,"_AutoRefresh")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
    
    If $iDisplay Then
        $iDisplay = 0
        _ArrayDisplay($arr_switch)
    EndIf
WEnd

Edited October 23, 2014 by jguinch

[ReDFlaG]

both solution are working. thanks