Custom buttons with GDI+ [solved]

[stormbreaker]

Greetings to everyone... while experimenting with GDI+, I ran into a bit of trouble.

CODE:

expandcollapse popup

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

; create variables and objects

_GDIPlus_Startup()

$gpsind0=_GDIPlus_ImageLoadFromFile("search.png")
$Form1 = GUICreate("A problem to solve", 150, 150)
$btn = GUICtrlCreateButton('Button', 10, 10, 90, 30)
GUISetState(@SW_SHOW)
$hGraphic=_GDIPlus_GraphicsCreateFromHWND(GUICtrlGetHandle($btn))

; main program code

_GDIPlus_GraphicsDrawImage($hGraphic,$gpsind0,0,0)
GUIRegisterMsg($WM_PAINT, "WM_ERASEBKGND")

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
_GDIPlus_ImageDispose($gpsind0)
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_ShutDown()
Exit

Case $btn
msgbox(64, '', 'you clicked a button')

EndSwitch
WEnd

Func WM_ERASEBKGND()
_GDIPlus_GraphicsDrawImage($hGraphic,$gpsind0,0,0)
EndFunc

Well, the image disappears once the mouse hovers over the button (or when the button is clicked etc). Can someone please help me in this issue.

Also, could someone please guide me as how to change the image once the button is clicked, mouse hovered, button is pressed and so on...

Thank you for your time and invaluable guidance.

Regards,

MKISH

IMAGE ATTACHED BELOW:

Edited December 3, 2012 by MKISH

[PhoenixXL]

buttons are painted onhover - you see a blue focus rectangle

instead try with a label

[stormbreaker]

I have already accomplished all this with a label using GUIRegisterMsg() and all, but what I am asking, is to do such things for a button control (like changing images on hover, mousedown, button press etc.).

Thank you for your time once again.

[BrewManNH]

If you use _GUICtrlButton_SetImageList you can specify the image for every condition for a button. This might work for what you're trying to achieve. Or, there's a script in the Examples section that deals with button hover somewhere in the depths of that forum that might also be helpful.

[UEZ]

Try this:

#include <ButtonConstants.au3>
#include <Constants.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
;~ #include <WindowsConstants.au3>;~~~

; create variables and objects

_GDIPlus_Startup()

$gpsind0 = _GDIPlus_ImageLoadFromFile("search.png")
$hHBMP = _GDIPlus_BitmapCreateHBITMAPFromBitmap($gpsind0)
$Form1 = GUICreate("A problem to solve", 150, 150)
$btn = GUICtrlCreateButton('Button', 10, 10, 90, 30, $BS_BITMAP)
GUISetState(@SW_SHOW)
_WinAPI_DeleteObject(GUICtrlSendMsg($btn, $BM_SETIMAGE, $IMAGE_BITMAP, $hHBMP))


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            _GDIPlus_ImageDispose($gpsind0)
            _WinAPI_DeleteObject($hHBMP)
            _GDIPlus_Shutdown()
            GUIDelete()
            Exit

        Case $btn
            MsgBox(64, '', 'you clicked a button')

    EndSwitch
WEnd

Br,

UEZ

[stormbreaker]

@BrewManNH, that solves the problem.

@UEZ, nice trick once again... I'll remember that one.