Extract icon from running process

[spudw2k]

Can someone help point me in the right direction to do this? I want this from a running process.

Edited October 10, 2008 by spudw2k

[Bert]

Usually the exe will have the icon in it when it is compiled. However, depending on the program, you may be dealing with a dll file that host the icon. In either case, it will depend on what you plan to do with it. If you want to have it in your GUI, you can use GUICtrlCreateIcon. I have seen tools out there that can extract icons from dll files if that is the route you want to go. A third route is to go here for icons: http://www.iconarchive.com/

I get most of my icons from here. Good selection, and usually free.

[Overkill]

  Volly said:

Usually the exe will have the icon in it when it is compiled. However, depending on the program, you may be dealing with a dll file that host the icon. In either case, it will depend on what you plan to do with it. If you want to have it in your GUI, you can use GUICtrlCreateIcon. I have seen tools out there that can extract icons from dll files if that is the route you want to go. A third route is to go here for icons: http://www.iconarchive.com/

I get most of my icons from here. Good selection, and usually free.

http://www.nirsoft.net/utils/iconsext_setup.exe is also a good free program for extracting icons

[spudw2k]

Thanks for the replies.

I've seen some tools to do this (some great ones even here written in AutoIt), but I was wondering if/how to grab that icon from a process that's running. Ultimately I'd lik to make a minimiz to tray tool. I realize this has been done, but I'd like to learn to code it myself.

[ProgAndy]

There is a message for _sendmessage to get the icon from a window (as handle), theres an example in the forum, but atm i don't find it.

[MrCreatoR]

Try this:

expandcollapse popup

#include <StaticConstants.au3>

$sProcess = "firefox.exe"
$sIcon = _ProcessGetIcon($sProcess)

If Not @error Then
    $iWidth = 400
    $iHeight = 120
    
    GUICreate("_ProcessGetIcon - Extract Icon From Process Demo", $iWidth, $iHeight)
    GUISetIcon($sIcon)
    
    GUICtrlCreateLabel("Extracted Icon: " & @CRLF & $sIcon, 0, ($iHeight/2) - (32/2) - 30, $iWidth, 30, $SS_CENTER)
    GUICtrlCreateIcon($sIcon, 0, ($iWidth/2) - (32/2), ($iHeight/2) - (32/2), 32, 32)
    
    GUISetState()
    
    While GUIGetMsg() <> -3
    WEnd
Else
    MsgBox(48, "Attention!", "Error - Process (" & $sProcess & ") probably not runing!")
EndIf

Func _ProcessGetIcon($vProcess)
    Local $iPID = ProcessExists($vProcess)
    If Not $iPID Then Return SetError(1, 0, -1)
    
    Local $aProc = DllCall('kernel32.dll', 'hwnd', 'OpenProcess', 'int', BitOR(0x0400, 0x0010), 'int', 0, 'int', $iPID)
    If Not IsArray($aProc) Or Not $aProc[0] Then Return SetError(2, 0, -1)
    
    Local $vStruct = DllStructCreate('int[1024]')
    
    Local $hPsapi_Dll = DllOpen('Psapi.dll')
    If $hPsapi_Dll = -1 Then $hPsapi_Dll = DllOpen(@SystemDir & '\Psapi.dll')
    If $hPsapi_Dll = -1 Then $hPsapi_Dll = DllOpen(@WindowsDir & '\Psapi.dll')
    If $hPsapi_Dll = -1 Then Return SetError(3, 0, '')
    
    DllCall($hPsapi_Dll, 'int', 'EnumProcessModules', _
        'hwnd', $aProc[0], _
        'ptr', DllStructGetPtr($vStruct), _
        'int', DllStructGetSize($vStruct), _
        'int_ptr', 0)
    Local $aRet = DllCall($hPsapi_Dll, 'int', 'GetModuleFileNameEx', _
        'hwnd', $aProc[0], _
        'int', DllStructGetData($vStruct, 1), _
        'str', '', _
        'int', 2048)
    
    DllClose($hPsapi_Dll)
    
    If Not IsArray($aRet) Or StringLen($aRet[3]) = 0 Then Return SetError(4, 0, '')
    Return $aRet[3]
EndFunc

[spudw2k]

Excellent, excellent! thanks a bunch. Also looking more into the _SendMessage func. First time hearing of it. Looks intersting. Thanks guys