how get image from clipboard without loss quality?

[joelson]

get image from clipboard, but _GDIPlus_ImageSaveToFile loss image quality

#include <Clipboard.au3>
#Include <GDIPlus.au3>
_SaveClip(@ScriptDir & "\XXX.jpg")
Func _SaveClip($sFile)
ConsoleWrite($sFile)
    If _ClipBoard_IsFormatAvailable($CF_BITMAP) <> 1 Then Return SetError(1, 0, 0)
    If _ClipBoard_Open(0) <> 1 Then Return SetError(2, 0, 0)
    If @error Then SetError(3, 0, 0)
    $hBitmap = _ClipBoard_GetDataEx($CF_BITMAP)
    If IsPtr($hBitmap) = 0 Then Return SetError(4, 0, 0)
    _GDIPlus_Startup()
    $hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)
    If @error Or IsPtr($hImage) = 0 Then
        _ClipBoard_Close()
        _WinAPI_DeleteObject($hBitmap)
        _GDIPlus_Shutdown()
        Return SetError(5, 0, 0)
    EndIf
    _ClipBoard_Close()
    _WinAPI_DeleteObject($hBitmap)
    If _GDIPlus_ImageSaveToFile($hImage, $sFile) = False Then
        _GDIPlus_ImageDispose($hImage)
        _GDIPlus_Shutdown()
        Return SetError(6, 0, 0)
    Else
        _GDIPlus_ImageDispose($hImage)
        _GDIPlus_Shutdown()
        Return SetError(0, 0, 1)
    EndIf
EndFunc   ;==>_SaveClip

please post a sample

thanks any help

[bogQ]

well after you explain why do you save it to JPG "XXX.jpg" then someone probably can make sense of your request for this problem.

[UEZ]

Try this

expandcollapse popup

;coded by UEZ 2011
#include <clipboard.au3>
#include <gdiplus.au3>
#include <guiconstantsex.au3>
#include <windowsconstants.au3>

$msgb = MsgBox(4, "Clipboard to GUI", "Ready to copy an image from clipboard to GUI?")
If $msgb <> 6 Then Exit

If Not _ClipBoard_Open(0) Then Exit _WinAPI_ShowError ("_ClipBoard_Open failed")
$hMemory = _ClipBoard_GetDataEx($CF_BITMAP)
If $hMemory  = 0 Then Exit _WinAPI_ShowError ("_ClipBoard_GetDataEx failed")

_GDIPlus_Startup()
$hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hMemory)
If $hBitmap = 0 Then Exit _WinAPI_ShowError ("_GDIPlus_BitmapCreateFromHBITMAP failed")

$iWidth = _GDIPlus_ImageGetWidth($hBitmap)
$iHeight = _GDIPlus_ImageGetHeight($hBitmap)

$hGUI = GUICreate("Show Image from Clipboard", $iWidth, $iHeight, -1, -1, $WS_POPUP, $WS_EX_TOPMOST)
GUISetState(@SW_SHOW, $hGUI)

$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
_GDIPlus_GraphicsDrawImage($hGraphic, $hBitmap, 0, 0)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            _ClipBoard_Close()
            _GDIPlus_ImageSaveToFile($hBitmap, @ScriptDir & "ImageFromClipboard.png")
            _GDIPlus_BitmapDispose($hBitmap)
            _GDIPlus_GraphicsDispose($hGraphic)
            _GDIPlus_Shutdown()
            GUIDelete($hGUI)
            ExitLoop
    EndSwitch
WEnd
Exit

Image will be save in lossless PNG format!

For the JPG best quality you can use these lines:

Local $sCLSID = _GDIPlus_EncodersGetCLSID("JPG")
Local $tParams = _GDIPlus_ParamInit(1)
Local $tData = DllStructCreate("int Quality")
DllStructSetData($tData, "Quality", 100)
Local $pData = DllStructGetPtr($tData)
_GDIPlus_ParamAdd($tParams, $GDIP_EPGQUALITY, 1, $GDIP_EPTLONG, $pData)
Local $pParams = DllStructGetPtr($tParams)
$save = _GDIPlus_ImageSaveToFileEx($hBitmp, @ScriptDir & "ImageFromClipboard.jpg"), $sCLSID, $pParams)

Br,

UEZ

Edited November 21, 2011 by UEZ

[joelson]

well after you explain why do you save it to JPG "XXX.jpg" then someone probably can make sense of your request for this problem.

get this script

_SaveClip(@ScriptDir & "XXX.jpg")

in this forum

[joelson]

thanks UEZ your script is working perfect.

very thanks your help.