_GUICtrlDTP_GetSystemTime() seems not to be compatible with _GUICtrlDTP_SetSystemTime()

[Jefrey]

Hi!

I'm having problems when, after getting a datetimepicker control's data, I try to restore it later.

It seems that _GUICtrlDTP_GetSystemTime() gerenates a 0-based index array (C-like), while _GUICtrlDTP_SetSystemTime() expects a 1-based index array (pascal-like).

I made this simple example:

#include <ButtonConstants.au3>
#include <DateTimeConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiDateTimePicker.au3>
#include <Array.au3>


GUICreate("sample", 288, 105)

$picker = GUICtrlCreateDate("2015/06/24 14:22:35", 8, 8, 274, 21)
$getsystemtime = GUICtrlCreateButton("GetSystemTime", 8, 40, 273, 25)
$setsystemtime = GUICtrlCreateButton("SetSystemTime (after clicking above)", 8, 72, 275, 25)

GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $getsystemtime
            $aSystemtime = _GUICtrlDTP_GetSystemTime(GUICtrlGetHandle($picker))
            _ArrayDisplay($aSystemtime)

        Case $setsystemtime
            If Not IsDeclared('aSystemtime') Then
                MsgBox(0, '', 'click getsystemtime first')
            Else
                _ArrayDisplay($aSystemtime)
                _GUICtrlDTP_SetSystemTime(GUICtrlGetHandle($picker), $aSystemtime)
            EndIf

    EndSwitch
WEnd

When I run it and press GetSystemTime, I see this array:

And when I put this same array into the picker again, using _GUICtrlDTP_SetSystemTime(), it breaks the script and the SciTe console shows:

"C:\Program Files (x86)\AutoIt3\Include\GuiDateTimePicker.au3" (286) : ==> Array variable has incorrect number of subscripts or subscript dimension range exceeded.:
DllStructSetData($tDate, "Second", $aDate[6])
DllStructSetData($tDate, "Second", ^ ERROR

I could fix it just with a few modifications on the _GUICtrlDTP_GetSystemTime() function on %PROGRAMFILES%\AutoIt3\Include\GuiDateTimePicker.au3, which starts on line 159:

; #FUNCTION# ====================================================================================================================
; Author ........: Paul Campbell (PaulIA)
; Modified.......: Jefrey
; ===============================================================================================================================
Func _GUICtrlDTP_GetSystemTime($hWnd)
    Local $aDate[7]
 ; modified the array range, from 6 to 7

    Local $tDate = _GUICtrlDTP_GetSystemTimeEx($hWnd)
    $aDate[0] = False ; pushed the item 0 (if true, the input will be 'no date') and re-set the following indexes:
    $aDate[1] = DllStructGetData($tDate, "Year")
    $aDate[2] = DllStructGetData($tDate, "Month")
    $aDate[3] = DllStructGetData($tDate, "Day")
    $aDate[4] = DllStructGetData($tDate, "Hour")
    $aDate[5] = DllStructGetData($tDate, "Minute")
    $aDate[6] = DllStructGetData($tDate, "Second")
    Return $aDate
EndFunc   ;==>_GUICtrlDTP_GetSystemTime

I'm using AutoIt version 3.3.12.0. Has someone also faced this issue?

Edited June 24, 2015 by Jefrey

[BrewManNH]

You could use something like this to add the first parameter to the array returned by _GUICtrlDTP_GetSystemTime

Local $aDate = StringSplit(True & "|" & _ArrayToString($aSystemTime), "|", $STR_NOCOUNT )

 

[Jefrey]

@BrewManNH thanks for your reply!
That's another solution. Can it be considered a bug on the GuiDateTimePicker.au3 lib?

[BrewManNH]

I wouldn't call it a bug, more like a design decision that wasn't well thought out. A bug is something that doesn't work as intended in the code, this works exactly like it is designed to do.