how to capture a click event on a list?

[ShadowElf]

I have a list

when I click on a item i want to execute a function. How to do that?

thx

[Melba23]

ShadowElf,

Just look for it in your GUIGetMsg loop:

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$hList = GUICtrlCreateList("", 10, 10, 480, 200)
GUICtrlSetData($hList, "One|Two|Three|Four|Five|Six|Seven|Eight|Nine|Ten")

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hList
            _My_Func()
    EndSwitch

WEnd

Func _My_Func()

    MsgBox(0, "List Item", GUICtrlRead($hList) & " clicked")

EndFunc

M23

[JoeBar]

Hi, sorry to excavate the topic, but when we want to capture a doubleclick on an item, what's the difference in the code ?

[Nine]

 Look at the example for _GUICtrlListView_Create.  It clearly shows how to capture a double click event.

[JoeBar]

I was talking about items in List (not ListView).

I have another question, Is there an event for when an item is selectionned (either by click or arrows) ?

Edited November 5, 2019 by JoeBar

[Zedna]

expandcollapse popup

#include <GUIConstants.au3>
#NoTrayIcon

;~ Global Const $WM_COMMAND = 0x0111
;~ Global Const $LBN_SELCHANGE = 1
;~ Global Const $LBN_DBLCLK = 2

$Form2 = GUICreate("Menu", 300, 300, 302, 218, -1, $WS_EX_TOPMOST)
;GUISetIcon("C:\Documenti\Icone\cvbxbd.ico")
$GCCList = GUICtrlCreateList("", 10, 10, 220, 300)
$Label1 = GUICtrlCreateLabel("Menu", 20, 32, 140, 30)
;GUICtrlSetFont(-1, 20, 400, 0, "Century Gothic")
GUIRegisterMsg($WM_COMMAND, "MY_WM_COMMAND")
GUISetState(@SW_SHOW)
poplist()

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case _IsPressed('0D') And ControlGetFocus($Form2) = 'ListBox1'
            If GUICtrlRead($GCCList) Then
                Run("rundll32 shell32,Control_RunDLL " & GUICtrlRead($GCCList))
                Sleep(10); Delay not to run multiple copies
            EndIf
            Exit
    EndSelect
WEnd

Func MY_WM_COMMAND($hWnd, $msg, $wParam, $lParam)
    $nNotifyCode = BitShift($wParam, 16)
    $nID = BitAND($wParam, 0x0000FFFF)
    $hCtrl = $lParam
    If $nID = $GCCList Then
        Switch $nNotifyCode
            Case $LBN_DBLCLK
                If GUICtrlRead($GCCList) Then
                    Run("rundll32 shell32,Control_RunDLL " & GUICtrlRead($GCCList))
                EndIf
                Exit
                Return 0
        EndSwitch
    EndIf
EndFunc   ;==>MY_WM_COMMAND

Func _IsPressed($s_hexKey, $v_dll = 'user32.dll')
    Local $a_R = DllCall($v_dll, "int", "GetAsyncKeyState", "int", '0x' & $s_hexKey)
    If Not @error And BitAND($a_R[0], 0x8000) = 0x8000 Then Return 1
    Return 0
EndFunc   ;==>_IsPressed

Func Runcpl()
    ;Run (@Comspec & " /c start " &GUICtrlRead($GCCList))
    Run("rundll32 shell32,Control_RunDLL " & GUICtrlRead($GCCList))
EndFunc   ;==>Runcpl

Func poplist()
    $search = FileFindFirstFile(@SystemDir & "\*.cpl")
    If @error Then Return
    While 1
        $file = FileFindNextFile($search)
        If @error Then Return
        GUICtrlSetData($GCCList, $file)
    WEnd
EndFunc   ;==>poplist

 

[JoeBar]

@Zedna

Very interesting, thank you.

So for the Lists, we must create a WM_COMMAND , while for other controls (ListView) it's integrated.