Jump to content
Jibsbrown

Listview with checkbox only showing 1st column

Recommended Posts

Jibsbrown

So trying to get an INI section in a listView with checkboxes. Was able to get the the section values to show until i add the checkboxes and now only the keys are show up. Between reading the Help file, Forum Topic and trying other code option. I have been unable to answer this problem. I'm assuming its something very basic I'm overlooking since this it's day 21 of learning Autoit.

If someone could please advise I would appreciate the assistance.

 

Here's the code: 

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <GUIListView.au3>
#include <Array.au3>
#include <File.au3>
#include <ListViewConstants.au3>


Global $sIniPath = "installLog.ini"
;ConsoleWrite($sIniPath)

$iniSctionNames = IniReadSectionNames($sIniPath)
 ;_ArrayDisplay($iniSctionNames, "$iniSctionNames")
 $keys2 = IniReadSection($sIniPath, $iniSctionNames[2])
_ArrayDisplay($keys2 , "$keys2")


; Create GUI
$hGUI = GUICreate("Test", 300, 250)

; Create ListView

$cLV = GUICtrlCreateListView("", 10, 10, 200, 200,$LVS_List,$LVS_EX_CHECKBOXES)

_GUICtrlListView_AddColumn($cLV, $keys2, 100)
_GUICtrlListView_AddColumn($cLV, $keys2, 100)
  ;_GUICtrlListView_AddItem($cLV, $keys2, 0)



_GUICtrlListView_AddArray($cLV, $keys2)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

WEnd

And the INI file I'm using. 

[OldSysInfo]
4=192.168.0.4|DESKTOP-RDIU2SN|R90M05Q8
5=192.168.0.5|SD0123456789101|R9WGP9P
6=192.168.0.6|SD0123456789102|R9WGP9PT
3=192.168.0.3|DESKTOP-3RS4LKL|R9WGP9P
23=192.168.0.23|SD0123456789102|MXL1234P5I

[PrinterIp]
50=192.168.0.50
48=192.168.0.48
47=192.168.0.47

[NewSysInfo]
newPC = SD0123456789adfs|192.168.0.185|2UA1234FTR

Also if possible could you explain how to hide the Array count row as well.

Share this post


Link to post
Share on other sites
Zedna
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>
#include <Array.au3>
#include <File.au3>
#include <ListViewConstants.au3>


Global $sIniPath = "installLog.ini"
;ConsoleWrite($sIniPath)

$iniSctionNames = IniReadSectionNames($sIniPath)
 ;_ArrayDisplay($iniSctionNames, "$iniSctionNames")
 $keys2 = IniReadSection($sIniPath, $iniSctionNames[2])
_ArrayDisplay($keys2 , "$keys2")


; Create GUI
$hGUI = GUICreate("Test", 300, 250)

; Create ListView

$cLV = GUICtrlCreateListView("Id.|IP", 10, 10, 200, 200, $GUI_SS_DEFAULT_LISTVIEW, BitOR($LVS_EX_CHECKBOXES,$WS_EX_CLIENTEDGE))

;~ _GUICtrlListView_AddColumn($cLV, "Id.", 100)
;~ _GUICtrlListView_AddColumn($cLV, "IP", 100)
  ;_GUICtrlListView_AddItem($cLV, $keys2, 0)

_ArrayDelete($keys2, 0)
_GUICtrlListView_AddArray($cLV, $keys2)

GUICtrlSendMsg($cLV, $LVM_SETCOLUMNWIDTH, 0, 50)
GUICtrlSendMsg($cLV, $LVM_SETCOLUMNWIDTH, 1, 100)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

WEnd

 

Share this post


Link to post
Share on other sites
Zedna

Here is version displaying only one column "IP" (without column "Id."):

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>
#include <Array.au3>
#include <File.au3>
#include <ListViewConstants.au3>


Global $sIniPath = "installLog.ini"
;ConsoleWrite($sIniPath)

$iniSctionNames = IniReadSectionNames($sIniPath)
 ;_ArrayDisplay($iniSctionNames, "$iniSctionNames")
 $keys2 = IniReadSection($sIniPath, $iniSctionNames[2])
