Create SuperHidden

[HackerZer0]

I made this a while ago to create superhidden folders in mass...

$quanity = InputBox("Super Hidden Generator", "How many Super Hidden files?", "")
If $quanity = 0 Then _Exit()
$var = 1

Do
DirCreate("SuperHidden (" & $var & ")")
$var = $var + 1
Until $var = $quanity

FileSetAttrib("SuperHidden*", "+SH")

Func _Exit()
Exit
EndFunc

to enable the viewing of superhidden folders navigate to the following registry key:

HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced

right click on ShowSuperHidden and select Modify

Change the value to 1 and click OK to save your changes

[Skrip]

It's pretty good...but I don't see anything in that code, that does anything to the registery..

[HackerZer0]

nothing in the code does do anything to the registry, i was just posting a method to view the super hidden folder once they are created...

i decided not to integrate it into the script because some people may not want to have their registry altered, and i'm also very lazy lol : )

[lod3n]

If you enter 1, it will get stuck in an infinite loop, and create folders until you run out of disk space.

[AutoChris]

If you enter 1, it will get stuck in an infinite loop, and create folders until you run out of disk space.

Change: $var = 1 to $var = 0. The problem is that $var starts out as 1 and then becomes 2 at the first loop so it never equals one when the variable is checked for its value. Therefore, it keeps running since it will never equal 1.

[RazerM]

expandcollapse popup

;===============================================================================
;
; Program Name:     SuperHidden Folder Creator
; Description::     Create SuperHidden folders
; Requirement(s):   None
; Author(s):        RazerM, HackerZer0
;
;===============================================================================
;
#include <GUIConstants.au3>
#include <GuiListView.au3>
#include <array.au3>
GUICreate("SuperHidden Folder Creator", 500, 400)
$hCurFolder = GUICtrlCreateInput(@ScriptDir, 10, 10, 450, 20)
$hChangeDir = GUICtrlCreateButton("...", 465, 10, 30, 20)
$hSuperHiddenList = GUICtrlCreateListView("Folder Name", 10, 40, 160, 350, $LVS_SHOWSELALWAYS)
_GUICtrlListViewSetColumnWidth($hSuperHiddenList, 0, 135)
$hAddFolder = GUICtrlCreateButton("Add Folder", 180, 40, 80, 25)
$hRemoveFolder = GUICtrlCreateButton("Remove Folder", 265, 40, 90, 25)
$fShowSuperHidden = RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced", "ShowSuperHidden")
Global $fShowButtonState = False
If $fShowSuperHidden = True Then
    $hToggleShowSuperHidden = GUICtrlCreateButton("Disable SuperHidden Folders in Explorer", 275, 70, 200, 25)
Else
    $hToggleShowSuperHidden = GUICtrlCreateButton("Enable SuperHidden Folders in Explorer", 275, 70, 200, 25)
    $fShowButtonState = True
EndIf
$hCreateFolders = GUICtrlCreateButton("Create Folders", 180, 70, 90, 25)
Global $ahItems[1] =[-1]
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hChangeDir
            Local $sNewDir = FileSelectFolder("Please select the parent folder", "", 7)
            If Not @error Then
                GUICtrlSetData($hCurFolder, $sNewDir)
            EndIf
        Case $hAddFolder
            Local $sFolderName = InputBox("Folder Name", "Enter your desired folder name", "Super Hidden Folder", " M", 300, 150)
            If Not @error Then
                _ArrayAdd($ahItems, GUICtrlCreateListViewItem($sFolderName, $hSuperHiddenList))
                If UBound($ahItems) = 2 And $ahItems[0] = -1 Then _ArrayDelete($ahItems, 0)
            EndIf
        Case $hToggleShowSuperHidden
            If $fShowButtonState = True Then
                GUICtrlSetData($hToggleShowSuperHidden, "Disable SuperHidden Folders in Explorer")
                $fShowButtonState = False
                RegWrite("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced", "ShowSuperHidden", "REG_DWORD", 1)
            Else
                GUICtrlSetData($hToggleShowSuperHidden, "Enable SuperHidden Folders in Explorer")
                $fShowButtonState = True
                RegWrite("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced", "ShowSuperHidden", "REG_DWORD", 0)
            EndIf
        Case $hCreateFolders
            For $i = 0 To UBound($ahItems) - 1
                DirCreate(StringReplace(GUICtrlRead($hCurFolder) & "\" & GUICtrlRead($ahItems[$i]), "\\", "\"))
                FileSetAttrib(StringReplace(GUICtrlRead($hCurFolder) & "\" & GUICtrlRead($ahItems[$i]), "\\", "\"), "+SH")
            Next
            MsgBox(262144, "Done", "Your super hidden folders have been created")
        Case $hRemoveFolder
            $hListViewItem = GUICtrlRead($hSuperHiddenList)
            If $hListViewItem > 0 Then
                $iPos = _ArraySearch($ahItems, $hListViewItem)
                If @error Then
                    MsgBox(262144 + 16, "Error", "A fatal error has occured.")
                    Exit
                EndIf
                GUICtrlDelete($ahItems[$iPos])
                _ArrayDelete($ahItems, $iPos)
            Else
                MsgBox(262144 + 16, "Error", "No folders are selected in the listview control")
            EndIf
    EndSwitch
WEnd

This should aid in the creation of super hidden folders.

[HackerZer0]

wow, nice script RazerM

[RazerM]

Thanks

[jvanegmond]

Yea, I might modify this a little and use it on my computer frequently. I'm going for a shortcut in my start menu that says 'Enable superhidden folders' and one that says 'Disable superhidden folders'

[Yho2005]

Don't want to be pain or sound too noobish but is there a UNHIDE function? I mean like change the attribute. I've hidden a file but it's no longer on the list. (I used RazerM's script.

Edited January 12, 2007 by Yho2005

[Psibernetic]

I have made a program that does exactly this, feel free to use any of my code as long as you give me credit somewhere.

X-Hide(your new best friend for examples...code is too long to post unfortunately)

Also it's updated to Securacy v1.0(adds RazorM's IDEA encryption)...I would temporarily avoid using this if you arent prepared for BETA... folder encryption fails for now