GUI Title bar Dark Theme, an elegant solution using DwmAPI

[DK12000]

I had a search around on how to do dark windows properly and found this elegant solution on GitHub, but did not see it posted here so thought I would connect the 2. 
SkyEmie is the creator and deserves a round of applause, also the first time I have seen If statements done this way. Yay for learning new things.
This little draft demonstrates how to switch from a light theme, to a dark application title bar with AutoIT, using DWM api. · GitHub

expandcollapse popup

; This little draft demonstrates how to switch from a light theme, to a dark application title bar with AutoIT, using DwmAPI.
; It will probably be useful to someone who wants to do this, without any headache.
; Because windows does not have any official documentation on this subject today :s

#include <GUIConstantsEx.au3>
#notrayicon

opt('guioneventmode', 1)

#cs ----------------------------------------------------------------------------
 Function    : is_app_dark_theme()
 Description : returns if the user has enabled the dark theme for applications in the Windows settings (0 on / 1 off)
               if OS too old (key does not exist) the key returns nothing, so function returns False
#ce ----------------------------------------------------------------------------
func is_app_dark_theme()
    return(regread('HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Themes\Personalize', 'AppsUseLightTheme') == 0) ? True : False
endfunc

#cs ----------------------------------------------------------------------------
 Function    : set_dark_theme($hwnd, $dark_theme = True)
 Description : set to the handle, the attribute to define whether dark/light theme
#ce ----------------------------------------------------------------------------
func set_dark_theme($hwnd, $dark_theme = True)
    ; before this build set to 19, otherwise set to 20, no thanks Windaube to document anything ??
    $DWMWA_USE_IMMERSIVE_DARK_MODE = (@osbuild <= 18985) ? 19 : 20
    $dark_theme = ($dark_theme == True) ? 1 : 0

    dllcall( _
        'dwmapi.dll', _
        'long',   'DwmSetWindowAttribute', _
        'hwnd',   $hwnd, _
        'dword',  $DWMWA_USE_IMMERSIVE_DARK_MODE, _
        'dword*', $dark_theme, _
        'dword',  4 _
    )
endfunc

; create gui
$gui_hwnd = guicreate('Tiny gui', 800, 450)
guisetonevent($GUI_EVENT_CLOSE, 'gui_close')

; if dark theme enabled for apps in windows settings, set dark theme to gui
if is_app_dark_theme() == True then
    set_dark_theme($gui_hwnd, True)
endif

; display gui
guisetstate(@sw_show)

while 1
    sleep(10)
wend

func gui_close()
    exit
endfunc

 

 

[argumentum]

In over 10 years you don't type... but when you do. Thanks for the code 

[argumentum]

you inspired me

#include <GUIConstantsEx.au3>
#notrayicon

opt('guioneventmode', 1)

; create gui
$gui_hwnd = guicreate('Tiny gui', 800, 450)
guisetonevent($GUI_EVENT_CLOSE, 'gui_close')

set_BorderColor($gui_hwnd, 0x00ff00) ; for Win 11 22H2 onwards
Func set_BorderColor($hwnd, $iBorderColor = 0xFFffffff) ; default is 0xffFFFFFF ; else use 0x00rrggbb
    $DWMWA_BORDER_COLOR = 34 ; https://www.purebasic.fr/english/viewtopic.php?t=78732
    dllcall( _
        'dwmapi.dll', _
        'long',   'DwmSetWindowAttribute', _
        'hwnd',   $hwnd, _
        'dword',  $DWMWA_BORDER_COLOR, _
        'dword*', $iBorderColor, _
        'dword', 4 )
EndFunc

; display gui
guisetstate(@sw_show)

while 1
    sleep(100)
wend

func gui_close()
    exit
endfunc

Set_BorderColor() 

Edit: ..I use IsDarkMode() instead of the registry for the dark mode setting.

Edited December 13, 2023 by argumentum
clarify

[Andreik]

@argumentum You've been inspired to create a radioactive border. We need to be careful about what we post because you are inspired to do strange things.

[Danyfirex]

The registry key does not exist in my machine but the set_dark_theme function works.

 

Saludos