_ArrayDisplay($keys2 , "$keys2")

; Create GUI
$hGUI = GUICreate("Test", 300, 250)

; Create ListView
$cLV = GUICtrlCreateListView("IP", 10, 10, 200, 200, $GUI_SS_DEFAULT_LISTVIEW, BitOR($LVS_EX_CHECKBOXES,$WS_EX_CLIENTEDGE))

_ArrayDelete($keys2, 0)
_GUICtrlListView_AddArray_Ini($cLV, $keys2)

GUICtrlSendMsg($cLV, $LVM_SETCOLUMNWIDTH, 0, 120)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

WEnd

; modified original UDF function
Func _GUICtrlListView_AddArray_Ini($hWnd, ByRef $aItems)
    Local $bUnicode = _GUICtrlListView_GetUnicodeFormat($hWnd)

    Local $tItem = DllStructCreate($tagLVITEM)
    Local $tBuffer
    If $bUnicode Then
        $tBuffer = DllStructCreate("wchar Text[4096]")
    Else
        $tBuffer = DllStructCreate("char Text[4096]")
    EndIf
    DllStructSetData($tItem, "Mask", $LVIF_TEXT)
    DllStructSetData($tItem, "Text", DllStructGetPtr($tBuffer))
    DllStructSetData($tItem, "TextMax", 4096)
    Local $iLastItem = _GUICtrlListView_GetItemCount($hWnd)
    _GUICtrlListView_BeginUpdate($hWnd)

    Local $pItem = DllStructGetPtr($tItem)
    For $iI = 0 To UBound($aItems) - 1
        DllStructSetData($tItem, "Item", $iI + $iLastItem)
        DllStructSetData($tItem, "SubItem", 0)
;~      DllStructSetData($tBuffer, "Text", $aItems[$iI][0])
        DllStructSetData($tBuffer, "Text", $aItems[$iI][1]) ; get value from second dimension and use it as text for first column in ListView
        If $bUnicode Then
            GUICtrlSendMsg($hWnd, $LVM_INSERTITEMW, 0, $pItem)
        Else
            GUICtrlSendMsg($hWnd, $LVM_INSERTITEMA, 0, $pItem)
        EndIf
        ; don't use values from other dimensions for more columns
;~      For $iJ = 1 To UBound($aItems, $UBOUND_COLUMNS) - 1
;~          DllStructSetData($tItem, "SubItem", $iJ)
;~          DllStructSetData($tBuffer, "Text", $aItems[$iI][$iJ])
;~          If $bUnicode Then
;~              GUICtrlSendMsg($hWnd, $LVM_SETITEMW, 0, $pItem)
;~          Else
;~              GUICtrlSendMsg($hWnd, $LVM_SETITEMA, 0, $pItem)
;~          EndIf
;~      Next
    Next

    _GUICtrlListView_EndUpdate($hWnd)
EndFunc   ;==>_GUICtrlListView_AddArray

 

Edited by Zedna

Share this post


Link to post
Share on other sites
Jibsbrown

Thank you very much Zedna, I can now see I had a lot more coding to do to just have one Column. 

Now its time to read up on DllStructSetData and all that links off.
 

Again thank you.

 

Share this post


Link to post
Share on other sites
Zedna

In this case change in _GUICtrlListView_AddArray() was simpler than changing content of array obtained from INI and passed to ListView through _GUICtrlListView_AddArray().

Without my modified UDF you should change (or copy) array obtained from INI to 1D array because you have only 1 column in ListView and _GUICtrlListView_AddArray() suppose array dimensions fit to number of columns in ListView.

Edited by Zedna

Share this post


Link to post
Share on other sites
Jibsbrown

Thank you for the additional info. I tried to get it down to a 1D but due to way I first set the INI with changing keys names I kinda stuck my self a 2D... Or at least that's my 21+ day Autoit brain is telling me.

Starting to think that I either leave the key blank or make it the same, but leaning to making this just variables that are made when the EXE starts. But have yet to understand how to get the IPs for the following code to set as global varibles out side of the For/Nest that can later be called for either a direct pass or a clipboard pass to active window input field.

