MouseOnEvent UDF!

[fatyguy]

What is the best way to restrict long mouse press (left button) allowing only short click or double click?

I've tried such code:

 

#include "MouseOnEvent.au3"
 #include <AutoItConstants.au3>

...

   _MouseSetOnEvent($MOUSE_PRIMARYUP_EVENT, "__Dummy", 0, 1)
   _MouseSetOnEvent($MOUSE_PRIMARYDOWN_EVENT, "Mouse_LeftClick", 0, 1)
   _MouseSetOnEvent($MOUSE_SECONDARYUP_EVENT, "__Dummy", 0, 1)
   _MouseSetOnEvent($MOUSE_SECONDARYDOWN_EVENT, "__Dummy", 0, 1)
   _MouseSetOnEvent($MOUSE_WHEELDOWN_EVENT, "__Dummy", 0, 1)
   _MouseSetOnEvent($MOUSE_WHEELUP_EVENT, "__Dummy", 0, 1)

...

Func Mouse_LeftClick()
   MouseDown($MOUSE_CLICK_LEFT) ; Set the left mouse button state as down.
   Sleep(10)
   MouseUp($MOUSE_CLICK_LEFT) ; Set the left mouse button state as up.
EndFunc

It works fine until I made multiple left clicks, after that it totally stops to prevent long clicks of left button.

[fatyguy]

Func Mouse_LeftClick()
   MouseDown($MOUSE_CLICK_LEFT) ; Set the left mouse button state as down.
   MouseUp($MOUSE_CLICK_LEFT) ; Set the left mouse button state as up.
EndFunc

It works fine without "sleep(10)" but it I click left mouse multiple times the CPU load goes to 50%. Anything to do about this?

[shaqan]

Assigning a function to middle button and clicking it fast, made the whole script crash hard. Clicking slowly worked.

[Synaps3]

It works typically between 1-5 times and then none of the events trigger anymore. It seems some other people have this problem. Can someone please try to fix it?

[MrCreatoR]

#include "MouseOnEvent.au3"
#include <AutoItConstants.au3>

HotKeySet('{ESC}', '_Exit')

Global $iHold_Time = 200
Global $iTimer = 0

_MouseSetOnEvent($MOUSE_PRIMARYDOWN_EVENT, '_Primary_Event', 0, 0)
_MouseSetOnEvent($MOUSE_PRIMARYUP_EVENT, '_Primary_Event', 0, 0)

While 1
    Sleep(10)
WEnd

Func _Primary_Event($iEvent)
    Switch $iEvent
        Case $MOUSE_PRIMARYDOWN_EVENT, $MOUSE_PRIMARYDBLCLK_EVENT
            $iTimer = TimerInit()
            AdlibRegister('_Timer', 10)
        Case $MOUSE_PRIMARYUP_EVENT
            AdlibUnRegister('_Timer')
            $iTimer = 0
    EndSwitch
EndFunc


Func _Timer()
    If $iTimer And TimerDiff($iTimer) > $iHold_Time Then
        MouseUp($MOUSE_CLICK_PRIMARY)
    EndIf
EndFunc

Func _Exit()
    Exit
EndFunc

 

[MrCreatoR]

Update:

Quote

 v2.4 [15.03.2020]
* Fixed crash issue when running under x64 script. Thanks to LarsJ (Gary Frost?).
* Added _MouseSetOnEvent_SetDblClckSpeed function to set double click speed.

 

[drwhopoe1]

When you call $sFuncName of _MouseSetOnEvent more than twice, with a sleep of approx. greater than half a second, it breaks all events. lower sleeps work fine.

The intent is to fire off one and only one instance of a function call when you scroll wheel. As the UDF captures each instance of a notch of the scroll wheel, you can get several at once. So, a sleep or a semaphore with a sleep, or unbind then rebinding the mouse event with a sleep -- these all break after the first or second use.

 

expandcollapse popup

#include "MouseOnEvent.au3"

HotKeySet("^x",  "endProgram")

global $NotepadWHND = WinGetHandle ( "Notepad")

_MouseSetOnEvent($MOUSE_WHEELSCROLLDOWN_EVENT, "_MouseWheel_Events", $NotepadWHND,-1)

waitForInterrupt()

Func waitForInterrupt()
    While 1

    WEnd
EndFunc   ;==>waitForInterrupt

Func _MouseWheel_Events($iEvent)
    ConsoleWrite("_MouseWheel_Events call..." & @CRLF)
    Switch $iEvent
        Case $MOUSE_WHEELSCROLLDOWN_EVENT
            MouseWheel_down()
        Case $MOUSE_WHEELSCROLLUP_EVENT
            MouseWheel_up()
    EndSwitch
