multi column combo boxes autoit

[ozmike]

Can we do multi column combo boxes - and hide columns

I want to have data in a combo

ABC "www.yyy.com"

DEF "www.jjj.com"

I want to show the below - i want to hide column 2 eg.

ABC

DEF

I want to do this so that i don't have to maintain a separate 2d

array

- I know you can do this with list views but what about combos..

mike

[Yoriz]

You could do it like this.

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $aComboContents[2] = ["ABC www.yyy.com","DEF www.jjj.com"]

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 261, 122, -1, -1)
$Combo1 = GUICtrlCreateCombo("", 58, 50, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
For $i = 0 To UBound($aComboContents)-1 Step 1
    $aComboPart = StringSplit($aComboContents[$i], " ")
    GUICtrlSetData(-1, $aComboPart[1], $aComboPart[1])
Next
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Combo1
            $sText = GUICtrlRead($Combo1)
            For $i = 0 To UBound($aComboContents)-1 Step 1
                $aComboPart = StringSplit($aComboContents[$i], " ")
                If $aComboPart[1] = $sText Then
                    MsgBox(0, "Selected", $aComboPart[2])
                    ExitLoop
                EndIf
            Next
    EndSwitch
WEnd

Edited June 10, 2010 by Yoriz

[ozmike]

Thanks that solution work..

I was hoping there was such a control ..like in msaccess ..but your solution works..

I'll have to check out KODA..

[spudw2k]

You can also use the _GUICtrlComboBoxEx_SetItemParam/_GUICtrlComboBoxEx_GetItemParam functions, but they do not display the second value in the combox either.