_GUICtrlListView_GetItemTextString Single Cell

[PINTO1927]

Hi guys,

through _GUICtrlListView GetItemText String formula you can only get the contents of a cell?
example:

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListview

    GUICreate("ListView Get Item Text String", 400, 300)

    $idListview = GUICtrlCreateListView("col1|col2|col3", 2, 2, 394, 268)
    GUICtrlCreateListViewItem("line1|data1|more1", $idListview)
    GUICtrlCreateListViewItem("line2|data2|more2", $idListview)
    GUICtrlCreateListViewItem("line3|data3|more3", $idListview)
    GUICtrlCreateListViewItem("line4|data4|more4", $idListview)
    GUICtrlCreateListViewItem("line5|data5|more5", $idListview)
    GUISetState(@SW_SHOW)

    MsgBox($MB_SYSTEMMODAL, "Information", "Item 2 Text: " & @CRLF & @CRLF & _GUICtrlListView_GetItemTextString($idListview, 1))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

In the MsgBox I would like to show only, for example, "data3", and not all the content of the line3.

[BugFix]

Use 

_GUICtrlListView_GetItemText

to get the text from a sub item.

[PINTO1927]

I tried to use it but it does not show what I was looking

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListview
    GUICreate("ListView Get Item Text", 400, 300)
    $idListview = GUICtrlCreateListView("test|test|test", 2, 2, 394, 268)
    GUICtrlCreateListViewItem("line1|data1|more1", $idListview)
    GUICtrlCreateListViewItem("line2|data2|more2", $idListview)
    GUICtrlCreateListViewItem("line3|data3|more3", $idListview)
    GUISetState(@SW_SHOW)

    MsgBox($MB_SYSTEMMODAL, "Information", _GUICtrlListView_GetItemText($idListview, 1))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc

 

[PINTO1927]

solved, thanks a lot

[ROBINHOOD3]

Hello partner, and to read the whole column?

[ROBINHOOD3]

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListview

    GUICreate("ListView Get Item Text String", 400, 300)

    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)

    _GUICtrlListView_AddColumn(GUICtrlGetHandle($idListview), "ESTADO", 100)
    _GUICtrlListView_AddColumn(GUICtrlGetHandle($idListview), "PRUEBA", 100)

    For $s = 0 to 5
        _GUICtrlListView_AddItem(GUICtrlGetHandle($idListview), "ESTADO" & $s)
        _GUICtrlListView_AddSubItem(GUICtrlGetHandle($idListview), $s, "PRUEBA" & $s, 1)
    Next

    GUISetState(@SW_SHOW)

    MsgBox($MB_SYSTEMMODAL, "Information", _GUICtrlListView_GetItemTextString(GUICtrlGetHandle($idListview)))
    Exit

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example
 

[Nine]

Something like this :

Local $nRows = _GUICtrlListView_GetItemCount($idListview)
  Local $aCol [$nRows], $iColToGet = 1
  For $i = 0 to $nRows-1
    $aCol[$i] = _GUICtrlListView_GetItemText ($idListview,$i,$iColToGet)
  Next
  _ArrayDisplay ($aCol)