ShortHand

[Joke758]

Thanks to RazerM for his RC4 function!

expandcollapse popup

;By Joke758
If Msgbox ( 4, "Shorthand", "Encode(yes) or  decode(no)?" ) = 6 Then
    $file = FileOpenDialog ( "Choose a file", @scriptdir, "JPG Files (*.jpg)|Any Files (*.*)" )
    $message = InputBox ( "Shorthand", "Choose a message to hide in the jpg", "", "", -1, 100, -1, -1 )
    $hex = FileRead ( $file )
    $temp = StringInStr ( $hex, "!-)" )
    If $temp <> 0 Then $hex = StringTrimRight ( $hex, StringLen ( $hex )-$temp+1 )
    $hex &= "!-)"
    $hex = _StringToHexEx ( $hex ) & _StringEncryptRC4 ( $message, "Joke758" )
    $open = FileOpen ( "output.jpg", 2 )
    FileWrite ( $open, _HexToStringEx( $hex ) )
    Msgbox ( 64, "ShortHand", "Message successfully encoded in "&@scriptdir&"\output.jpg" )
Else
    $file = FileOpenDialog ( "Choose a file", @scriptdir, "JPG Files (*.jpg)|Any Files (*.*)" )
    $str = FileRead ( $file )
    $num = StringInStr ( $str, "!-)" )+2
    If $num = 2 Then
        Msgbox ( 16, "ShortHand", "Error, no message found." )
        Exit
    EndIf
    $msg = _StringDecryptRC4 ( _StringToHexEx ( StringTrimLeft ( $str, $num ) ), "Joke758" )
    Msgbox ( 0, "Shorthand", "Decoded message: "&$msg )
EndIf
   

Func _HexToStringEx($strHex)
    Return BinaryString("0x" & $strHex)
EndFunc   ;==>_HexToStringEx

Func _StringToHexEx($strChar)
    Return Hex(BinaryString($strChar))
EndFunc   ;==>_StringToHexEx

;===============================================================================
;
; Function Name:   _StringEncryptRC4
; Description::    Encrypts text using RC4 Encryption
; Parameter(s):    $text, $encryptkey
; Requirement(s):  AutoIt
; Return Value(s): Encrypted String
; Author(s):       RazerM
;
;===============================================================================
;
Func _StringEncryptRC4($text, $encryptkey)
    Local $sbox[256]
    Local $key[256]
    Local $temp
    Local $a
    Local $i
    Local $j
    Local $k
    Local $cipherby
    Local $cipher

    $i = 0
    $j = 0

    __RC4Initialize($encryptkey, $key, $sbox)

    For $a = 1 To StringLen($text)
        $i = Mod(($i + 1),256)
        $j = Mod(($j + $sbox[$i]),256)
        $temp = $sbox[$i]
        $sbox[$i] = $sbox[$j]
        $sbox[$j] = $temp

        $k = $sbox[Mod(($sbox[$i] + $sbox[$j]),256)]

        $cipherby = BitXOR(Asc(StringMid($text, $a, 1)),$k)
        $cipher = $cipher & Chr($cipherby)
    Next

    Return _StringToHexEx($cipher)
EndFunc   ;==>_StringEncryptRC4

;===============================================================================
;
; Function Name:   _StringDecryptRC4
; Description::    Decrypts text using RC4 Encryption
; Parameter(s):    $text, $encryptkey
; Requirement(s):  AutoIt
; Return Value(s): Decrypted String
; Author(s):       RazerM
; Note(s):         RC4 uses the same algorithm to encrypt and decrypt
;
;===============================================================================
;

Func _StringDecryptRC4($text, $encryptkey)
    Local $sbox[256]
    Local $key[256]
    Local $temp
    Local $a
    Local $i
    Local $j
    Local $k
    Local $cipherby
    Local $cipher
    $text = _HexToStringEx($text)
    $i = 0
    $j = 0

    __RC4Initialize($encryptkey, $key, $sbox)

    For $a = 1 To StringLen($text)
        $i = Mod(($i + 1),256)
        $j = Mod(($j + $sbox[$i]),256)
        $temp = $sbox[$i]
        $sbox[$i] = $sbox[$j]
        $sbox[$j] = $temp

        $k = $sbox[Mod(($sbox[$i] + $sbox[$j]),256)]

        $cipherby = BitXOR(Asc(StringMid($text, $a, 1)),$k)
        $cipher = $cipher & Chr($cipherby)
    Next
    Return $cipher
EndFunc   ;==>_StringDecryptRC4


; Helper function
Func __RC4Initialize($strPwd, ByRef $key, ByRef $sbox)
    Dim $tempSwap
    Dim $a
    Dim $b

    $intLength = StringLen($strPwd)
    For $a = 0 To 255
        $key[$a] = Asc(StringMid($strPwd, (Mod($a,$intLength))+1, 1))
        $sbox[$a] = $a
    Next

    $b = 0
    For $a = 0 To 255
        $b = Mod($b + $sbox[$a] + $key[$a],256)
        $tempSwap = $sbox[$a]
        $sbox[$a] = $sbox[$b]
        $sbox[$b] = $tempSwap
    Next
EndFunc   ;==>__RC4Initialize

Edited January 4, 2007 by Joke758

[WeMartiansAreFriendly]

cool burritoes.

[Skrip]

Decode doesn't seem to work...

[XxXFaNtA]

Works for me...great

I used something similar..but this is way better i guess...

My Script changed the color of specific pixels (but not realizable) to save the letters .

Great job on that one

Greetz,

FaNtA

[RazerM]

@Firestorm

The file with the message is output.jpg not the original. Nice script Joke758.

[Joke758]

Thanks! Your RC4 function is like 1000 times better than _StringEncrypt().

[Skrip]

@Firestorm

The file with the message is output.jpg not the original. Nice script Joke758.

Ahh, thanks. Good job man!

[llamnuds]

Great Script.

Cheers,

llamnuds

[dandymcgee]

How 'bout a "Remove" function to take the message back out of the picture? Tried to simply re-encode it with a different message, but when decoded the first message remained and a bunch of junk was added. Remove function would be useful.

[Joke758]

How 'bout a "Remove" function to take the message back out of the picture? Tried to simply re-encode it with a different message, but when decoded the first message remained and a bunch of junk was added. Remove function would be useful.

Added. See first post. If the picture already contain a secret message, it will be overwritted.

[A. Percy]

Nice job!

Cheers,

Alexsandro

[floker]

Great job!

[BillLuvsU]

Cool stuff mate. Great example on how to exploit an image format too. =]

[James]

Nice!!! I like this. There was something like this before.