Create 24h timer

[Terenz]

A friend of mine ask me to make a 24h timer for check how long require some task on his PC. I'll do it my friend, i'm a super expert of this things! 

In my mind was easy but seems a timer has a "couple" of rules.

$sHour = 23
$sMin = 57
$sSec = @SEC

$sHour = StringFormat("%02s", $sHour)
$sMin = StringFormat("%02s", $sMin)

Do
    If $sSec <> @SEC Then
        $sSec = @SEC
        Select
;~          Case $sSec = "00" And $sMin = "59"
;~              $sHour += 1
;~              $sMin = 0
;~              If $sMin < 10 Then $sMin = StringFormat("%02s", $sMin)
;~              If $sHour < 10 Then $sHour = StringFormat("%02s", $sHour)
            Case $sSec = "00" And Not $sMin = "59"
                $sMin += 1
                If $sMin < 10 Then $sMin = StringFormat("%02s", $sMin)
;~          Case $sHour = "23" And $sMin = "00" And $sSec = "00"
;~              $sHour = 0
;~              StringFormat("%02s", $sHour)
        EndSelect
        ConsoleWrite($sHour & ":" & $sMin & ":" & $sSec & @CRLF)
    EndIf
Until 0

Well 'im stuck, that things doesn't satisfy me and not work. Example i don't know how to start again from 00:00:00. If i'll check 23:59:59 i'll update the hour one second early, if i'll check 23:00:00 can be two different time 23:00:00 and 00:00:00

Thanks for help me to resolve that code.

Edited February 26, 2017 by Terenz

[JohnOne]

What about

$sHour = 23
$sMin = 59
$SecsPassed = 55
; obviously set all above to 0
$sSec = 60


Do
    If $sSec <> @SEC Then
        $sSec = @SEC
        $SecsPassed += 1
        If $SecsPassed > 59 Then
            $SecsPassed = 0
            $sMin += 1
            If $sMin > 59 Then
                $sHour += 1
            EndIf
        EndIf
        if $sHour > 23 Then $sHour = 0
        if $sMin > 59 Then $sMin = 0
        ConsoleWrite(StringFormat("%02s", $sHour) & ":" & StringFormat("%02s", $sMin) & ":" & StringFormat("%02s", $SecsPassed) & @CRLF)
    EndIf

    Sleep(10)

Until 0

 

[mikell]

and what about

$hour = 23
$min = 59
$sec = 55
; obviously set all above to 0
Global $ticks = $hour*3600 + $min*60 + $sec

AdlibRegister("_Display", 1000)
While 1
  Sleep(10)
Wend

Func _Display()
  Local $sc, $mn, $hr
  $sc = Mod($ticks, 60)
  $mn = Mod($ticks/60, 60)
  $hr = Mod($ticks/3600, 24)
  $str = StringFormat("%02i", $hr) & ":" & StringFormat("%02i", $mn) & ":" & StringFormat("%02i", $sc)
  Tooltip($str, 0, 0)
  $ticks += 1
EndFunc

[UEZ]

@mikell: your StringFormat line can be shorten to:

$str = StringFormat("%02i:%02i:%02i", $hr, $mn, $sc)

[mikell]

Absolutely right.  I hastily copypasted the line from J1's post - and apologize for my laziness 

[Terenz]

Correct me if i'm wrong, but i think AdlibRegister is unnecessary. It call the function every second, is the same inside the loop since we check for @SEC? Considered a loop is required for the script to be alive, put everything there isn't better and we saving an Adlib? Just my curiosity, both script work fine for what i have see

Edited February 26, 2017 by Terenz

[Gianni]

@Terenz in which way do you think to use the timer to "check how long require some task on his PC"?

edit:

????

Local $iDelay = 0
Local $timer = 86390 ; start timer at 23:59:50 as example

While True
    Do
        If $iDelay <> @SEC Then
            $iDelay = @SEC
            ConsoleWrite(StringFormat("%02d:%02d:%02d", Floor($timer / 3600), Mod(Floor($timer / 60), 60), Mod($timer, 60)) & @CRLF)
            $timer += 1
        EndIf
    Until $timer = 86400 ; total seconds in 24 Hours
    $timer = 0 ; reset timer
WEnd

 

Edited February 26, 2017 by Chimp

[genius257]

Can windows task scheduler be a solution, or will the script be doing anything in between the 24h besides waiting?