Checking what is written in an InputBox

[Kjodiz]

I'm currently making a script to make work extremely easier, but I can't get it to check the text that is written in the InputBox.

My code at the moment:

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Test", 303, 179, 192, 124)
$Input1 = GUICtrlCreateInput("", 96, 32, 121, 21)
$Button1 = GUICtrlCreateButton("Check", 72, 80, 75, 25)
$Button2 = GUICtrlCreateButton("Exit", 160, 80, 75, 25)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $Button1
   If $Input1 = "Test" Then
      MsgBox (0,"Success!","Shit Works")
   Else
      MsgBox (0,"Failure","Failed")
   EndIf
   Exit
  
  
        Case $Button2
           Exit
    EndSwitch
WEnd

Help?

[kylomas]

kjodiz,

See GuiCtrlRead() in the help file. You are currently accessing the controlid, not the controls data.

kylomas

Edited February 28, 2012 by kylomas

[Realm]

Hello Kjodiz,

GuiCtrlCreateInput is assigned to variable $input1, thus it is the pointer to the control, not what is written in the control. You need to use GuiCtrlRead() to identify what is written in the control.

If GuiCtrlRead($Input1) == "Test" Then

I would also use the '==' operator since you are testing strings rather than values.

Realm

[Kjodiz]

Thanks very much guys!

I'd post the finished script here if it could be at some help for you guys, but as it will just be repetitive norwegian 'bullshit', I don't see the point ...

[BrewManNH]

I would also use the '==' operator since you are testing strings rather than values.

Realm

I would only use "==" if I were testing strings that have to be of a certain case, as that is a case sensitive comparison operator. Otherwise you could end up with a script that doesn't work as expected.

[Kjodiz]

Thanks to you to BrewManNH

And another thing:

For this script, I'll be using a lot of 'if's.

For example:

If GuiCtrlRead($Input1) == "Test" Then
      MsgBox (0,"Success!","Shit Works")
 If GuiCtrlRead($Input1) == "Test2" Then
      MsgBox (0,"Success!","Shit Worksagain")

I'm making a list of countries, and I'll need maybe 150 - 200..

Will it be too many 'if's for it to work properly, or will it work? (My "teacher" told me to try to stay away from using too many 'if's)

Is there another way?

[GMK]

For this script, I'll be using a lot of 'if's.

I would suggest using Switch...Case...EndSwitch.

[ileandros]

If you are going to use a lot of if statment u will have to use it like this

If GuiCtrlRead($Input1) == "Test" Then
      MsgBox (0,"Success!","Shit Works")
ElseIf GuiCtrlRead($Input1) == "Test2" Then
      MsgBox (0,"Success!","Shit Worksagain")

and then add

EndIf

at the end.

I would suggest as GMK said use switch.

While 1
$msg = GUIGetMsg()
Switch $msg
Case ; add your if statment here
Case ; add your others and so go on
EndSwitch ; end your switch statment

I suggest go and check the switch...case...endswitch at ur helpfiles before using it.

Edited February 28, 2012 by ileandros

[BrewManNH]

Switch is a lot faster than a load of If/Then statements take this:

If GuiCtrlRead($Input1) == "Test" Then
      MsgBox (0,"Success!","Shit Works")
If GuiCtrlRead($Input1) == "Test2" Then
      MsgBox (0,"Success!","Shit Worksagain")

Turn it into this:

Switch GuiCtrlRead($Input1) 
      Case  "Test"
         MsgBox (0,"Success!","Shit Works")
      Case "Test2" 
      MsgBox (0,"Success!","Shit Worksagain")
EndSwitch

Faster and easier to read.

[UEZ]

I wouldn't do it that way when you have a lot of checks.

I would create a 2d array with values to check and then check the array after input has been made.

Something like that

#include <buttonconstants.au3>
#include <editconstants.au3>
#include <guiconstantsex.au3>
#include <windowsconstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Test", 303, 179, 192, 124)
$Input1 = GUICtrlCreateInput("", 96, 32, 121, 21)
$Button1 = GUICtrlCreateButton("Check", 72, 80, 75, 25)
$Button2 = GUICtrlCreateButton("Exit", 160, 80, 75, 25)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Global $aCheck[2][2] = [    ["Test", "Shit works"], _
                                            ["Test2", "Shit works again"]]
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $Button1
            CheckInput(GUICtrlRead($Input1), $aCheck)
        Case $Button2
           Exit
    EndSwitch
WEnd

Func CheckInput($value, $array, $row = 0)
    Local $i
    For $i = 0 To UBound($array) - 1
        If $array[$i][$row] = $value Then Return MsgBox(0, "Found", $array[$i][1], 10)
    Next
    Return MsgBox(0, "Found", "Nothing found!")
EndFunc

The function CheckInput() has no error checks!

Br,

UEZ

Edited February 28, 2012 by UEZ

[Kjodiz]

Thanks for all the replies!