minimise to system tray

[ChrisL 13]

minimise a gui to the system tray

Edit~: Updated to support newer versions of Autoit, thanks to Zedna too I've used some of your suggestions

expandcollapse popup

#NoTrayIcon
#include <GuiConstants.au3>
#include <Constants.au3>

Opt("GUIEventOptions",1)
Opt("TrayOnEventMode",1)
Opt("TrayMenuMode",1)   

TraySetOnEvent($TRAY_EVENT_PRIMARYUP,"SpecialEvent")


$gui = GuiCreate("MyGUI", 392, 316,-1, -1 , BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS))
GuiSetState()

While 1
    $msg = GuiGetMsg()
    
    Select
        Case $msg = $GUI_EVENT_MINIMIZE 
            GuiSetState(@SW_MINIMIZE)
            GuiSetState(@SW_HIDE)
            TraySetState(1) ; show
            
            If @OSVersion = "WIN_NT4" or @OSVersion = "WIN_ME" or @OSVersion = "WIN_98" or @OSVersion = "WIN_95" then
                TraySetToolTip ("My app - click here to restore")
            Else
                Traytip ("My App", "click here to restore", 5)
            EndIf
            

        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
    EndSelect
WEnd

Func SpecialEvent()
    GuiSetState(@SW_RESTORE)
    GuiSetState(@SW_Show)
    TraySetState(2) ; hide
EndFunc

Edited July 17, 2007 by ChrisL

[Pakku 0]

Hi ChrisL,

nice idee i can use this in one of my scripts!

thanks

Arjan

[RazerM 0]

simple yet effective. Nice

[iceberg 1]

hi ChrisL,

thanks alot for the codes. but can i check with you something....what if i am using "Switch...Case...EndSwitch"? I tried to play around with the codes for half an hr. i cdn't figure it out.

pls help me. thanks.

[SmOke_N 210]

hi ChrisL,

thanks alot for the codes. but can i check with you something....what if i am using "Switch...Case...EndSwitch"? I tried to play around with the codes for half an hr. i cdn't figure it out.

pls help me. thanks.

I'd like to see what you "tried" if you couldn't get it to work.

#include <GuiConstants.au3>
#include <Constants.au3>

Opt("TrayOnEventMode",1)
Opt("TrayMenuMode",1)   
Opt("TrayIconHide", 0)

TraySetOnEvent($TRAY_EVENT_PRIMARYUP,"SpecialEvent")
TraySetState()

GuiCreate("MyGUI", 392, 316,-1, -1 , BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS))
GuiSetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_MINIMIZE
            GuiSetState(@SW_HIDE)
            Opt("TrayIconHide", 0) 
            Traytip ("My App", "Click the Icon not the Tool Tip To Restore", 5)
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd

Func SpecialEvent()
    GuiSetState(@SW_Show)
    Opt("TrayIconHide", 1)
EndFunc

Edit:

(Forgot to paste my code)

Edited September 22, 2006 by SmOke_N

[iceberg 1]

thanks SmOke_N,

well one of the scripts i got from the forum was using "Switch...Case...EndSwitch" method. And the other portion of the script i made was with "Select...Case...EndSelect" method. I didn't knew how to combine both of them. I even tried having 2 "whiles". obviously tat didn't work.

[iceberg 1]

this was the code taken off the forum

While 1
    Sleep(0)
    $recv = TCPRecv($sock, 2048)
    If not $recv Then ContinueLoop
    $recv = StringSplit($recv, Chr(1))
    For $i = 1 to $recv[0]
        $temp = StringSplit($recv[$i], Chr(2))
        Switch $temp[1]
            Case "rejected"
                mError("Too many users in chat room.", 1)
            Case "accepted"
            ; nothing
            Case "adduser"
                _AddUser($temp[2])
            Case "deluser"
                _DelUser($temp[2])
            Case "exit"
                mError("Server has closed.", 1)
            Case Else
                If $recv[$i] Then GUICtrlSetData($edit, $recv[$i] & @CRLF, 1)
        EndSwitch
    Next
    _ReduceMemory()
WEnd

my code was

While 1
   $msg = GUIGetMsg()
   Select
       Case $msg = $GUI_EVENT_CLOSE
         MsgBox(0, "", "Dialog was closed") 
         Exit
      Case $msg = $GUI_EVENT_MINIMIZE
         MsgBox(0,"", "Dialog minimized",2)
      Case $msg = $GUI_EVENT_MAXIMIZE
         MsgBox(0,"", "Dialog restored",2)
   
      Case $msg = $button_1
         MsgBox(0, "Default button clicked", "Radio " & $radioval1 )
         
      Case $msg >= $radio_1 AND $msg <= $radio_3
         $radioval1 = $msg - $radio_1

   EndSelect
WEnd

so tats where i got blurred.

[Zedna 276]

minimise a gui to the system tray

Thanks for very nice and simple code

I made little changes:

1) #NoTrayIcon - to avoid initial flash of tray

2) hide tray after start of application

3) use TraySetState(2) ; hide and TraySetState(1) ; show

instead of Opt("TrayIconHide", 0/1)

4) use TraySetToolTip instead of TrayTip --> to work also on WIN98

#NoTrayIcon
#include <GuiConstants.au3>
#include <Constants.au3>

Opt("TrayOnEventMode",1)
Opt("TrayMenuMode",1)   

TraySetOnEvent($TRAY_EVENT_PRIMARYUP,"SpecialEvent")
;TraySetState(2) ; hide --> not needed

GuiCreate("MyGUI", 392, 316,-1, -1 , BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS))
GuiSetState()

While 1
    $msg = GuiGetMsg()
    
    Select
        Case $msg = $GUI_EVENT_MINIMIZE 
            GuiSetState(@SW_HIDE)
            TraySetState(1) ; show
            TraySetToolTip ("My app - click here to restore")

        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
    EndSelect
WEnd

Func SpecialEvent()
    GuiSetState(@SW_Show)
    TraySetState(2) ; hide
EndFunc

Edited September 22, 2006 by Zedna

[iceberg 1]

thanks Zedna!

[jftuga 1]

Nice script, I like it!

-John

[slayerz 0]

Nice and simple script, thanks for sharing

[BinaryCortex 0]

This script is not working for me.

C:\Users\NameDeleted\Desktop\tray.au3 (12) : ==> Variable used without being declared.:

$gui = GuiCreate("MyGUI", 392, 316,-1, -1 , BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS))

$gui = GuiCreate("MyGUI", 392, 316,-1, -1 , BitOR(^ ERROR

What are these supposed to be set to?

[Melba23 3,396]

BinaryCortex,

It is a very old script and the includes have changed a lot since it was written. Put these in place of the includes currently used:

#include <GuiConstantsEx.au3>
#include <Constants.au3>
#include <WindowsConstants.au3>

M23

[grimmlock 1]

Yes that works Thank you!!!