EndFunc

Func MouseWheel_down()
    ConsoleWrite("[1] npd active - mouse wheel down" & @CRLF)
    sleep(555)
EndFunc
Func MouseWheel_up()
    ConsoleWrite("[1] npd active - mouse wheel up" & @CRLF)
EndFunc


Func endProgram()
    ConsoleWrite("quitting..." & @CRLF)
    Exit
EndFunc   ;==>endProgram

 

Edited September 15, 2021 by drwhopoe1

[BakedCakes]

I have found a bug.

If you register a mouse wheel up event, trigger the event by scrolling up, then unregister it and register it again and trigger it -- it triggers twice! If you unregister and register the event once more, it triggers trice, etc. The expectation is that it will trigger exactly once, since you have registered it N+1 times and unregistered N times.

This happens:

• only with the non-RI functions
• only if $iBlockDefProc function argument is set to $MOE_RUNDEFPROC
• only after you trigger the event (if you don't trigger it, it works as expected)

To reproduce:

#include "MouseOnEvent.au3"

_MouseSetOnEvent($MOUSE_WHEELSCROLLUP_EVENT, "onMouseWheelUp", 0, $MOE_RUNDEFPROC) ; register
MouseWheel($MOUSE_WHEEL_UP) ; trigger
Sleep(100) ; some delay to allow the event to be processed before we unregister it
_MouseSetOnEvent($MOUSE_WHEELSCROLLUP_EVENT) ; unregister
_MouseSetOnEvent($MOUSE_WHEELSCROLLUP_EVENT, "onMouseWheelUp", 0, $MOE_RUNDEFPROC) ; register
_MouseSetOnEvent($MOUSE_WHEELSCROLLUP_EVENT) ; unregister
_MouseSetOnEvent($MOUSE_WHEELSCROLLUP_EVENT, "onMouseWheelUp", 0, $MOE_RUNDEFPROC) ; register
ConsoleWrite("---")
MouseWheel($MOUSE_WHEEL_UP) ; trigger
Sleep(100) ; some delay to allow the event to be processed before we exit

Func onMouseWheelUp()
    ConsoleWrite("up" & @CRLF)
EndFunc

After it prints "---", you would expect it to print "up" once, but it printa it 3 times!

After some debugging, it looks like the UDF author forgot to set $i__MSOE_EventReturn to 1 somewhere. With $iBlockDefProc function argument being set to $MOE_RUNDEFPROC, once __MouseSetOnEvent_MainHandler() is called at least once, which is done by the first "MouseWheel($MOUSE_WHEEL_UP)" in the reproducible code, $i__MSOE_EventReturn gets set from 1 to 0 and is never set back to 1. With $i__MSOE_EventReturn now always being 0, _WinAPI_UnhookWindowsHookEx() never gets called when we remove the last event, so the hook never gets removed from the chain. When we later add an event, UDF sees that it's a first event and creates another, 2nd, hook with _WinAPI_SetWindowsHookEx(). Basically, hooks are always created but never removed when they should be, which causes these extra event triggers.

Tbh I don't understand why $i__MSOE_EventReturn is needed in the first place. If I understand the code correctly, it is used to delay the cleanup in case the event is being processed via __MouseSetOnEvent_MainHandler() -> _WinAPI_PostMessage() -> __MouseSetOnEvent_WM_CALL(),  but I don't see why the delay is necessary. Not very familiar with Win32 programming and haven't read too much into UDF's code, so I can easily be missing something. For now I have set $i__MSOE_EventReturn to always be 1 in my copy of the UDF, which fixes the reproducible code issue.

tl;dr: Calling _MouseSetOnEvent to unregister the last event, it unregisters it from the UDF but it doesn't remove the created WinAPI hook, it remains in the Windows's hook chain.

Edited September 10, 2022 by BakedCakes

[BakedCakes]

Found another bug: RI doesn't callback on mouse wheel events when the mouse is moving, it only calls back when the mouse is stationary.

#include "MouseOnEvent.au3"

_MouseSetOnEvent_RI($MOUSE_WHEELSCROLLDOWN_EVENT, "onMouseWheelDown", 0, $MOE_RUNDEFPROC)
$counter = 0
While 1
    Sleep(10)
WEnd

Func onMouseWheelDown()
    ConsoleWrite($counter & @CRLF)
    $counter += 1
EndFunc

When running the above, if you move the mouse cursor around, for example to the left and right, while also scrolling down, onMouseWheelDown() will not be called. onMouseWheelDown() is called only when you scroll down while the mouse cursor is not changing the position.

_MouseSetOnEvent() (the non-RI one) doesn't have this bug and works even when the mouse is moving around.

Edited September 18, 2022 by BakedCakes