Unique characters to array

[jjohn]

Hi all,

I have the following code, basically, it populates an array with unique characters found in a string, but it turns out only one character is in the array, i don't want to think it is due to a bug of autoit at this point, so i need your help on why, please

Dim $sx[0]
Dim $cn
$ss = "Xx"
ConsoleWrite(StringLeft($ss, 1) & " " & StringRight($ss, 1) & @CRLF)
ConsoleWrite(StringLeft($ss, 1) = StringRight($ss, 1) & @CRLF) ;here show X <> x
ConsoleWrite(@CRLF)
;the following is to populate array $sx with different unique characters in $ss
For $b = 1 To StringLen($ss)
    $flg = 0
    For $a = 0 To UBound($sx) - 1
        ;if asc(StringMid($ss,$b,1)) = asc($sx[$a]) Then ;if this line is used instead of the next, everything is fine
        If StringMid($ss, $b, 1) = $sx[$a] Then
            If StringMid($ss, $b, 1) = "x" Then ConsoleWrite("<<->>" & StringMid($ss, $b, 1) & " " & $sx[$a] & @CRLF)
            $flg = 1
            ExitLoop
        EndIf
    Next
    If $flg = 0 Then
        $cn = $cn + 1
        ReDim $sx[$cn]
        $sx[$cn - 1] = StringMid($ss, $b, 1)
    EndIf

Next
ConsoleWrite(UBound($sx) & @CRLF);list the ubound of $sx
;list what is in array $sx
For $a = 0 To UBound($sx) - 1
    ConsoleWrite($sx[$a] & @CRLF)
Next

same code in a file is attached as uniqueChar2Array.au3

[jchd]

When applied to strings, = performs a case-insensitive comparison. Use == instead.

 

[MagnumXL]

In the string provided, "Xx" there is only one unique character. Try using StringInStr or StringRegExp to match by case as well.

[jjohn]

Wow, you guys are fast, i learn more today, thanks!

[jguinch]

You can also retrieve all uniq characters using a regex :

#Include <Array.au3>

Local $sString = "This is a complex String"

Local $aUniqChars = StringRegExp($sString, "(.)(?!.*\1)", 3)
ConsoleWrite(UBound($aUniqChars) & " uniq characters found : " & @CRLF)
For $i = 0 To UBound($aUniqChars) - 1
    ConsoleWrite( " " & $aUniqChars[$i] & @CRLF)
Next

or with other basic functions :

#include <StringConstants.au3>
#Include <Array.au3>

Local $sString = "This is a complex String"

Local $aChars = StringSplit($sString, "", $STR_NOCOUNT)
$aUniqChars = _ArrayUnique($aChars)
_ArrayDisplay($aUniqChars)

 

Edited April 26, 2017 by jguinch