; Get IP and separate into Subnet and host oct
$oct = StringSplit(@IPAddress1, ".")
$readOct = $oct[4]
Global $siteSubnet = $oct[1] & "." & $oct[2] & "." & $oct[3] & "."
Global $oHost = $oct[4]

;-Scan Subnet for ping able IPs and get WMIC Data
For $i = 50 To 43 Step - 1

    $activeIP = Ping($siteSubnet & $i, 250)
    $PrinterIP = $siteSubnet & $i
    If @error = 0 Then
        ;MsgBox(0,"",$PrinterIP,10)
        ;IniWrite($sInstallIniName, "PrinterIp", $i, $PrinterIP)
    EndIf
Next

What I'm building is for a desktop refresh project that will happen at different locations with changing subnets. This part take care of finding the printer IPs.

Share this post


Link to post
Share on other sites
Zedna

Here is simplified version for displaying one column (without _GUICtrlListView_AddArray):

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>

Global $sIniPath = "installLog.ini"

$iniSctionNames = IniReadSectionNames($sIniPath)
$keys2 = IniReadSection($sIniPath, $iniSctionNames[2])
;~ _ArrayDisplay($keys2 , "$keys2")

; Create GUI
$hGUI = GUICreate("Test", 300, 250)

; Create ListView
$cLV = GUICtrlCreateListView("IP", 10, 10, 200, 200, $GUI_SS_DEFAULT_LISTVIEW, BitOR($LVS_EX_CHECKBOXES,$WS_EX_CLIENTEDGE))

For $i = 1 To UBound($keys2) - 1 ; skip first item with index 0 (number of rows)
    GUICtrlCreateListViewItem($keys2[$i][1], $cLV)
Next

GUICtrlSendMsg($cLV, $LVM_SETCOLUMNWIDTH, 0, 120)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

 

And here is code for: copy one column from original 2D array to new global 1D array for later use:

; copy one column from original 2D array to new 1D array for later use
Global $ip[1]
$n = UBound($keys2) - 1
ReDim $ip[$n]
For $i = 1 To $n
    $ip[$i-1] = $keys2[$i][1]
Next
_ArrayDisplay($ip , "$ip")

 

Edited by Zedna

Share this post


Link to post
Share on other sites
Zedna

And here is simplified version for displaying of two columns:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>

Global $sIniPath = "installLog.ini"

$iniSctionNames = IniReadSectionNames($sIniPath)
$keys2 = IniReadSection($sIniPath, $iniSctionNames[2])
;~ _ArrayDisplay($keys2 , "$keys2")

; Create GUI
$hGUI = GUICreate("Test", 300, 250)

; Create ListView
$cLV = GUICtrlCreateListView("Id.|IP", 10, 10, 200, 200, $GUI_SS_DEFAULT_LISTVIEW, BitOR($LVS_EX_CHECKBOXES,$WS_EX_CLIENTEDGE))

For $i = 1 To UBound($keys2) - 1 ; skip first item with index 0 (number of rows)
    GUICtrlCreateListViewItem($keys2[$i][0] & '|' & $keys2[$i][1], $cLV)
Next

GUICtrlSendMsg($cLV, $LVM_SETCOLUMNWIDTH, 0, 50)
GUICtrlSendMsg($cLV, $LVM_SETCOLUMNWIDTH, 1, 100)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

 

Share this post


Link to post
Share on other sites
Jibsbrown

Thank you again Zedna for the code, see I still have a lot left to learn and figure out. Because I tried using variation of

Global $ip[1]

with the only success be an error message.  

Well also on to Func / EndFunc learning as well.

