Jump to content
Valnurat

A little advice

Recommended Posts

Valnurat

What kind og GUI item can I use to show some numbers in?

I would like to have the option not to have scrollbars and if possible have 3 columns and it sould also have the option to sort the content.

What would you suggest?


Yours sincerely

Kenneth.

Share this post


Link to post
Share on other sites
Melba23

Valnurat,

I would suggest a ListView.

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites
Valnurat

Ok, but it dosen't seem that I have any option to not have any scrollbars.


Yours sincerely

Kenneth.

Share this post


Link to post
Share on other sites
Melba23

Valnurat,

You only get scrollbars if there are too many items to fit into the control - and if you did not have the scrollbars you would not be able to see the items. Why is this such a breaking point?

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites
Valnurat

That's true, but in my situation it is not necessary to see them all. Only the top 20 numbers.

Can you change the size of the font in the ListView?


Yours sincerely

Kenneth.

Share this post


Link to post
Share on other sites
Melba23

Valnurat,

Quote

Can you change the size of the font in the ListView?

Yes, if you create the ListView with GUICtrlCreateListView then GUICtrlSetFont will work.

And if you only want the top 20, then only load that many into the ListView - that way you will avoid scrollbars if you size the control correctly:

#include <GUIConstantsEx.au3>
#include <GUIListView.au3>

$hGUI = GUICreate("Test", 500, 500)

$cLV = GUICtrlCreateListView("Col 0|Col 1|Col 2", 10, 10, 480, 480)

; Size columns
For $i = 0 To 2
    _GUICtrlListView_SetColumnWidth($cLV, $i, Int(480 / 3) - 2) ; avoid horizontal scrollbar by makign columns slightly smaller then total width
Next

; Fill ListView with 20 items
For $i = 0 To 19
    GUICtrlCreateListViewItem(StringFormat("%05i", $i) & "|" & StringFormat("%05i", $i) & "|" & StringFormat("%05i", $i), $cLV)
Next

; Now size ListView vertically
$hHeader = _GUICtrlListView_GetHeader($cLV)
$aSize = WinGetPos($hHeader)
$iHeaderHeight = $aSize[3] ; Header height
$aRect = _GUICtrlListView_GetItemRect($cLV, 0)
$iItemHeight = $aRect[3] - $aRect[1] ; Item height
$iTotalHeight = $iHeaderHeight + (20 * ($iItemHeight + .5)) ; Allow for the inter-item gaps
; Resize ListView
GuiCtrlSetPos($cLV, 10, 10, 480, $iTotalHeight)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites
Valnurat

Thank you M23.

I need to have 3 listview in my project.

1. To have a listview1 with 3 columns with vertical lines to seperate the columns and in designtime have vertical scrollbars and no horizontial. I want to know from the start, how it would look like when numbers are added.

2. To have another listview2 that only show the top 20 numbers out of 90 and when numbers are picked out from LV2 it should be transferred to listview3 and then the next number should be visible. E.g. In your example 0-19 are visible. If 7 is picked, it should still show the top 20 numbers in LV2 and 7 is moved to LV3.

For now it seems that the listview only show scrollbars if it is necessary. Or do you have another suggestion?

Edited by Valnurat

Yours sincerely

Kenneth.

Share this post


Link to post
Share on other sites
Melba23

Valnurat,

How about this:

#include <GUIConstantsEx.au3>
#include <GUIListView.au3>

$iMax = 90

Global $aMainArray[$iMax]
For $i = 0 To $iMax - 1
    $aMainArray[$i] = StringFormat("%05i", $i) & "|" & StringFormat("%05i", $i) & "|" & StringFormat("%05i", $i)
Next

$hGUI = GUICreate("Test", 900, 500)

; Create ListView 1
$cLV_1 = GUICtrlCreateListView("Col 0|Col 1|Col 2", 10, 10, 280, 480)
; Size columns
For $i = 0 To 2
    _GUICtrlListView_SetColumnWidth($cLV_1, $i, Int(280 / 3) - 2) ; avoid horizontal scrollbar by making columns slightly smaller then total width
Next

; Fill ListView with all items
For $i = 0 To $iMax - 1
    GUICtrlCreateListViewItem($aMainArray[$i], $cLV_1)
Next

; Now calculate ListView 2 vertical size
$hHeader = _GUICtrlListView_GetHeader($cLV_1)
$aSize = WinGetPos($hHeader)
$iHeaderHeight = $aSize[3] ; Header height
$aRect = _GUICtrlListView_GetItemRect($cLV_1, 0)
$iItemHeight = $aRect[3] - $aRect[1] ; Item height
$iTotalHeight = $iHeaderHeight + (20 * ($iItemHeight + .5)) ; Allow for the inter-item gaps

; Create ListView 2
$cLV_2 = GUICtrlCreateListView("Col 0|Col 1|Col 2", 300, 10, 280, $iTotalHeight)
For $i = 0 To 2
    _GUICtrlListView_SetColumnWidth($cLV_2, $i, Int(280 / 3) - 2)
