Garfield Reader

[James]

Hey,

Ivan(i542) sent me this and I asked if I could edit it a bit. I then asked if I could post in his name. He said yes.

Basically, this will download a garfield comic. You need to make sure that the date is set correctly in your settings.

expandcollapse popup

#include <GUIConstants.au3>
Kernel()

Func Kernel()
    MsgBox(0, "About", "Created by i542. Edited by JamesB" & @CRLF & "Garfield (c) Jim Davis (See http://www.garfield.com)" & @CRLF & @CRLF & "Version: 1.0 Alpha" & @CRLF & "Updates on www.i542.net")
    $TodayComicAddress = "http://images.ucomics.com/comics/ga/" & @YEAR & "/ga" & StringTrimLeft(String(@YEAR), 2) & @MON & @MDAY & ".gif"
    ProgressOn("Garfield Reader", "Downloading Garfield Comic Strip", "0 percent")
    $iSize = InetGetSize($TodayComicAddress)
    InetGet($TodayComicAddress, "C:\Garfield.gif", 0, 1)
    $iTemp = -1
    Do
        $iPCent = int(@InetGetBytesRead/$iSize*100)
        If $iPCent <> $iTemp Then ProgressSet($iPCent, $iPCent & "%") ;prevent flicker
        $iTemp = $iPCent
    Until Not @InetGetActive
    ProgressSet(100, "Done", "Download complete! Garfield comic downloaded!")
    Sleep(1000)
    ProgressOff()
    If @WDAY = 1 Then
        MainBig()
    Else
        MainSmall()
    EndIf
EndFunc   ;==>Kernel

Func MainSmall()
    $gui = GUICreate("Garfield Reader", 614, 230, 193, 115, BitOR($WS_CAPTION, $WS_BORDER, $WS_CLIPSIBLINGS))
    $garfield = GUICtrlCreatePic("", 6, 7, 600, 177, BitOR($SS_NOTIFY, $WS_GROUP))
    GUICtrlSetImage(-1, "C:\Garfield.gif")
    $save = GUICtrlCreateButton("Save in file", 5, 195, 75, 25, 0)
    $quit = GUICtrlCreateButton("Quit", 533, 196, 75, 25, 0)
    GUICtrlCreateLabel("Garfield Reader by i542 & JamesB. Version 1.0 Alpha", 177, 200, 243, 17)
    GUICtrlSetState(-1, $WS_DISABLED)
    GUISetState(@SW_SHOW)

    While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $quit
                Exit
            Case $save
                MsgBox(64, "Save Garfield", "This command will save Garfield to your HDD. Please refer http://www.garfield.com for distribution information")
                $path = FileSaveDialog("Save", @MyDocumentsDir, "Graphic Interchange Format (*.GIF)")
                If @error Then ContinueLoop
                FileCopy("C:\Garfield.gif", $path & ".gif")
        EndSwitch
    WEnd
EndFunc   ;==>MainSmall

Func MainBig()
    $gui = GUICreate("Garfield Reader", 751, 407, 193, 115, BitOR($WS_CAPTION, $WS_BORDER, $WS_CLIPSIBLINGS))
    $garfield = GUICtrlCreatePic("", 2, 1, 600, 398, BitOR($SS_NOTIFY, $WS_GROUP))
    GUICtrlSetImage(-1, "C:\Garfield.gif")
    $save = GUICtrlCreateButton("Save to disk", 616, 6, 75, 25, 0)
    $quit = GUICtrlCreateButton("Quit", 612, 377, 75, 25, 0)
    GUISetState(@SW_SHOW)

    While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $quit
                Exit
            Case $save
                MsgBox(64, "Save Garfield", "This command will save Garfield to your HDD. Please refer http://www.garfield.com for distribution information")
                $path = FileSaveDialog("Save", @MyDocumentsDir, "Graphic Interchange Format (*.GIF)")
                If @error Then ContinueLoop
                FileCopy("C:\Garfield.gif", $path & ".gif")
                GUICtrlSetImage(-1, "C:\Garfield.gif")
        EndSwitch
    WEnd
