Real-time Line Counter

[dreamzboy]

I have an edit box that I wanted to keep tabs of the line number in real-time.  For an example, if a user enter 3 lines, the counter should update as soon as the user hit "Enter" after the 3rd entry.  I managed to do it but it's not real-time.  Program would hung or slow to response after I hit the "Configuration" button.

Many thanks!

expandcollapse popup

; Testing Host Count

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <StaticConstants.au3>

Example()

Func Example()
    Local $hostLabel, $hostEdit, $button, $msg, $count, $hostname
    GUICreate("Host Count") ; will create a dialog box that when displayed is centered

    $hostLabel = GUICtrlCreateLabel ("Hostname", 10, 10, 120, 20)
    $hostEdit = GUICtrlCreateEdit ("", 10, 40, 200, 80)
    $button = GUICtrlCreateButton ("Configure", 20, 140, 120, 30)

    GUISetState() ; will display an  dialog box with 1 checkbox

    ; Run the GUI until the dialog is closed
    While 1
        $msg = GUIGetMsg()
        $hostname = StringRegExp (GUICtrlRead ($hostEdit), '\V\S+', 3)
        $count = UBound ($hostname)
        sleep (500)
        GUICtrlCreateLabel ($count, 200, 10, 10, 20, $SS_RIGHT)
        Select
            Case $msg = $GUI_EVENT_CLOSE
                ExitLoop
            Case $msg = $button
                MsgBox (0, "Count", "The count is " & $count)
                #cs
                $hostname = StringRegExp (GUICtrlRead ($hostEdit), '\V\S+', 3)
                $count = UBound ($hostname)
                GUICtrlCreateLabel ($count, 200, 10, 10, 20, $SS_RIGHT)
                #ce
        EndSelect
    WEnd
EndFunc   ;==>Example

[jaberwacky]

This is the best I can do.  I'm sure there is a better way, so stick around.  I'm *sure* that someone will see my post and be inspired to do a better job.  8)

expandcollapse popup

; Testing Host Count

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <StaticConstants.au3>

Example()

Func Example()
    GUICreate("Host Count")

    Local Const $hostLabel = GUICtrlCreateLabel("Hostname", 10, 10, 120, 20)
        
    Local Const $label = GUICtrlCreateLabel('0', 200, 10, 30, 20, $SS_RIGHT)
    
    Local Const $hostEdit = GUICtrlCreateEdit("", 10, 40, 200, 80)
    
    Local Const $button = GUICtrlCreateButton("Configure", 20, 140, 120, 30)

    GUISetState(@SW_SHOWNORMAL)

    Local $count, $hostname
    
    Do              
        Switch GUIGetMsg()
            Case $button
                $hostname = StringRegExp(GUICtrlRead($hostEdit), "(*ANY)", $STR_REGEXPARRAYGLOBALMATCH)
                
                $count = (UBound($hostname) - 1) / 2
                
                GUICtrlSetData($label, $count)
                
            Case $GUI_EVENT_CLOSE
                ExitLoop                
        EndSwitch
    Until False
EndFunc

[dreamzboy]

Thank you for the quick response.  I tried running your code but came up with undeclared variable error:

C:\Users\nguyenk\Documents\AutoIT\RxG\test5.au3(20,91) : WARNING: $STR_REGEXPARRAYGLOBALMATCH: possibly used before declaration.
                $hostname = StringRegExp(GUICtrlRead($hostEdit), "(*ANY)", $STR_REGEXPARRAYGLOBALMATCH)
                ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
C:\Users\nguyenk\Documents\AutoIT\RxG\test5.au3(20,91) : ERROR: $STR_REGEXPARRAYGLOBALMATCH: undeclared global variable.
                $hostname = StringRegExp(GUICtrlRead($hostEdit), "(*ANY)", $STR_REGEXPARRAYGLOBALMATCH)
                ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
C:\Users\nguyenk\Documents\AutoIT\RxG\test5.au3 - 1 error(s), 1 warning(s)
!>18:06:06 AU3Check ended. Press F4 to jump to next error.rc:2
>Exit code: 2    Time: 0.517

[jaberwacky]

just replace it with 3

[Melba23]

jaberwacky & dreamzboy,

I would do it this way:

Case $button
    $count = ControlCommand("Host Count", "", $hostEdit, "GetLineCount", "")
    GUICtrlSetData($label, $count)

M23

[jaberwacky]

Op, please mark #5 as solved.

/thread

[dreamzboy]

Maybe I'm missing something but that's not real-time.  The count only update once you hit the $button.  What I'm looking for is a line counter similar to the Scite Editor where it shows the number of lines at the bottom of the status bar as you type.  It should show the number of lines even before you hit the button.

My current code work great counting only the number of entries which is what I wanted instead of empty lines.  The problem is that it's not real-time.  It doesn't show the entry number until you hit the $button.

Case $msg = $button
                $hostname = StringRegExp (GUICtrlRead ($hostEdit), '\V\S+', 3)
                $count = UBound ($hostname)
                GUICtrlSetData ($countLabel, $count)

 

Edited March 19, 2015 by dreamzboy

[Melba23]

dreamzboy,

Sorry about that - I based my response on jaberwacky's code. How about this?

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <StaticConstants.au3>

Example()

Func Example()
    GUICreate("Host Count")

    Local $hostLabel = GUICtrlCreateLabel("Hostname", 10, 10, 120, 20)
    Local $label = GUICtrlCreateLabel('0', 200, 10, 30, 20, $SS_RIGHT)
    Local $hostEdit = GUICtrlCreateEdit("", 10, 40, 200, 80)
    Local $button = GUICtrlCreateButton("Configure", 20, 140, 120, 30)

    GUISetState()

    Local $count, $iCurrentCount = 0

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch

        ; Get current line count
        $count = ControlCommand("Host Count", "", $hostEdit, "GetLineCount", "")
        ; If not what is stored
        If $count <> $iCurrentCount Then
            ; Reset label
            GUICtrlSetData($label, $count)
            ; Store new value
            $iCurrentCount = $count
        EndIf

    WEnd

EndFunc   ;==>Example

Better?

M23

[dreamzboy]

You are brilliant!  I wish I have 1/4 of your intelligence. 

Thanks to both of you.

[kylomas]

 You are brilliant! 

 

...and then some...

No shit, you learn something new every day, thanks M23...