Again i can't express my appreciation enough for code help and insights shared. Thank you.

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now

  • Similar Content

    • Broihon
      By Broihon
      Hey guys,

      I ran into a problem when I wanted to delete items of a listview using the delete key. My approach is to register my own WndProc for the listview and then filter the $WM_GETDLGCODE msg and then call the original WndProc.
      That works like a charm. The problem is that when the listview gets redrawn it somehow ends up in an infinite loop. The listview is suddenly emtpy and I can't interact with any controls of the GUI at all. Here's the code:
       
      #include <GUIConstantsEx.au3> #include <GUIListView.au3> #include <WinAPI.au3> $h_GUI = GUICreate("Test", 200, 200, 350, 350) $h_LV = GUICtrlCreateListView("Col 1|Col 2|Col 3", 0, 0, 200, 200) _GUICtrlListView_AddItem($h_LV, "") _GUICtrlListView_AddSubItem($h_LV, 0, "bla0", 0) _GUICtrlListView_AddSubItem($h_LV, 0, "bla0", 1) _GUICtrlListView_AddSubItem($h_LV, 0, "bla0", 2) _GUICtrlListView_AddItem($h_LV, "") _GUICtrlListView_AddSubItem($h_LV, 1, "bla1", 0) _GUICtrlListView_AddSubItem($h_LV, 1, "bla1", 1) _GUICtrlListView_AddSubItem($h_LV, 1, "bla1", 2) _GUICtrlListView_AddItem($h_LV, "") _GUICtrlListView_AddSubItem($h_LV, 2, "bla2", 0) _GUICtrlListView_AddSubItem($h_LV, 2, "bla2", 1) _GUICtrlListView_AddSubItem($h_LV, 2, "bla2", 2) _GUICtrlListView_AddItem($h_LV, "") _GUICtrlListView_AddSubItem($h_LV, 3, "bla3", 0) _GUICtrlListView_AddSubItem($h_LV, 3, "bla3", 1) _GUICtrlListView_AddSubItem($h_LV, 3, "bla3", 2) $h_LV_NewWndProc = DllCallbackRegister("WndProc_LV", "int", "hwnd;uint;wparam;lparam") $g_LV_OldWndProc = _WinAPI_SetWindowLong(GUICtrlGetHandle($h_LV), $GWL_WNDPROC, DllCallbackGetPtr($h_LV_NewWndProc)) GUISetState(@SW_SHOW) Func WndProc_LV($hWnd, $uMsg, $wParam, $lParam) Return _WinAPI_CallWindowProc($g_LV_OldWndProc, $hWnd, $uMsg, $wParam, $lParam) EndFunc ;==>WndProc_GUI Do Until GUIGetMsg() = $GUI_EVENT_CLOSE DllCallbackFree($h_LV_NewWndProc) As you can see I'm doing nothing in the WndProc of the listview. I'm simply calling the original WndProc. This still "freezes" when I mess with the width of the columns or in the original project when I add more items that they don't fit in the listview and I have to scroll. If I don't do that it's working fine.
    • c.haslam
      By c.haslam
      I have
      Local $idListview = GUICtrlCreateListView("",8,8,@DesktopWidth/2-16,@DesktopHeight-150,$LVS_SHOWSELALWAYS, _ $LVS_EX_INFOTIP) Local $hListView = GUICtrlGetHandle($idListview) _GUICtrlListView_InsertColumn($hListview, 0, "Filename", 400) _GUICtrlListView_InsertColumn($hListview, 1, "Ext", 50) _GUICtrlListView_InsertColumn($hListview, 2, "Size",70) _GUICtrlListView_InsertColumn($hListview, 3, 'Date time',100) _GUICtrlListView_InsertColumn($hListview, 4, "Path", 385) _GUICtrlListView_InsertColumn($hListview, 5, "sizeInt", 0) _GUICtrlListView_JustifyColumn($hListview, $kSize,1) ; right align then further on
      While True $sFnamExt = FileFindNextFile($iSrch) If @error Then ExitLoop EndIf $sAtts = FileGetAttrib($sPath&'\'&$sFnamExt) If StringInStr($sAtts,'D') Then If $sFnamExt<>'$RECYCLE.BIN' Then $sDirs &= '?'&$sPath&'\'&$sFnamExt EndIf Else $p = StringInStr($sFnamExt,'.',0,-1) ; last If $p=0 Then $sFnam = $sFnamExt $sExt = '' Else $sFnam = StringLeft($sFnamExt,$p-1) $sExt = StringTrimLeft($sFnamExt,$p) EndIf _GUICtrlListView_AddItem($hListview,$sFnam,-1,_GUICtrlListView_GetItemCount($hListview)+1000) _GUICtrlListView_AddSubItem($hListview,$nItem,$sExt,$kExt) $nSize = FileGetSize($sPath&'\'&$sFnamExt) $sSize = AddThousandsSeparator($nsize) _GUICtrlListView_AddSubItem($hListview,$nItem,$sSize,$kSize) _GUICtrlListView_AddSubItem($hListview,$nItem,$nsize,$kSizeInt) $nTotBytes += $nSize $a1 = FileGetTime($sPath&'\'&$sFnamExt,$FT_MODIFIED,$FT_ARRAY) $t = $a1[0]&'-'&$a1[1]&'-'&$a1[2]&' '&$a1[3]&':'&$a1[4] _GUICtrlListView_AddSubItem($hListview,$nItem,$t,$kDateTime) _GUICtrlListView_AddSubItem($hListview,$nItem,$sPath,$kPath) If $gSQL Then $s = "Insert into tbl values ("&_SQLite_Escape($sFnam)&","&_SQLite_Escape($sExt)&",'"& _ $sSize&"','"& _ $t&"',"&_SQLite_Escape($sPath)&","&$nSize&")" _SQLite_Exec(-1,$s) If @error Then MsgBox(0,@ScriptLineNumber,_SQLite_ErrMsg()) EndIf EndIf EndIf WEnd FileClose($iSrch) You will see that I heeded the advice in Help > _GUICtrlListView_AddItem: "As AutoIt uses the $iParam parameter to store the controlID of native-created ListView items, this value should be set sufficiently high for UDF-created items to avoid possible conflict with any existing controls - a starting value of 1000 is recommended."
      (It's unfortunate that the Example does not heed this advice. OK, it doesn't need to because there are no other controls, but still --- it would help neophytes if it did. Also to me _GUICtrlListView_AddItem is not native because it is a UDF. Confused?)
      My script then does a sort using SQLite, and updates the ListView:
      Local $hQuery Local $colNames = ['fnam','ext','nsize','dateTime','path','SizeInt'] Local $s = "Select * FROM tbl ORDER BY "&$colNames[$ncol]&';' _SQLite_Query(-1,$s, $hQuery) If @error Then MsgBox(0,@ScriptLineNumber,_SQLite_ErrMsg()) EndIf Local $aRow[$kSizeInt+1] Local $iItem=-1 While _SQLite_FetchData($hQuery, $aRow, False, False) = $SQLITE_OK ; Read Out the next Row If @error Then MsgBox(0,@ScriptLineNumber,_SQLite_ErrMsg()) EndIf $iItem += 1 For $i = $kFnam To $kSizeInt _GUICtrlListView_SetItem($hListview,$aRow[$i],$iItem,$i,Default) Next WEnd This works, but I had earlier coded
      _GUICtrlListView_SetItem($hListview,$aRow[$i],$iItem,$i,Default,$iItem+1000) because the same advice is in the Help for this function.
      So my care in specifying $param back-fired! What am I not understanding?
      The only difference in what works is that the $param parameter is defaulted.
    • FrancescoDiMuro
      By FrancescoDiMuro
      Good evening everyone
      I am building a management for the company I work with, and I just imported a real amount of rows ( about 29000 ), in my SQLite DB.
      The thing I am not understanding, is the time that the script takes to build this amount of rows in the ListView.
      I didn't measure it, but I think it took 2 minutes or so to create each ListView item...
      It is normal that it takes so much time?
      What can I do to improve the creation of the items?

      Here's the code I am using to query and to create ListView items...
      ; Articles ListView: Global $lvwArticles = GUICtrlCreateListView("ID|Fornitore|Codice|Descrizione|EU|Prezzo|Sconto Applicato|Note", 14, 87, 1507, 660, BitOR($GUI_SS_DEFAULT_LISTVIEW,$LVS_SORTASCENDING,$LVS_SORTDESCENDING), BitOR($WS_EX_CLIENTEDGE,$LVS_EX_GRIDLINES,$LVS_EX_FULLROWSELECT)) ; Query $strQuery = "SELECT * FROM ARTICOLI;" ; Query Execution _SQLite_GetTable2d($objDatabase, $strQuery, $arrResult, $intRows, $intColumns) If @error Then ; Error Handling Else ; Cleaning the ListView _GUICtrlListView_DeleteAllItems($lvwArticles) If @error Then ; Error Handling Else ; No records in the Table If UBound($arrResult) < 2 Then ; Error Handling Else _GUICtrlListView_BeginUpdate($lvwArticles) For $intCounter = 1 To UBound($arrResult) - 1 $strListViewItem = $arrResult[$intCounter][0] & "|" & _ $arrResult[$intCounter][1] & "|" & _ $arrResult[$intCounter][2] & "|" & _ $arrResult[$intCounter][3] & "|" & _ $arrResult[$intCounter][4] & "|" & _ $arrResult[$intCounter][5] & "|" & _ $arrResult[$intCounter][6] & "|" & _ $arrResult[$intCounter][7] $objListViewItem = GUICtrlCreateListViewItem($strListViewItem, $lvwArticles) Next _GUICtrlListView_EndUpdate($lvwArticles) EndIf EndIf EndIf Thanks in advance


      Best Regards.
    • Skysnake
      By Skysnake
      I am tracking this topic by @LarsJ.  It is very advanced and overkill for what I am currently trying to do.
       
      Problem is this.
      Listview contains columns, one of which is right aligned and gets populated by float values, such as 123.99.  Some do not have decimals ie 124.00 and on sort gets truncated to 124.  Its obviously still the same value, but the display has reset.
      ; line below is for list VIEW ;..................................0.........1......2............ $cListView = GUICtrlCreateListView("CUSTOMER|AMOUNT|DESCRIPTION", 8, 152, 764, 279) GUICtrlSetBkColor($cListView, $GUI_BKCOLOR_LV_ALTERNATE) ; alternate between the listview background color and the listview item background color GUICtrlSetBkColor($cListView, $LVStdClr) ; Set the background color for the listview _GUICtrlListView_SetColumnWidth($cListView, 0, 120) ; -- the client name _GUICtrlListView_SetColumnWidth($cListView, 1, 90) ;-- the amount _GUICtrlListView_JustifyColumn($cListView, 1, 1) ; 1 - Text is right aligned _GUICtrlListView_SetColumnWidth($cListView, 2, 200) ; the description What I am looking for is something native and simple like a 
          _GUICtrlListView_SetColumnFormat($cListView, 1, "%.2f") ;  1 - column is stringformatted to "%.2f"
      So that after each sort it will appear as it was in the original rendering.
      Is there something like this? I have not been able to find a simple solution.

      Thanks.
      Skysnake
    • Ambient
      By Ambient
      I have tried several way sto get this to work to no avail. Any help would be appreciated. #include <ListViewConstants.au3> #include <GuiListView.au3> #include "GuiListViewEx.au3" $idItem = GUICtrlCreateListViewItem($r & " | " & $c & $adoRs.Fields("TransactionAmount").value & " | " & $Timestamp & " | " & _StringProper($adoRs.Fields("Tillid").value) & @CRLF & @CRLF & "Card Number : " & $cardnum & " " , $idListView) ConsoleWrite( "IDITEM" & $idItem) If STRINGLEFT($adoRs.Fields("TransactionAmount").value,1)= "-" Then Consolewrite(" String is Negative" & @CRLF) ;Drops in Here as expected ;GUICtrlSetColor(-1, $COLOR_RED) ; Colour line if item is negative this didn' work $TxC= _GUICtrlListView_SetTextColor($hListView, $CLR_RED) ; I also tried $TxC= _GUICtrlListView_SetTextColor(-1, 0xFF0000) CONSOLEWRITE("TEXTCOLOUR RETURNED " & $TxC & @crlf) ; This is returning True ELSE Consolewrite(" String is NOT Negative" & @CRLF) EndIf  
×