EndFunc   ;==>MainBig

-James & Ivan through MSN

Edited August 11, 2007 by JamesB

[RazerM]

Firstly, the script downloads the image 10 times, I believe the following is what was meant to happen:

$iSize = InetGetSize($TodayComicAddress)
    InetGet($TodayComicAddress, "C:\Garfield.gif", 0, 1)
    $iTemp = -1
    Do
        $iPCent = int(@InetGetBytesRead/$iSize*100)
        If $iPCent <> $iTemp Then ProgressSet($iPCent, $iPCent & "%") ;prevent flicker
        $iTemp = $iPCent
    Until Not @InetGetActive

Edited August 11, 2007 by RazerM

[James]

Whoops. Must of missed that error. Thanks RazerM.

[Achilles]

I like this, good job to the both of you!

EDIT: I put this in my startup, it's just like those little calendar things that have a joke on them...

Edited August 13, 2007 by Piano_Man

[James]

And thanks from the both of us. Wait till you see our latest project.

[Nahuel]

hahahha I LOVE IT!!!

Just awesome. Good Job.

Oh, I edited a bit so it deletes the pic from the C drive once you clik quit or after you save it.

Edited August 12, 2007 by Nahuel

[Achilles]

Hope you guys don't mind! I used your script and made a Calvin and Hobbes Reader! I changed the GUI a little bit too... I don't know if Calving and Hobbes in the "big size" but if they do it probably won't work right, but you can change that if it ever happens.

expandcollapse popup

#noTrayIcon
#include <GUIConstants.au3>

Opt("GUIOnEventMode", 1)

Kernel()

While 1 
    Sleep(1000)
WEnd

Func Kernel()
    $TodayComicAddress = "http://images.ucomics.com/comics/ch/" & @YEAR & "/ch" & StringTrimLeft(@YEAR, 2) & @MON & @MDAY & ".gif"

    ProgressOn("Calving and Hobbes Reader", "Downloading...", "0%")
    $iSize = InetGetSize($TodayComicAddress)
    InetGet($TodayComicAddress, "C:\CalvinAndHobbes.gif", 0, 1)
    $iTemp = -1
    Do
        $iPCent = int(@InetGetBytesRead/$iSize*100)
        If $iPCent <> $iTemp Then ProgressSet($iPCent, $iPCent & "%");prevent flicker
        $iTemp = $iPCent
    Until Not @InetGetActive
    ProgressSet(100, "Complete", "Download successful!")
    Sleep(200)
    ProgressOff()
    If @WDAY = 1 Then
        MainBig()
    Else
        MainSmall()
    EndIf
EndFunc  ;==>Kernel

Func MainSmall()
    $gui = GUICreate("Calving and Hobbes Reader", 615, 226, -1, -1, $WS_SYSMENU, $WS_EX_TOOLWINDOW)
        GuiSetOnEvent($GUI_EVENT_CLOSE, '_Exit')
    $garfield = GUICtrlCreatePic("", 5, 5, 600, 189, BitOR($SS_NOTIFY, $WS_GROUP))
    GUICtrlSetImage(-1, "C:\CalvinAndHobbes.gif")

    GUISetState(@SW_SHOW)
EndFunc  ;==>MainSmall

Func MainBig()
    $gui = GUICreate("Calving and Hobbes Reader", 615, 430, -1, -1, $WS_SYSMENU, $WS_EX_TOOLWINDOW)
        GuiSetOnEvent($GUI_EVENT_CLOSE, '_Exit')
    $garfield = GUICtrlCreatePic("", 5, 5, 600, 398, BitOR($SS_NOTIFY, $WS_GROUP))
    GUICtrlSetImage(-1, "C:\CalvinAndHobbes.gif")

    GUISetState(@SW_SHOW)
EndFunc  ;==>MainBig

Func _Exit() 
    Exit 
EndFunc

[James]

Cool! Nice job!

[Toady]

Very nice work! I love it