Next
; Fill with top 20 of array
For $i = 0 To 19
    GUICtrlCreateListViewItem($aMainArray[$i], $cLV_2)
Next

; Create button to move element from ListView 2 to ListView 3
$cMove = GUICtrlCreateButton("Move Selected", 300, 430, 280, 60)

; Create ListView 3
$cLV_3 = GUICtrlCreateListView("Col 0|Col 1|Col 2", 600, 10, 280, 480)
; Size columns
For $i = 0 To 2
    _GUICtrlListView_SetColumnWidth($cLV_3, $i, Int(280 / 3) - 2)
Next

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cMove
            $sText = _GUICtrlListView_GetItemTextString($cLV_2)
            If $sText Then
                ; Add to ListView 3
                GUICtrlCreateListViewItem($sText, $cLV_3)
            EndIf
            ; Find element in main array
            $iIndex = _ArraySearch($aMainArray, $sText)
            If $iIndex <> - 1 Then
                ; Delete it
                _ArrayDelete($aMainArray, $iIndex)
            EndIf
            ; Now clear ListViews 1 & 2
            _GUICtrlListView_BeginUpdate($cLV_1)
            _GUICtrlListView_BeginUpdate($cLV_2)
            _GUICtrlListView_DeleteAllItems($cLV_1)
            _GUICtrlListView_DeleteAllItems($cLV_2)
            ; And reload with all / the top 20 elements in the main array
            $iMax = UBound($aMainArray) - 1
            For $i = 0 To $iMax
                GUICtrlCreateListViewItem($aMainArray[$i], $cLV_1)
                If $i < 20 Then
                    GUICtrlCreateListViewItem($aMainArray[$i], $cLV_2)
                EndIf
            Next
            _GUICtrlListView_EndUpdate($cLV_1)
            _GUICtrlListView_EndUpdate($cLV_2)
    EndSwitch
WEnd

That seems to do what you require.

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites
Valnurat

That is awesome.

Is it possible to have vertical lines between the column all the way down in listview 1 and can you sort listview 3?


Yours sincerely

Kenneth.

Share this post


Link to post
Share on other sites
Valnurat

Listview1 should have 3 columns, Listview 2 and 3 should only have 1 column.

And it could be nice if there was no header in the listviews.

Edited by Valnurat

Yours sincerely

Kenneth.

Share this post


Link to post
Share on other sites
Melba23

Valnurat,

12 hours ago, Valnurat said:

Is it possible to have vertical lines between the column all the way down in listview 1

You can apply the $LVS_EX_GRIDLINES style, but that gives you vertical and horizontal lines.

12 hours ago, Valnurat said:

can you sort listview 3?

Yes, the _GUICtrlListView_SimpleSort example in the Help file shows you how to do it.

1 hour ago, Valnurat said:

Listview1 should have 3 columns, Listview 2 and 3 should only have 1 column

Then amend the code used when you create the ListViews 2 & 3.

1 hour ago, Valnurat said:

And it could be nice if there was no header in the listviews.

Just apply the $LVS_NOCOLUMNHEADER style.

M23

 


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites
Valnurat

Thank you very much. 5 stars.

I learn a lot from your example.


Yours sincerely

Kenneth.

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now

  • Similar Content

    • SharpDressedMan
      By SharpDressedMan
      Hello,
      Is there any way to check for validity of a pointer to a DllStruct ?
      In the above code, a DllStruct is created from an invalid pointer. How to prevent from doing this ?
      local $tStruct = DllStructCreate("int i") DllStructSetData($tStruct, "i", 123) local $pStruct = DllStructGetPtr($tStruct) $tStruct = 0 ; destroy DllStruct ==> $pStruct becomes invalid ; how to check here for validity of $pStruct and prevent from doing the following ? $tStruct = DllStructCreate("int i", $pStruct) ; create DllStruct from invalid pointer... MsgBox(0, @ScriptName, @error) ; displays '0' : invalid pointer is not detected by DllStructCreate() MsgBox(0, @ScriptName, IsDllStruct($tStruct)) ; displays '1' : tStruct is assumed as a valid DllStruct object, which is not Thanks for help
    • nooneclose
      By nooneclose
      I need to send a string of text to this popup and click on the ok button to save it.
      Here is the code I have so far:
      ;Start IE Sleep(7000) $oIE = _IECreate("http://www.google.com") Sleep(500) _IELoadWait($oIE) $hIE = _IEPropertyGet($oIE, "hwnd") ; Get Handle of the IE window Sleep(500) WinSetState($hIE, "", @SW_MAXIMIZE) ;Wait for a browser page load to complete Sleep(3000) _IENavigate($oIE, "https://properURL.com") Sleep(8000) _IELoadWait($oIE) ;Attach to a browser control embedded in another window $oIE = _IEAttach("https://"properURL.com", url") ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $oIE = ' & $oIE & @CRLF & '>Error code: ' & @error & ' Extended code: 0x' & Hex(@extended) & @CRLF) ;### Debug Console Sleep(2000) ;Get the title of the webpage ;Local $wTitle = _IEPropertyGet($oIE, "title") ;MsgBox($MB_SYSTEMMODAL, "Webpage title:", $wTitle) ;Clicks the new button Sleep(3000) _IEAction($nWorkOrderB, "focus") _IEAction($nWorkOrderB, "click") Sleep(5000) ;Store the Element names where the important data will be sent ;Store the long description button Local $wLongDButton = _IEGetObjById($oIE, "m65d795a4-img") ;Store the long Description field id Local $wComments = _IEGetObjById($oIE, "ma6499a9c-rte_iframe") ;Store the ok button id that is in the long description Local $wCommOk = _IEGetObjById($oIE, "m74031266-pb") ;******************************************************************************* ; Send the stored data to the proper field ;******************************************************************************* ;Click the long description button Sleep(300) _IEAction($wLongDButton, "focus") _IEAction($wLongDButton, "click") Sleep(300) ;Sends the Comments Sleep(500) _IEAction($wComments, "focus") _IEAction($wComments, "click") Sleep(500) _IEFormElementSetValue($wComments, "hello darkness my old friend") ;Click the ok button Sleep(500) _IEAction($wCommOk, "focus") _IEAction($wCommOk, "click") Sleep(500)  
      Here is the popup:

    • yasha
      By yasha
      i want am trying to select a nimber to run a program and then select where to save the excel result at before hand
      the problem is that it does not save in the folder i want but the folder before any solutions
      #.................
      $sFolder = ""
          ; Create a constant variable in Local scope of the message to display in FileSelectFolder.
          Local Const $sMessage = "Select a folder"
          ; Display an open dialog to select a file.
          $sFileSelectFolder = FileSelectFolder($sMessage, $sFolder)
          If @error Then
              ; Display the error message.
              MsgBox($MB_SYSTEMMODAL, "", "No folder was selected.")
          Else
              ; Display the selected folder.
              MsgBox($MB_SYSTEMMODAL, "", "You chose the following folder:" & @CRLF & $sFileSelectFolder)
          EndIf
      .......
      ........
      $oExcel = ObjCreate("Excel.Application")                   ; Create an Excel Object
      $oExcel.Visible = 1                                        ; Let Excel show itself
      $oExcel.Workbooks.Open("J:\OPS\OPS_Share\Planners\2 - Weekly Reports\Auto download\"& $YY & $MM & $DD & " ORDER.xls",0)
      $oExcel.ActiveWorkbook.Saveas ( $sFileSelectFolder,""& $YY & $MM & $DD & " ORDER.xlsx", 1)
      $oExcel.ActiveWorkBook.Close
      $oExcel.Quit
      i only want to save it as ddmmyy order inside documents but it saves in libraries as documents ddmmyy order.
    • vynce1982
      By vynce1982
      I am trying to make a simple installer script for my understanding.  I would just like to understand how to deal with multiple possible windows. In the case of installing VLC, I might get a window saying VLC is already installed. I have also tried a switch with no luck.  I would just like to understand some methods for dealing with the possible existence of unexpected windows. 
       
      ;INSTALL VLC VIEWER
      Run(@ScriptDir & '\bin\VLCViewer_2.2.4_3.EXE')
      AutoItSetOption('MouseCoordMode', 0)
      sleep(4000)
      WinWait("VLC Viewer 2.2.4")

           ; this window will pop up if vlc is already installed
          If WinExists( "VLC Viewer 2.2.4", "VLC 2.2.4 Already Installed") Then
                ConsoleWrite ("already installed")
                WinActivate ('VLC Viewer 2.2.4','Already Installed')
                MouseClick ('primary', 93, 83, 1, 0)
                
          EndIf
       
            ; this window will pop up if installer finishes sucessfully
           If WinExists( "VLC Viewer 2.2.4", "VLC Viewer 2.2.4 Installed") Then 
                ConsoleWrite ("already installed")
                WinActivate ('VLC Viewer 2.2.4','VlC Installed')
                MouseClick ('primary', 93, 83, 1, 0)
         EndIf

       
       
       
    • TrashBoat
      By TrashBoat
      After i create my GUI i cant set the color anymore.  help?
      $hBarGUI1 = GUICreate("", 50, 1, 91, 188, 0x80000000, 0x08000080) $g = GUICtrlCreateLabel("", 1, 1, 1, 1) GUICtrlSetBkColor(-1, $color) GUISetBkColor($color, $hBarGUI1) WinSetTrans($hBarGUI1, '', 0) WinSetState($hBarGUI1, '', @SW_SHOWNOACTIVATE) WinMove($hBarGUI1, '', -1, -1) WinSetTrans($hBarGUI1, '', 254) WinSetOnTop($hBarGUI1, "", 1) I see that my problem has to do something with WinSetState but have no clue how to fix it already tried to set it to @SW_UNLOCK and @SW_SHOWNORMAL.
      @swa
×